preform an action x times pre frame... where x can be less than 1 ?

Programming Questions

yanom0

preform an action x times pre frame... where x can be less than 1 ?

in Programming Questions • 1 years ago

So I'm programming a simple "dodging bullets" game in the vein of Kenta Cho's rRootage. I have class Source, which is the source that bullets emanate from: (You can check out the whole program at my github sketchbook page ( https://github.com/yanom/yanomsketchbook) under the working title "fightergame"

class Source {
int x;
int y;
float speed;
int r;
int g;
int b;

Source () {
    x = 250;
    y = 250;
    speed = 5.0;
    r=255;
    g=0;
    b=0;
}

Source (int inx, int iny) {
    x = inx;
    y = iny;
    speed = 5.0;
    r=255;
    g=0;
    b=0;
}

Source (int inx, int iny, float inspeed) {
    x = inx;
    y = iny;
    speed = inspeed;
    r=255;
    g=0;
    b=0;
}

Source (int inx, int iny, float inspeed, int ir, int ig, int ib) {
    x = inx;
    y = iny;
    speed = inspeed;
    r=ir;
    g=ig;
    b=ib;
}

void handle(ArrayList holdbullet, int numbullets, int windowSize) {
    /*
    if (goingRight) {
      x += 6;
    }
    else {
      x -= 6;
    }
    if (x<8) {
      goingRight = true;
    }
    if (x>(windowSize-8)) {
      goingRight = false;
    }
    */

    for (int iii=1; iii<=numbullets; iii++) {
      float randX = random(-1*speed, speed);
      float randY = random(-1*speed, speed);

      holdbullet.add(new Bullet(x, y, 10, 10, r, g, b, randX, randY));
    }
}
}

And currently, it receives int numbullets in it's handle() function, which is called every frame the program runs, and it releases that many bullets every frame. The thing is, what's the best way to release less than one bullet per frame?

Like, release 30 bullets every 60 frames or something. But also still be able to release multiple bullets per frame.

Also probably of interest is class Layer. Layer has-a Source. Layer updates every frame and currently, each Layer tells it's Source how many to shoot that frame. The Layer knows how many to shoot because of global variable difficulty (currently set to 1).

That's kinda a crappy setup there so I need a better solution for releasing bullets :D

Replies(6)

jbum

Re: preform an action x times pre frame... where x can be less than 1 ?

1 years ago

I tend to use the millis() timer for this kind of thing - working with actual time (in milliseconds), rather than frames. This way, if the framerate happens to be slow or fast, you still release bullets at the same rate. So, assuming you want to release 30 bullets over 6 seconds:

long lastBulletRelease = millis(); // set this once

float bulletReleaseRate = 6*1000 / 30.0; // 6 seconds divided by 30 bullets

// in your bullet release check (typically in draw() )

if (millis()-lastBulletRelease >= bulletReleaseRate) {

// release bullet here <--

lastBulletRelease = millis();

}

yanom0

Re: preform an action x times pre frame... where x can be less than 1 ?

1 years ago

ah yes millis()!
It looks like this could be rigged up to release more than one bullet per frame if I needed too.

kritzikra..

Re: Re: preform an action x times pre frame... where x can be less than 1 ?

1 years ago

i've been back to the processing forums since yesterday only and i've seen variations on this question three times already since then.

so i decided to make a little utility class that deals with the most common triggers to be used inside draw (there's different ways to do this using threads though).

it has the following features:

(hopefully) easy to use,
just initialize with the trigger interval, e.g. Trigger trig = new Trigger( timeInMilliseconds );
and then query with if( trig.fires() ){ ... }
not a problem with variable / unstable framerates
multiple triggers per frame are not a problem, just use a while instead of the if, i.e.
while( trig.fires() ){ ... }

allrighty, here's the code:

Trigger slowTrigger = new Trigger( 3000, true ); // triggers every 3 seconds, that triggers immediately the first time
Trigger fastTrigger = new Trigger( 500 ); // triggers every 0.5 seconds
void setup(){
// very slow framerate to demonstrate
frameRate( 1 );
}
void draw(){
// should trigger ~ every three second
// this will never occur multiple times per frame,
// so you can use an if(...)
if( slowTrigger.fires() ){
println( "3000ms trigger activated" );
}
// should trigger ~ 2 times per second,
// so between 1 and 3 times per frame in this case (you never quite know if a frame is a bit longer or shorter than 1s)
// this means we have to use a while loop
while( fastTrigger.fires() ){
println( "500ms trigger activated" );
}
}
// The trigger class, copy this into your sketch
// (preferably in it's own tab)
class Trigger{
int start = millis();
int rate;
public Trigger( int rate ){
this( rate, false );
}
/**
* additional boolean parameter to indicate whether the trigger
* should fire immediately
*/
public Trigger( int rate, boolean immediately ){
setRate( rate );
if( immediately ) start -= rate;
}
/**
* changes the rate at which the trigger fires in milliseconds
*/
public void setRate( int rate ){
this.rate = rate;
}
/**
* returns the rate at which the trigger fires, in milliseconds
*/
public int getRate(){
return rate;
}
/**
* returns true if the trigger has fired, false otherwise
*/
public boolean fires(){
if( millis() - start >= rate ){
start += rate;
return true;
}
else{
return false;
}
}
/**
* resets the timer,
* next trigger will occur in _rate_ milliseconds.
*/
public void reset(){
start = millis();
}
}

if you prefer short code,

here's a "minified" version:

class Trigger{
int start = millis();
int rate;
public Trigger( int rate ){ this( rate, false ); }
public Trigger( int rate, boolean immediately ){ setRate( rate ); if( immediately ) start -= rate; }
public void setRate( int rate ){ this.rate = rate; }
public int getRate(){ return rate; }
public boolean fires(){
if( millis() - start >= rate ){
start += rate;
return true;
}
else{
return false;
}
}
public void reset(){ start = millis(); }
}

note that this code should work without problems in all processing variants (processingjs, processing java, processing android).

best,

hansi.

v.k.

Re: preform an action x times pre frame... where x can be less than 1 ?

1 years ago

One question. Why long? thx

kritzikra..

Re: Re: preform an action x times pre frame... where x can be less than 1 ?

1 years ago

long because old habbits die hard.

didn't look at the docs and expected millis() to be milliseconds since 1970, not milliseconds since application startup.

changed my original post to to use int, thanks for noting this :)

jbum

Re: preform an action x times pre frame... where x can be less than 1 ?

1 years ago

This class is really useful, thanks k!

Top Reply