Prcessing following control

Programming Questions

karenpunk

in Programming Questions • 1 year ago

code as below:

int maxCircle = 200;
float minDistance=2;
float distance;
Circle [] circles= new Circle[maxCircle];
void setup(){
size(800,800);
smooth();
for(int i=0;i<maxCircle;i++){
circles[i] = new Circle(random(width),random(height),random(2,20));
}
}
void draw(){
background(255,255);
for(int i=0;i<maxCircle;i++){
circles[i].update(width,height);
for(int j=0;j<maxCircle;j++){
distance = dist(circles[i].x,circles[i].y,circles[j].x,circles[j].y);
if(distance<minDistance){
stroke(0,50);
noFill();
line(circles[i].x,circles[i].y,circles[j].x,circles[j].y);}}
circles[i].display();
}
}
void mouseMoved(){
for(int i = 0; i<maxCircle;i++){
circles[i].x+=(mouseX-circles[i].x)*.2;
circles[i].y+=(mouseX-circles[i].y)*.2;}}
class Circle{
float x,y,vx,vy,r,speed;
Circle(float tempx, float tempy, float tempr){
x=tempx;
y=tempy;
vx=random(-1,1);
vy=random(-1,1);
r=tempr;
}
void update(int w,int h){
x+=vx;
y+=vy;
if(x<r || x>w-r){
vx*=-1;};
if(y<r || y>h-r){
vy*=-1;};
}
void display(){
fill(0,50);
noStroke();
ellipse(x,y,r,r);
}
}

Two questions:

1.Why doesn't the line function work?

2.How can i make circles move smoothly(respectively) following my mouse instead of squeezing into one point abruptly?

Thank you very much.

Replies(1)

allonestr..

Re: Prcessing following control

1 year ago

• Why doesn't the lie function work? Because you've set the conditions to be too limiting. Try setting minDistance to something bigger so that you see it working before making it smaller.

• Make the circles smoothly follow the mouse? One way is to use ease; you make the circles move a fraction of the distance to the mouse each frame. I'd put an easeTo() function in your Circle class; something like this:

// at the top
float easing = 0.1; //play with this value
void easeTo(float targetx, float targety)
{
float dx = targetx - x;
float dy = targety - y;
x += dx * easing;
y += dy * easing;
}

I changed some stuff in your main tab too:

the mouse function, for testing I changed it to mousePressed():

void mousePressed()
{
for (int i = 0; i < maxCircle; i++)
{
circles[i].easeTo(mouseX, mouseY);
}
}

and draw();

void draw()
{
background(255, 255);
for (int i = 0; i < maxCircle - 1; i++)
{
for (int j = i + 1; j < maxCircle; j++)
{
distance = dist(circles[i].x, circles[i].y, circles[j].x, circles[j].y);
if (distance < minDistance)
{
stroke(0, 50);
noFill();
line(circles[i].x, circles[i].y, circles[j].x, circles[j].y);
}
}
}
for(int c = 0; c < maxCircle; c++)
{
circles[c].update(width, height);
circles[c].display();
}
}

Note that I've split the loops - the first for checking the other circles - now they check each other only once in each frame, and the second for the update() and display() as these apply to the whole array.

I also reduced maxCircles to 20 as it was grindlingly slow otherwise.

If you're aiming at " node garden", try making the alpha of the lines less as the circles move apart.

Top Reply