Picking in PGraphics

Contributed Library Questions

chicoatomo

in Contributed Library Questions • 1 year ago

Hello.

I'm trying to use the picking library, but I have a problem and I don't know how to solve it.

I have this code that works correctly:

import picking.*;

Picker picker;

void setup()

{

size(500, 500, P3D);

picker = new Picker(this);

}

void draw()

{

camera(-20, -20, 50, 0, 0, 0, 0, 1, 0);

rotateY(10);

background(255);

lights();

picker.start(1);

fill(32,64,128);

box(10,10,10);

picker.start(2);

translate(20,0,0);

fill(255,0,0);

box(10,10,10);

}

void mouseClicked()

{

int id = picker.get(mouseX, mouseY);

println(id);

}

But in my program I need to draw in a PGraphics object. Then the picking doesn't work.

How could I fix this???

This code doesn't work

import picking.*;

Picker picker;

PGraphics render;

void setup()

{

size(500, 500, P3D);

render = createGraphics(500,500,P3D);

picker = new Picker(this);

}

void draw()

{

render.beginDraw();

render.camera(-20, -20, 50, 0, 0, 0, 0, 1, 0);

render.rotateY(10);

render.background(255);

render.lights();

picker.start(1);

render.fill(32,64,128);

render.box(10,10,10);

picker.start(2);

render.translate(20,0,0);

render.fill(255,0,0);

render.box(10,10,10);

render.endDraw();

image(render,0,0);

}

void mouseClicked()

{

int id = picker.get(mouseX, mouseY);

println(id);

}

Best regards and thanks in advance

Replies(6)

quarks

Re: Picking in PGraphics

1 year ago

I have not used this library but you might try this.

Change the line
picker = new Picker(this);

to this
picker = new Picker(render);

chicoatomo

Re: Picking in PGraphics

1 year ago

Hello

That was one of the first things I tried but does not work because

"Picker" needs a PApplet, not a PGraphics

Thanks in any case.

I'm trying to understand the java code of the library but something escapes me.

Any help?

I need to make picking a PGraphics

calsign

A potentially problematic way to go about doing this would involve drawing the PGraphics object to the canvas, performing your picking, and then drawing over the PGraphics before the end of the frame...
Just a thought...

chicoatomo

Re: Picking in PGraphics

1 year ago

Hello again

I'm trying a new way. Instead of drawing in a PGraphics, I'm trying to draw using a new PApplet.

For that purpose, I have had to delete some lines in the code of the picking library. (Picker.java)

/*
Provides an easy way to pick an object in a 3D scene.
(c) copyright
This library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
This library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General
Public License along with this library; if not, write to the
Free Software Foundation, Inc., 59 Temple Place, Suite 330,
Boston, MA 02111-1307 USA
*/
package picking;
import processing.core.*;
/**
* A Picker object helps you to process picking.
*
* @example Simple
* @author Nicolas Clavaud <antiplastik@gmail.com>
*
*/
public class Picker {
/**
* Processing applet
*/
protected PApplet parent;
/**
* Main picking buffer
* Direct access to the buffer is allowed so you can draw shapes that
* you wouldn't like to draw on the main screen (like bounding boxes).
*/
public Buffer buffer;
public Picker(PApplet parent_) {
parent = parent_;
buffer = (Buffer)parent.createGraphics(parent.width,parent.height,"picking.Buffer");
buffer.callCheckSettings();
if (parent.recorder == null) {
parent.recorder = buffer;
}
buffer.background(0);
//parent.registerPre(this);
//parent.registerDraw(this);
}
/*
public void pre() {
buffer.beginDraw();
if (parent.recorder == null) {
parent.recorder = buffer;
}
}
public void draw() {
buffer.endDraw();
}
*/
/**
* Begins recording object(s)
*
* @param i Object ID
*/
public void start(int i) {
if (i < 0 || i > 16777214) {
PApplet.println("[Picking error] start(): ID out of range");
return;
}
if (parent.recorder == null) {
parent.recorder = buffer;
}
buffer.setCurrentId(i);
}
/**
* Stops/pauses recording object(s)
*/
public void stop() {
parent.recorder = null;
}
/**
* Resumes recording object(s)
*/
public void resume() {
if (parent.recorder == null) {
parent.recorder = buffer;
}
}
/**
* Reads the ID of the object at point (x, y)
* -1 means there is no object at this point
* @param x X coordinate
* @param y Y coordinate
* @return Object ID
*/
public int get(int x, int y) {
return buffer.getId(x, y);
}
/**
* Get the buffer
* @return Buffer
*/
public PGraphics getBuffer() {
return buffer;
}
}

This code fails, because the PApplet is not correctly initialized.

import picking.*;

PApplet applet;

Picker picker;

void setup()

{

size(500,500,P2D);

applet = new PApplet();

applet.width = 500;

applet.height = 500;

applet.init();

applet.start();

applet.g = applet.createGraphics(500,500,P3D);

println(applet);

picker = new Picker(applet);

}

void draw()

{

picker.buffer.beginDraw();

applet.g.beginDraw();

applet.g.background(255);

applet.g.noSmooth();

applet.g.noStroke();

applet.g.lights();

applet.g.camera(20,20,50,0,0,0,0,1,0);

picker.start(1);

applet.g.fill(0,255,0);

applet.g.box(10,10,10);

picker.start(2);

applet.translate(20,0,0);

applet.g.fill(0,0,255);

applet.g.sphere(10);

applet.g.endDraw();

image(applet.g,0,0);

picker.buffer.endDraw();

}

void mouseClicked()

{

int id = picker.get(mouseX, mouseY);

println(id);

}

Please any idea about how to initialize the PApplet correctly?

Or how to pick objects in a PGraphics using the picking library?

Thanks in advance!

antiplast..

Re: Picking in PGraphics

1 year ago

Actually the Picking library uses the useful PApplet.recorder object which is echoing all drawing/camera events applied to the PApplet canvas.

There is no such recorder in the PGraphics object, so for this reason, you need to echo everything yourself to the Picker.buffer object.

Here is your code, with a few modifications (I did not echo the useless background() , lights()... methods to keep it clear but it wouldn't do any harm) :

import picking.*;
Picker picker;
PGraphics render;
void setup()
{
size(500, 500, P3D);
render = createGraphics(500,500,P3D);
picker = new Picker(this);
}
void draw()
{
render.beginDraw();
render.camera(-20, -20, 50, 0, 0, 0, 0, 1, 0);
picker.buffer.camera(-20, -20, 50, 0, 0, 0, 0, 1, 0); // echo to picker.buffer
render.rotateY(10);
picker.buffer.rotateY(10); // echo to picker.buffer
render.background(255);
render.lights();
picker.start(1);
render.fill(32,64,128);
render.box(10,10,10);
picker.buffer.box(10,10,10); // echo to picker.buffer
picker.start(2);
render.translate(20,0,0);
picker.buffer.translate(20,0,0); // echo to picker.buffer
render.fill(255,0,0);
render.box(10,10,10);
picker.buffer.box(10,10,10); // echo to picker.buffer
render.endDraw();
image(render,0,0);
}
void mouseClicked()
{
int id = picker.get(mouseX, mouseY);
println(id);
}

This is way less handy, though. Another way is to group your object drawing into methods, then call the method on both your PGraphics object and the Picker.buffer object. Like this :

import picking.*;
Picker picker;
PGraphics render;
void setup()
{
size(500, 500, P3D);
render = createGraphics(500,500,P3D);
picker = new Picker(this);
}
void draw()
{
render.beginDraw();
drawInit(render);
drawInit(picker.buffer);
picker.start(1);
drawObject1(render);
drawObject1(picker.buffer);
picker.start(2);
drawObject2(render);
drawObject2(picker.buffer);
render.endDraw();
image(render,0,0);
}
void drawInit(PGraphics pg) {
pg.camera(-20, -20, 50, 0, 0, 0, 0, 1, 0);
pg.rotateY(10);
pg.background(255);
pg.lights();
}
void drawObject1(PGraphics pg) {
pg.fill(32,64,128);
pg.box(10,10,10);
}
void drawObject2(PGraphics pg) {
pg.translate(20,0,0);
pg.fill(255,0,0);
pg.box(10,10,10);
}
void mouseClicked()
{
int id = picker.get(mouseX, mouseY);
println(id);
}

Hope it helped.

chicoatomo

Re: Picking in PGraphics

1 year ago

Antiplastik, thank you very much for the reply.

Now I fully understand the use of the object PApplet.recorder and operation of the picking library.

Just one more question.

Then it would be possible to use a different PApplet to paint and select.

I mean:

Imagine that instead of using an object to paint PGraphics

I declare an object:

PApplet my_applet

and use my_applet.g to paint and use my_applet.recorder for the picking.

I don't know how to init the new PApplet.

import picking.*;

PApplet applet;

Picker picker;

void setup()

{

size(500,500,P2D);

applet = new PApplet();

applet.width = 500;

applet.height = 500;

applet.init();

applet.start();

applet.g = applet.createGraphics(500,500,P3D);

println(applet);

picker = new Picker(applet);

}

void draw()

{

picker.buffer.beginDraw();

applet.g.beginDraw();

applet.g.background(255);

applet.g.noSmooth();

applet.g.noStroke();

applet.g.lights();

applet.g.camera(20,20,50,0,0,0,0,1,0);

picker.start(1);

applet.g.fill(0,255,0);

applet.g.box(10,10,10);

picker.start(2);

applet.translate(20,0,0);

applet.g.fill(0,0,255);

applet.g.sphere(10);

applet.g.endDraw();

image(applet.g,0,0);

picker.buffer.endDraw();

}

void mouseClicked()

{

int id = picker.get(mouseX, mouseY);

println(id);

}

Top Reply