Indeed point() for some reason works awfully in a lot of renderers.

Thanks for the tip, i will try using lines instead points.

Just another fast question..... You say that:
otherwise i think toxiclibs has good methods for drawing point clouds...

i goggled that and i get
http://code.google.com/p/toxiclibs/source/browse/trunk/toxiclibs/src.core/toxi/geom/PointCloud.java?r=445

where i can find an example or docs on how to implement this library??

Thanks again!!

well you can start here  http://toxiclibs.org/

Thanks for your time !!!!

Im dowloading the library right now :)

More on the 'cloud' part, for rendering those point clouds, check here:  http://jimblackhurst.com/wp/?p=213

Hi

finally im trying to render those points using this post on wiki as base
http://wiki.processing.org/w/1,000,000_points_in_OpenGL_using_Vertex_Arrays#Downloads

Its working correct, im moving 100000 points. Right now im using a random color for each point but i would like to capture the color of each point to put on the color buffer.

Im using

1. fbColores.put(random(0,1)); // for red
2. fbColores.put(random(0,1)); // for green
3. fbColores.put(random(0,1)); // for blue

And i would like to do something like that, but it doesnt seems to work because i dont see anything on screen

1. float r = red(rgbImage.pixels[index]);
2. float g = green(rgbImage.pixels[index]);
3. float b = blue(rgbImage.pixels[index]);
4. fbColores.put(255/r); // for red
5. fbColores.put(r255/g); // for green
6. fbColores.put(255/b); // for blue

fbColores is declared in this way fbColores = BufferUtil.newFloatBuffer(numPoints*3) /// RGB

Why its that not working, when i put the colors using random its ok but when i try to put those normalized colors (255/r) it doesnt works

Thanks again for your patient

Ok i found it

what a stupid mistake, if i normalize the color value to get something between 0-255 it works, but i think that map is causing a slow... its there another way to normalize this color values

1. float r = red(rgbImage.pixels[index]);
2. float g = green(rgbImage.pixels[index]);
3. float b = blue(rgbImage.pixels[index]);

1. fbColores.put(map(r,0,255,0,1)); // for red
2. fbColores.put(map(g,0,255,0,1)); // for green
3. fbColores.put(map(b,0,255,0,1)); // for blue

You really need to be using the GLGraphics library for this kind of thing, and constructing your point cloud as a GLmodel. You can colour the individual points separately, and make the updateColor() call each frame to keep them changing color.

import javax.media.opengl.*;
import codeanticode.glgraphics.*;
import remixlab.proscene.*;

GLModel points;
GLModel grid;
Scene scene;
KeyFrameInterpolator kfi;


int data_rows = 1;
int max_points = 100000;
int rand_x = 2000;
int rand_y = 2000;
int rand_z = 2000;
int[] blessed = new int[max_points];
float[] coord_x = new float[max_points];
float[] coord_y = new float[max_points];
float[] coord_z = new float[max_points];
int min_bright =30;
int offset = 4;
PFont debug;



void setup() {
  size(screen.width-40, screen.height-100, GLConstants.GLGRAPHICS);
  scene = new Scene(this); 
  kfi = new KeyFrameInterpolator(this); 
  scene.setAxisIsDrawn(false);
  scene.setGridIsDrawn(false);
  scene.setRadius(5000);
  scene.camera().showEntireScene();

  load_data();
  debug = createFont("Arial", 14);
  frameRate(1000);

  drawgrid(10,50,20);
  
      for (int i = 0; i < max_points; i++)
      {
       blessed[i] = 50;
      }
}


void draw() 
{
   //note the framerate 
 frame.setTitle(str(round(frameRate))+"fps");
 
 bless();
 
 // When drawing GLModels, the drawing calls need to be encapsulated 
 // between beginGL()/endGL() to ensure that the camera configuration 
 // is properly set.
 GLGraphics renderer = (GLGraphics)g;
 renderer.beginGL(); 
 
 // We get the gl object contained in the GLGraphics renderer.
 GL gl = renderer.gl;

         gl.glDisable(GL.GL_DEPTH_TEST);
         gl.glEnable(GL.GL_BLEND);
         gl.glBlendFunc(GL.GL_SRC_ALPHA,GL.GL_ONE);

   //Move everything we draw into the middle of the screen (or could just move the camera)
   translate(width/2,height/2,0); 
   
  // Disabling depth masking to properly render a semitransparent
  // object without using depth sorting.
  gl.glDepthMask(false);  
    points.render(); 
  
  gl.glDepthMask(true);
  
  
  
  grid.render();
   
    /////////////////////////////
    // Update (load) Vertex data
    /////////////////////////////
   
      points.beginUpdateVertices();
      for (int i = 0; i < max_points; i++)
      {
        points.updateVertex(i, coord_x[i] + random(offset), coord_y[i] + random(offset), coord_z[i] + random(offset));
      }
      points.endUpdateVertices();
   
   
    /////////////////////////////
    // Update Vertex Colour
    /////////////////////////////
      points.beginUpdateColors();
      for (int i = 0; i < max_points; i++)
      {
        points.updateColor(i, 255, 255, 255, blessed[i]);
      }
      points.endUpdateColors();  
   
 renderer.endGL(); 

}



void drawgrid(float spacing, int gridsize, float gridStroke)
{
  int gridverts = gridsize*4;
  
  grid = new GLModel(this, gridverts+4, LINES, GLModel.STATIC);
  grid.initColors();

  grid.beginUpdateVertices();
    for (int i = 0; i < gridverts+4; i=i+4)
    {
      grid.updateVertex(i,-(gridverts*(spacing/2)), (i*spacing)-((gridverts/2)*spacing), 0);
      grid.updateVertex(i+1,(gridverts*(spacing/2)), (i*spacing)-((gridverts/2)*spacing), 0);

      grid.updateVertex(i+2,(i*spacing)-((gridverts/2)*spacing),-(gridverts*(spacing/2)), 0);
      grid.updateVertex(i+3,(i*spacing)-((gridverts/2)*spacing),(gridverts*(spacing/2)), 0); 
    }
  grid.endUpdateVertices();
  
  grid.beginUpdateColors();
    for (int i = 0; i < gridverts+4; i=i+4)
    {
      if (i%40 == 0)
      {
        grid.updateColor(i,   255, 255, 255, gridStroke+30);
        grid.updateColor(i+1, 255, 255, 255, gridStroke+30);
        grid.updateColor(i+2, 255, 255, 255, gridStroke+30);
        grid.updateColor(i+3, 255, 255, 255, gridStroke+30);
      }      
      else if(i%10 == 0)
      {
        grid.updateColor(i,   255, 255, 255, gridStroke+15);
        grid.updateColor(i+1, 255, 255, 255, gridStroke+15);
        grid.updateColor(i+2, 255, 255, 255, gridStroke+15);
        grid.updateColor(i+3, 255, 255, 255, gridStroke+15);
      }
      else
      {
        grid.updateColor(i,   255, 255, 255, gridStroke);
        grid.updateColor(i+1, 255, 255, 255, gridStroke);
        grid.updateColor(i+2, 255, 255, 255, gridStroke);
        grid.updateColor(i+3, 255, 255, 255, gridStroke);  
      }
    }
  grid.endUpdateColors(); 
}



void load_data()
{
     
    for (int i = 0; i < max_points; i++)
    {
      coord_x[i] = random(rand_x)-rand_x/2;
      coord_y[i] = random(rand_y)-rand_y/2;
      coord_z[i] = random(rand_z);
    }


    points = new GLModel(this, max_points, POINTS, GLModel.DYNAMIC);
    points.initColors();
    points.setPointSize(1);
    /////////////////////////////
    // Update (load) Vertex data
    /////////////////////////////
   
      points.beginUpdateVertices();
      for (int i = 0; i < max_points; i++)
      {
        points.updateVertex(i, coord_x[i] + random(offset), coord_y[i] + random(offset), coord_z[i] + random(offset));
      }
      points.endUpdateVertices();


    /////////////////////////////
    // Update Vertex Colour
    /////////////////////////////
      points.beginUpdateColors();
      for (int i = 0; i < max_points; i++)
      {
        points.updateColor(i, 255, 255, 255, min_bright);
      }
      points.endUpdateColors();  
}


void bless()
{
      for (int i = 0; i < max_points; i++)
      {
        if(int(random(1000000))==1) blessed[i] = 255;
        if (blessed[i] > min_bright) blessed[i] = blessed[i] -2;
        if (blessed[i] <= min_bright) blessed[i] = blessed[i] + int(random(20));
      }
}

Thanks a lot for the example.

I tried to run GLGraphics but my development laptop but even the examples give me an error
GLException: Method "glGenBuffersARB" not avaliable

I think that the graphics card of the laptop is not compatible......

Im running the code in a iMac and gives me this error
OpenGL error 1281 at top endDraw(): invalid value
but it render on screen..... at a slow framerate(17)


Thanks again !!!

I tried on a pc machine --------- win7 - ati 5770-

Im still with this error, but works better, i say better because i can get 17fps
OpenGL error 1281 at top endDraw(): invalid value

I analice you code download the libray and reading examples, and i begin to understand how to use that

When you instance a GLModel, you put the number of points

points = new GLModel(this, max_points, POINTS, GLModel.DYNAMIC);

But my cloudpoint comes from a kinect, im using simple-openni to get all pixels from a user (this library works great !!!)
so i dont know the number of points, how can i deal with that.

I read your post, and using the maximun points avaliables is the way to go.
http://forum.processing.org/topic/getting-started-with-glgraphics

Its there another way of do that (doing a GLModel instance without knowing the number_points)

kinect = new SimpleOpenNI(0,this);
depthPoints = kinect.depthMapRealWorld();

Then to find the amount of points you use:

depthPoints.length