You should know that in Processing, an image frame is only rendered
each time callback function draw() is finished!
It means that any temporary "special effect" you do, won't show up.
Only the final result state at the end of draw() is displayed! The screen is frozen until then!
Function delay() usage is especially detrimental in Processing! 

can not create that effect?

you can

use a timer

or distinguish between mousePressed and mouseReleased

that's the 2nd approach

distinguish between mousePressed and mouseReleased

1. PImage img1;
2. PImage img2;
3. //
4. boolean hold = false;
5. //
6. void setup()
7. {
8.   background (0, 0, 0);
9.   size(900, 600);
10.   img1 = loadImage("button1.jpg"); // normal button
11.   img2 = loadImage("button2.jpg"); // presed button
12.   //
13.   img1.resize(100, 100);
14.   img2.resize(100, 100);
15.   //
16. }
17. void draw()
18. {
19.   if (hold)
20.     image (img2, 0, 0); // mouse down
21.   else
22.     image (img1, 0, 0); // mouse normal
23. }
24. //
25. void mousePressed()
26. {
27.   if (mouseX >0 && mouseX<100 && mouseY>0 && mouseY<100)
28.   {
29.     hold = true;
30.   }
31. }
32. //
33. void mouseReleased()
34. {
35.   if (mouseX >0 && mouseX<100 && mouseY>0 && mouseY<100)
36.   {
37.     hold = false;
38.   }
39. }
40. //

Of course you can! But you need a strategy!!!

Apparently you want your button to change its image for some delay(200), isn't it?
That 200 means 200 milliseconds.

Let's say draw() is called 50 times / second. 50 FPS = 1000 msec / 50 = 20 msec.
200 msec / 20 msec = 10 draw() calls!

Thus, we have to display the pressed button image by 10 frame calls of draw()!
After that, get back to display normal button image!

It's very complicated to hold all of that in our brains. 

works fine, using mouseReleased..

Oh! Chrisir got you a solution already! Anyways, here's mine: 

final static short  FPS = 50, MSEC = 1000 / FPS;
final static short  BLINK = 200, FRAMES = BLINK / MSEC;
final static color  BG = 0;
final static String ENGINE = P2D; // JAVA2D, P2D, P3D, OPENGL

int frameGoal;
int ww, hh;
int btnWW, btnHH;

PImage normalBtn, blinkBtn;

void setup() {
  size(300, 200, ENGINE);
  background(BG);
  frameRate(FPS);  // # of draw() calls/second
  imageMode(CENTER);

  ww = width  >> 1; // Center of canvas
  hh = height >> 1;

  normalBtn = loadImage("button1.jpg");
  blinkBtn  = loadImage("button2.jpg");

  btnWW = normalBtn.width  >> 1; // half width  of button
  btnHH = normalBtn.height >> 1; // half height of button
}

void draw() {
  // if current frameCount > stipulated frameGoal, display normal button
  // otherwise, display pressed button:
  image(frameCount > frameGoal ? normalBtn : blinkBtn, width>>1, height>>1);
}

void mousePressed() {
  final int mx = mouseX, my = mouseY;

  if (mx > ww-btnWW & mx < ww+btnWW & my > hh-btnHH & my < hh+btnHH)
    frameGoal = frameCount + FRAMES + 1; // set frameGoal # of FRAMES ahead
}

Alternative version for those like me w/o an external image file:

final static short  FPS = 50, MSEC = 1000 / FPS;
final static short  BLINK = 200, FRAMES = BLINK / MSEC;
final static color  BG = 0;
final static String ENGINE = P2D; // JAVA2D, P2D, P3D, OPENGL

int frameGoal;
int ww, hh;
int btnWW = 50, btnHH = 50;

PImage normalBtn, blinkBtn;

void setup() {
  size(300, 200, ENGINE);
  background(BG);
  frameRate(FPS);  // # of draw() calls/second

  imageMode(CENTER);
  rectMode(CENTER);

  ww = width  >> 1; // Center of canvas
  hh = height >> 1;

  normalBtn = loadImage("button1.jpg");
  blinkBtn  = loadImage("button2.jpg");

  //btnWW = normalBtn.width  >> 1; // half width  of button
  //btnHH = normalBtn.height >> 1; // half height of button
}

void draw() {
  // if current frameCount > stipulated frameGoal, display normal button
  // otherwise, display pressed button:
  //image(frameCount > frameGoal ? 
  //normalBtn : blinkBtn, width>>1, height>>1);

  fill(frameCount > frameGoal ? #0000FF : #FF0000);
  rect(ww, hh, btnWW << 1, btnHH << 1);
}

void mousePressed() {
  final int mx = mouseX, my = mouseY;

  if (mx > ww-btnWW & mx < ww+btnWW & my > hh-btnHH & my < hh+btnHH)
    frameGoal = frameCount + FRAMES + 1; // set frameGoal # of FRAMES ahead
}

perfect... thanks again!