I guess you will find a part of the answer here: http://processing.org/learning/p3d/
see Textures-Chapter, (near the image of the berlin tv-tower): you just have to rotate a little bit, so use some matrix (see 3d Shapes-Chapter above on same page)

The points that you want to store- you mean them glowing lines that show where the planes flew? I think these are a combination of particle-effects at start/landing-location and some flat rectangular meshes like the tv-tower-example with a transparent texture. It could also be done through rotating the UV-values instead of rotating the mesh- which is probably the case - because you can see in the side-view that these flats show just the half of circles and the "animation" (those white dots before it becomes a glowing line) appear to be scaled - they have visibly different sizes: the longer the flight the larger the dots.

Hey, thanks alot for the reply return_true_if_false. Thanks for the link :) That helped.
About the second part, i guess i did not make my self very clear. (though anywhere i can find more about 'particle effect' you mentioned?)
But anyway, i am stuck as to how to start with this- 
For example, lets say i have about 22 origin and destinations. (obviously repeating positions(XY coordinate of those places). So should i-

You might store your 22 airports as PVector, fine.

But they're not points in the Processing-Window: they are in first place points somewhere on the surface of the mesh which displays the earth-texture - so they are just points on the map of the earth.

As first you should normalize the XY- coordinates so they all have values from 0.0 to 1.0.

Therefore calculate the positions like that:
maybe Kennedy Airport is located at Pixel 25, 77 of your texture
the textures-size has a width of 400 and a height of 300 pixels.
Divide 25 by 400 and 77 by 300 to get values from 0.0 to 1.0,
now Kennedy Airport Pixel is around Position 0.0625, 0.2567,
store them in imaginary forum-variables: KAP.H and KAP.V
(I use H and V for horizontal/vertical to not mess them up with coordinates in world-space)

You have the corners of the mesh: those vertex-thingamagickies.
They lay somewhere in space at some X,Y and Z position. Don't care where exactly, but we know Kennedy Airport is located at 6.25% of the width and at 25.67% of the height.
The top left corner-vertex (TLC) of the earth-mesh represents H 0.0, V 0.0 the bottom right corner-vertex (BRC) represents H 1.0, V 1.0 of the maps image. Since mesh and texture are fortunately both rectangular we don't need to worry that much and can use a simple formula to create two vectors which point horizontal and vertical relative to the mesh surface:

HVector.X = TRC.X - TLC.X
HVector.Y = TRC.Y - TLC.Y
HVector.Z = TRC.Z - TLC.Z

VVector.X = BLC.X - TLC.X
VVector.Y = BLC.Y - TLC.Y
VVector.Z = BLC.Z - TLC.Z

Now we got the directions and length of the horizontal and vertical borders.
The position of the TLC (TopLeftCorner) we have also.

now find Kennedy-Airport locations map-coordinates on the mesh-surface like this:

 X = TLC.X + HVector.X * KAP.H + VVector.X * KAP.V
 Y = TLC.Y + HVector.Y * KAP.H + VVector.Y * KAP.V
 Z = TLC.Z + HVector.Z * KAP.H + VVector.Z * KAP.V

Result (X,Y,Z) is the position of Kennedy-Airport as on the untransformed and unrotated earth-mesh.

If you use a matrix to rotate the earth-mesh now, draw Kennedy Airport whithin that rotation-block (before calling popMatrix or pushing another one in) or use the same rotation and translation values as for the earth-mesh. If you use some scaling-methods onto the mesh you'll have to scale HVector and VVector by the same value.

If you're done with Kennedy Airport go on to LAX 



 

EXCELLENT! This really gave a way better picture. So nicely explained. Thank you.

Hi asdf

As promised, here's some code that achieves the basics of what you are looking for. I've deviated from the previous contributors post because I think you were getting confused by the normalised vectors. The approach below is less generalised but perhaps a little easier to understand.

I'm using a map image I found on wikipedia and using the coordinates you supplied the line ends up in the wrong place but it could work for you using the img you've already chosen to base the coordinates on. It's easy enough to change them if not.

I haven't implemented the bezier curves describing the flight path. Just want to check you are comfortable with the basics first. Anyway here's the code...

1. PImage img;
   PVector delhi;
   PVector mumbai;
   
   void setup() {
     size(1000, 600, P3D);
   
     img = loadImage("map.png");
     textureMode(NORMAL);
   
     delhi = new PVector(427, 0, 234);//my coordinates are nearly the same as yours but note that I've swapped the Y and Z values.
     mumbai = new PVector(168, 0, 324);
   }
   
   void draw() {
     background(0);
     translate(width/2, height/2, 0);//translate the transformation point to the centre of the screen
     rotateX(-PI/4);//apply a rotation about the x axis to tilt the plane we will be drawing to
     rotateY(mouseX/200.0);//alllow us to pan round the map by moving the mouse
     scale(0.6);//you can apply a scaling factor here to suit the size of your img
   
     /*translate the transformation point one last time by half the width
      and half the height of the image. Note I'm translating the Z axis
      not the Y axis. This is so the image lies flat on the XZ plane and
      so my PVector coordinates are mapped correctly.
      */
     translate(-img.width/2, 0, -img.height/2);
    
   
     //draw the plane textured with the image
     beginShape();
     texture(img);
     vertex(0, 0, 0, 0, 0);//texture uv coordinates are the last two numbers
     vertex(img.width, 0, 0, 1, 0);
     vertex(img.width, 0, img.height, 1, 1);
     vertex(0, 0, img.height, 0, 1);
     endShape();
   
     //draw a line connecting delhi to mumbai
     stroke(255, 0, 0);
     strokeWeight(2);
     line(delhi.x, delhi.y, delhi.z, mumbai.x, mumbai.y, mumbai.z);
     noStroke();
   }