PGraphics in 3D? PGraphics and PeasyCam?

Chrisir

PGraphics in 3D? PGraphics and PeasyCam?

in Contributed Library Questions • 1 year ago

Hello,

I was just pondering another thread

http://forum.processing.org/topic/is-pgraphics-the-only-way-to-solve-the-memory-problems-in-processing

when it occured to me whether PGraphics works in 3D? And if PGraphics and PeasyCam work together?

I think it does not (for both).

But I can call createGraphics with P3D as a renderer and I can call

pg.line(40, 40, 100,
40, 40, 40);

with 3D lines / coors.

But the result with peasyCam shows a 2D image which rotates.

My hope was to have a 3D tree e.g. that in stored as a PGraphics.

Is that possible?

Thank you!

Greetings, Chrisir

//
// test on PGraphics
import peasy.org.apache.commons.math.*;
import peasy.*;
import peasy.org.apache.commons.math.geometry.*;
//
PGraphics pg;
PeasyCam pCamera;
//
void setup() {
size(800, 800, P3D);
pg = createGraphics(480, 480, P3D);
//
pg.beginDraw();
pg.background(102);
pg.stroke(255);
pg.line(40, 40, 100,
40, 40, 40);
pg.line(140, 40, 100,
140, 140, -90);
pg.endDraw();
pCamera = new PeasyCam(this, 300);
}
//
void draw() {
background(50);
image(pg, 10, 10);
}

Replies(6)

thomas.di..

Re: PGraphics in 3D? PGraphics and PeasyCam?

1 year ago

if you want the peasycam to affect the PGraphics-renderer, and not the default renderer, you could replace the PGraphic matrix with the one from the current renderer, and reset the matrix of the current renderer with the inital one.

example:

PGraphics pg;
PeasyCam cam;
PMatrix mat_scene; // to store initial PMatrix
public void setup() {
size(800, 800, P3D);
mat_scene = getMatrix();
pg = createGraphics(width, height, P3D);
cam = new PeasyCam(this, 300);
}
public void draw() {
background(50);
pg.beginDraw();
{
pg.setMatrix(getMatrix()); // replace the PGraphics-matrix
pg.background(102);
pg.stroke(255, 0, 0); pg.line(0, 0, 0, 100, 0, 0);
pg.stroke(0, 255, 0); pg.line(0, 0, 0, 0, 100, 0);
pg.stroke(0, 0, 255); pg.line(0, 0, 0, 0, 0, 100);
pg.stroke(0);
pg.fill(200);
pg.rect(10, 10, 200, 100);
}
pg.endDraw();
setMatrix(mat_scene); // replace the PeasyCam-matrix
image(pg, 10, 10, 500, 500);
fill(255, 100);
rect(400, 400, 100, 200);
}

hth, thomas

Chrisir

Re: PGraphics in 3D? PGraphics and PeasyCam?

1 year ago

I'll have a look, thanks!

Chrisir

Re: PGraphics in 3D? PGraphics and PeasyCam?

1 year ago

Apart from peasycam : PGraphics can get 3D stuff like line but can't really output them in fact, right?

So I can't use PGraphics here but need to use beginShape or load .obj or similar from HD, right?

I dunno much about 3D formats such as obj? Which are the Most common and which are free Programs to make them? Where can I find ressources of free obj or similar?

Thanks!

Chrisir

andres

Re: Re: PGraphics in 3D? PGraphics and PeasyCam?

1 year ago

Right now, the P3D renderer includes built-in support for the .obj format. Take a look at the LoadOBJ example in the opengl/IO category.

Once you have loaded an obj model into a PShape object, you can draw it either on the main surface or on an offscreen PGraphics canvas. Below you have the loadOBJ example modified to work with a P3D canvas created with createGraphics:

PShape rocket;
PGraphics pg;
public void setup() {
size(640, 360, P3D);
rocket = loadShape("rocket.obj");
pg = createGraphics(200, 200, P3D);
}
public void draw() {
background(150);
pg.beginDraw();
pg.background(0);
pg.lights();
pg.translate(pg.width/2, pg.height/2 + 100, -200);
pg.rotateX(PI);
pg.rotateY(frameCount * 0.01f);
pg.shape(rocket);
pg.endDraw();
image(pg, mouseX, mouseY);
}

amnon.owed

Re: PGraphics in 3D? PGraphics and PeasyCam?

1 year ago

As far as I know, there is no difference between P3D directly in size() and P3D in createGraphics(). So just like you can have 3D stuff in a 'normal' sketch, you should be able to have 3D stuff in a PGraphics. The only thing is that you should also do the camera(), translate(), rotate() etc. commands on the PGraphics if you want to have an impact. Or follow Thomas' instructions if you want peasycam to affect the PGraphics.

My hope was to have a 3D tree e.g. that in stored as a PGraphics.

This doesn't make sense to me. Storing a 3D object is different from displaying it. A PGraphics is about displaying things in pixels. Storing, creating, loading etc. objects is something else.

Chrisir

Re: PGraphics in 3D? PGraphics and PeasyCam?

1 year ago

@andres : thanks!!

@amnon : thanks. I guess this was my Initial question: PGraphics can Take 2D and 3D Input, but when you display it, it behaves only 2D (a 2D image). It would be cool if it was also 3D

Top Reply