I dunno much. Only quarks (Peter Lager) can reply adequately about his own library!  

...but I don't really understand the what "PVector" is or how it decides the position.  0,0 seems to place the cubes at the center of the image, rather than at the top left as I would expect.

Basically,  when you instantiate a PVector class, you get 3 field float variables -> x, y, z.
 
Whether (0,0) is top-left or center of a cube (or any other image), there's nothing to do w/ PVector.

If you wanna know more about the many tricks PVector can do,
besides giving you 3 variables to play with, go below:
PVector

It is obvious that working in 3D is new to you as well so a little primer on 3D graphics programming.

In 2D we can define a position on the screen using 2 values, in this case x and y and the origin[0,0] is the top left corner of the screen. In 3D we need 3 values to store a position in space, x, y and z. As GoToLoop said the PVector class has 3 attributes (variables) so is extremely convenient class for defining 3D positions.

Most of the rotate and move methods will accept PVector objects or 3 floats i.e. x,y,z so feel free to use whichever you find suits you.

So how to control each cube.

• The moveTo and moveBy methods are used to control the cube's position in 3D space. The [x,y,z] coordinates are to the centre of the cube.
• By default the centre of rotation is the centre of the cube and all rotateTo and rotateBy methods peform rotation about that centre, irrespective of where the cube is in 3D space
• The shapeOrientation method moves the cube's centre of rotation to a new position. This method is rarely needed and there is no need for it in your program.

Also note that when setting the draw mode then SOLID means use the fill color and TEXTURE means use an image to texture the shape. In your program you don't need both so it would be
cube[i][j].drawMode(S3D.TEXTURE);
or
cube[i][j].drawMode(S3D.TEXTURE | S3D.WIRE);
if you also wanted to see the cube edges.

I have modified your code above so that you have something working that you can build on.

The program creates a 10x10 matrix of cubes in the XY plane (Z=0) centred about X=0, Y=0
In the draw method I have modified your camera command so that the scene is viewed from [0,0,360] looking towards [0,0,0] middle of the cube wall with an up direction [0,1,0].

I don't have your images so I am using the default cube colours. In draw the every 10 frames a random cube will be picked and rotate 45 degrees about the X, Y or Z axis chosen at random.

HTH

1. import shapes3d.utils.*;
2. import shapes3d.animation.*;
3. import shapes3d.*;
4. 
   
5. Box[][] cube;
6. int cols = 10;
7. int rows = 10;
8. float angleX, angleY, angleZ;
9. 
   
10. void setup() {
11.   size(400, 400, P3D);
12.   background(160, 0, 90);
13.   lights();
14.   cube = new Box[cols][rows];
15.   for (int i = 0; i < cols; i++) {
16.     for (int j = 0; j < rows; j++) {
17.       cube[i][j] = new Box(this);
18.       cube[i][j].setSize(20, 20, 20);
19.       cube[i][j].drawMode(S3D.SOLID);
20.       cube[i][j].moveTo((4.5-i)*30, (4.5-j)*30, 0);
21.     }
22.   }
23.   frameRate(30);
24. }
25. 
    
26. void draw() {
27.   background(175, 0, 90);
28.   lights();
29.   camera(0, 0, 360, 0, 0, 0, 0, 1, 0);
30.   pushMatrix();
31.   if (frameCount % 10 == 0) {
32.     int col = (int)random(0, 10);
33.     int row = (int)random(0, 10);
34.     int axis = (int)random(0, 3);
35.     switch(axis) {
36.     case 0: // rotate 45 degrees about X axis
37.       cube[col][row].rotateBy(0, PI/4, 0);
38.       break;
39.     case 1: // rotate 45 degrees about Y axis
40.       cube[col][row].rotateBy(0, PI/4, 0);
41.       break;
42.     case 2: // rotate 45 degrees about Z axis
43.       cube[col][row].rotateBy(0, PI/4, 0);
44.       break;
45.     }
46.   }
47.   for (int i = 0; i < cols; i++) {
48.     for (int j = 0; j < rows; j++) {
49.       cube[i][j].draw();
50.     }
51.   }
52.   popMatrix();
53. }

Thanks so much to both of you.  These are exactly the explanations I was looking for, and this modified code gives me a great foundation to keep working from.

Hi, I'm back.  Again, thanks for the help so far, I've been digging in this week based on the direction you two led me in.  quarks, I have a few more questions about using your library.  I want to add interactivity, giving the user the ability to shuffle the (x,y,z) positions of the cubes around a little bit.  Eventually, this will be done with a Kinect, as guests walk close to the wall.  But first I want to try using the position of the cursor as the affector.

To convert a 3D scene to a 2D display involves a number of transformations and although it is possible to map from a XYZ coordinate to a XY pixel position is possible in Processing using screenX and screenY the reverse is not so straightforward.

Shapes3D uses a colour picking algorithm to identify the object being displayed at a screen XY position.

I have modified your program by adding a new method that works out which box is being display.

The method is generic in that it accepts any 2D array of boxes, an x and y position and calculates the row and col position of the box at that position. Here it is -

1. public void selectBox(Box[][] b, int x, int y) {
2.   boolean found = false;
3.   selBox = (Box)Shape3D.pickShape(this, x, y);
4.   selBoxCol = selBoxRow = -1;
5.   if (selBox != null) {
6.     int c = b.length;
7.     int r = b[0].length;
8.     for (int i = 0; i < c; i++) {
9.       for (int j = 0; j < r; j++) {
10.         if (selBox == b[i][j]) {
11.           found = true;
12.           selBoxCol = i;
13.           selBoxRow = j;
14.           println("C= " + i + "   R= " + j);
15.           break;
16.         }
17.       }
18.       if (found)
19.         break;
20.     }
21.   }
22.   else {
23.     println("MISSED");
24.   }
25. }

Then I modified the mouseClicked to

1. public void mouseClicked() {
2.   selectBox(cube, mouseX, mouseY);
3. }

The first time you click on the image it probably reported a miss, I don't know why this happens I suspect that it happens when it first creates the off-screen buffer.

Your modified code can be downloaded from here 

Thanks again, Quarks, this gives me just what I was looking for to move forward.  I really appreciate your guidance.  Thanks for the great library.