I don't really understand the second question, but maybe i can help with the first.
If you draw the shape to a PGraphics-object, you can convert it to a PImage witch get().
I made some changes to your code, this is how it could look like:

1. Poly p;
   
   void setup() {
     int[] x = {
       20, 40, 40, 60, 60, 20
     };
     int[] y = {
       20, 20, 40, 40, 60, 60
     };
     p = new Poly(x, y, 6);
   }
   
   void draw() {
     background(255);
   
     p.update(mouseX, mouseY);
     image(p.getImage(), 0, 0);
   }
   
   class Poly extends java.awt.Polygon {
     PGraphics canvas;
     PImage polyImage;
   
     public Poly(int[] x, int[] y, int n) {
       //call the java.awt.Polygon constructor
       super(x, y, n);
       canvas = createGraphics(width, height, P2D);
       polyImage = createImage(width, height, RGB);
     }
   
     void update(int pX, int pY) {
       if (contains(pX, pY)) {
         canvas.fill(255, 0, 0);
       }
       else {
         canvas.fill(255);
       }
     }
   
     // draws the shape to a PImage and returns it
     PImage getImage() {
       canvas.beginDraw();
       canvas.beginShape();
       for (int i = 0; i < npoints; i++) {
         canvas.vertex(xpoints[i], ypoints[i]);
       }
       canvas.endShape(CLOSE);
       canvas.endDraw();
   
       polyImage = canvas.get();
       return polyImage;
     }
   }
   

Thanks for the reply, lemme try the code and I would revert back.

The example which you gave is working fine, but when I try to do the same in my code canvas.fill() is not working am trying to make a polygon using some 2000 random points.

Yes, i think i understood. One way to do this is to create the image of the polygon once in setup(), and then make some of the pixels transparent on every frame.
I did some changes again, hope this helps:

1. Poly p;
   PImage img;
   float pX, pY;
   
   void setup() {
     size(600, 200);
     smooth();
   
     int[] x = {
       20, 40, 40, 60, 60, 20
     };
     int[] y = {
       20, 20, 40, 40, 60, 60
     };
     p = new Poly(x, y, x.length);
     img = p.getImage();
   }
   
   void draw() {
     background(0);
    
     if (p.contains(mouseX-pX, mouseY-pY)) {
       tint(255, 0, 0);
     }
     else {
       tint(255);
     }
   
     image(img, pX, pY);
     pX = pX + 1;
     pY = pY +0.3;
   
     // remove some pixels from the image
     destroyImage(img);
   }
   
   void destroyImage(PImage im) {
     im.loadPixels();
     for (int i = 0; i< im.pixels.length/150 ; i++ ) {
       // make random pixel transparent
       int index = (int)random(im.pixels.length);
       im.pixels[index] = 0;
     }
     im.updatePixels();
   }
   
   
   class Poly extends java.awt.Polygon {
     PGraphics canvas;
     PImage polyImage;
     int imgW, imgH;
   
     public Poly(int[] x, int[] y, int n) {
       //call the java.awt.Polygon constructor
       super(x, y, n);
      
       // calculate dimension of the polygon-image
       java.awt.Rectangle r = getBounds();
       imgW = r.x + r.width;
       imgH = r.y + r.height;
          
       canvas = createGraphics(imgW, imgH, P2D);
       polyImage = createImage(imgW, imgH, RGB);
     }
   
     // draws the shape to a PImage and returns it
     PImage getImage() {
       canvas.beginDraw();
       canvas.noStroke();
       canvas.beginShape();
       for (int i = 0; i < npoints; i++) {
         canvas.vertex(xpoints[i], ypoints[i]);
       }
       canvas.endShape(CLOSE);
       canvas.endDraw();
   
       polyImage = canvas.get();
       return polyImage;
     }
   }

Edit: Did not see your last post, if something doesn't work, please tell what exactly doesn't work and it helps a lot to see how you implemented it in your code. Otherwise, we can only guess what went wrong.

Am using the PolygonBlob class used here, for silhouette. I want to manipulate with the shadows for a project of mine: