Persistent Button Press

Programming Questions

helmutapp..

in Programming Questions • 2 months ago

Hello,

Button question here...

I have a voting table I have rigged up to joystick buttons to vote items up or down.

When I vote, the table is sorted to bring up a different entry.

My problem is that when the new entry comes up, it is automatically voted on if the button is being held down.

(the same happened with the keyboard, I thought the buttons might be momentary)

I'm sure there is a way to stop the voting for a new entry until a button release and a new press, but I could use a nudge...

Happy to show code if asked, but it is a bit spread out over classes (I will collapse it when I see if my multiple monitor displays work).

Replies(14)

PhiLho

Re: Persistent Button Press

2 months ago

My guess: you check the key press in draw() instead of using the keyPressed() method. In this case, the value of the key is unchanged until another key is pressed (or if you reset it yourself).

GoToLoop

A more traditional approach -> Use both keyPressed() & keyReleased().
Within keyPressed() you register in a boolean variable whether a key you're tracking got pressed.
And within keyReleased(), you finally turn that off.

Check this simple online example:
http://studio.processingtogether.com/sp/pad/export/ro.9bY07S95k2C2a/latest

P.S.: Notice that neither ENTER, RETURN nor ' ' keys are using this technique.
So they keep firing up if any of them are kept held down.
It is UP, DOWN, LEFT & RIGHT which follow the scheme and don't get any auto-repeat.

helmutapp..

Re: Persistent Button Press

2 months ago

Thanks for replying PhiLho...

here is a snippet (using ProControll)

if(button1.pressed()){down=true;} else{down=false;}

It works, but I would like the button to only fire once, not be firing continuously if held down, does that make sense?

Are you saying I should put that in keyPressed() instead of draw() ?

BTW, this was meant to be in Programming Questions :), am I able to move it?

Thanks for looking.....

helmutapp..

Re: Persistent Button Press

2 months ago

Thanks GoTo

I was using that for my earlier up and down arrow testing;

void keyPressed(){

if (key == CODED) {

if (keyCode == UP) {up=true;}

if (keyCode == DOWN) {down=true;}

}

void keyReleased() {

if (key == CODED) {

if (keyCode == UP) {up=false;}

if (keyCode == DOWN) {down=false;}

}

void display(){

for( int i=0; i < entriesVotingArray.length; i++ ){

Entry myVEntry = (Entry) entriesVotingArray[i];

Entry myREntry = (Entry) entriesVotingArray[myRandom];

if (i==0){

if (!myVEntry.voted) {

myVEntry.display();

myVEntry.votePosUpdate();

if (up==true) {myVEntry.voting(1);}

if (down==true) {myVEntry.voting(-1);}

}

else if (myVEntry.voted) {

myREntry.display();

myREntry.votePosUpdate();

if (up==true) {myREntry.voting(1); myRandom=int(random(entriesVotingArray.length));}

if (down==true) {myREntry.voting(-1);myRandom=int(random(entriesVotingArray.length));}

}

But the issue is when the entry voted on is marked as voted, the table sorting moves another entry up to the 0 index, and if you have the arrow key still pressed, it just voted on that and brings up another entry. I'd like to stop the voting unless you release and press again, but am having trouble placing the code for that....

PS, from the behavior, it feels like the arrows do auto-repeat, unless the trouble is with my boolean and I need some sort of state machine. At any rate, I may need that for the joystick buttons if they are auto. But the final buttons are momentary microswitch arcade buttons, does anyone know if they just fire once?

Anyway, thanks for your attention.

GoToLoop

Re: Persistent Button Press

2 months ago

... from the behavior, it feels like the arrows do auto-repeat,...

You're right on that. However, as soon as a key is released
due to the auto-repeat feature, it gets re-pressed afterwards.
For draw()'s point-of-view, a button state never becomes false due to auto-repeat feature!

I've added an additional line to my example to log the north 's state at the console.
Keep UP or W held down and you'll notice it's continuously true!

/* Move Object Example (v2.21)
 * by GoToLoop (2012/Dec)
 *
 * http://forum.processing.org/topic/keypressed-problem
 *
 * http://forum.processing.org/topic/
 * how-to-move-an-object-diagonally-using-keycode
 *
 * http://forum.processing.org/topic/
 * how-do-i-make-an-object-disappear-upon-collision
 *
 * http://studio.processingtogether.com/sp/pad/export/ro.9bY07S95k2C2a/latest
 */

// Object's variables:
static int x, y;     // positions
int w, h;            // dimensions
int ww, hh;          // radii
boolean ballOrBox;   // current shape

// Object's constants:
final static byte  SPX  = 30, SPY = 20; // speed movement
final static byte  BOLD = 4;            // border thickness
final static color COLOUR = #0000FF;    // #blue

// General constants:
final static byte  FPS = 60;
final static color BG  = #FFFF00;       // #yellow

// General boolean variables:
static boolean north, south, west, east;

void initVars() {
  x = width>>1;    // center of screen 
  y = height>>1;

  w = width/10;    // 1/10th size of screen
  h = height/10;

  ww = w>>1;       // distances from center (radii)
  hh = h>>1;
}

void setup() {
  size(800, 600);
  smooth();            // turn on drawing smoothness
  //noLoop();            // turn draw() callback off
  frameRate(FPS);      // set frames / second

  rectMode(CENTER);    // coordinates are relative from center
  ellipseMode(CENTER);

  fill(COLOUR);        // object's paint color
  stroke(0);           // #black
  strokeWeight(BOLD);  // object's border thickness

  initVars();
}

void draw() {
  background(BG);

  moveObj();
  checkBorder();

  if (ballOrBox)    ellipse(x, y, w, h);
  else              rect(x, y, w, h);
  
  print(north + " - ");
}

void keyPressed() {
  final int k = keyCode;

  if (k == ' ' | k == ENTER | k == RETURN)
    ballOrBox = !ballOrBox;

  else if (k == UP    | k == 'W')   north = true;
  else if (k == DOWN  | k == 'S')   south = true;
  else if (k == LEFT  | k == 'A')   west  = true;
  else if (k == RIGHT | k == 'D')   east  = true;

  //redraw();   //  queue draw()
}

void keyReleased() {
  final int k = keyCode;

  if      (k == UP    | k == 'W')   north = false;
  else if (k == DOWN  | k == 'S')   south = false;
  else if (k == LEFT  | k == 'A')   west  = false;
  else if (k == RIGHT | k == 'D')   east  = false;

  //redraw();   //  queue draw()
}

static void moveObj() {
  if (north)  y -= SPY;
  if (south)  y += SPY;
  if (west)   x -= SPX;
  if (east)   x += SPX;
}

void checkBorder() {
  if (x > width-ww)    x = width-ww;
  else if (x < ww)     x = ww;

  if (y > height-hh)   y = height-hh;
  else if (y < hh)     y = hh;
}

GoToLoop

Re: Persistent Button Press

2 months ago

But the issue is when the entry voted on is marked as voted, the table sorting moves another entry up to the 0 index, and if you have the arrow key still pressed, it just voted on that and brings up another entry.

Perhaps a custom resetKeyStates() can solve that?

void resetKeyStates() {
  north = south = west = east = false;
}

helmutapp..

Re: Persistent Button Press

2 months ago

Cool, thanks.

How do I stop that behavior?

What I need is a short or single momentary button where one pulse is sent at the first pressing, then only sent again after a release and subsequent press.

timer? state machine? booleans?

helmutapp..

Re: Persistent Button Press

2 months ago

Ah, replied before I saw the resetKeyStates() :)

Will look at that, thanks.....

GoToLoop

Re: Persistent Button Press

2 months ago

If the above is not enough, you may try out creating an extra boolean variable to flag
it's not ready to accept key state changes for a while.

Check it out how:

void keyPressed() {
  if (isBusy)  return;
  
  final int k = keyCode;

  if (k == ' ' | k == ENTER | k == RETURN)
    ballOrBox = !ballOrBox;

  else if (k == UP    | k == 'W')   north = true;
  else if (k == DOWN  | k == 'S')   south = true;
  else if (k == LEFT  | k == 'A')   west  = true;
  else if (k == RIGHT | k == 'D')   east  = true;
}

So, when your code makes the vote sorting thing, you make isBusy = true;
and also call resetKeyStates();

For as long as isBusy = true; no key state changes will occur.
Of course, you have to stipulate a time frame to set isBusy = false; again!

helmutapp..

Re: Persistent Button Press

2 months ago

Good one,

I was thinking of timing and am trying thi:

if(button4.pressed()){

up=true;

if (millis() - timer >= 500){

}

else{

up=false;

timer = millis();

}

helmutapp..

Re: Persistent Button Press

2 months ago

That looks like a good roadmap, I'll look into that, thanks!

GoToLoop

Re: Persistent Button Press

2 months ago

Here's my approach:
Let's make-believe that key BACKSPACE or 'J' activates the vote sorting thing.
I made it so that for a span of about 3 seconds, no key state changes would be allowed!
For that, I'm using 1 more constant (PAUSE) and 1 more variable (frameDelay).

Function draw() is invoked at 60 frames per second -> FPS = 60.
Let's say I wanna wait 3 seconds to re-activate key changes. I need the triple of FPS -> PAUSE = 3*FPS.

When either BACKSPACE or 'J' is hit, isBusy = true & resetKeyStates() is called.
Also, frameDelay = current frameCount + number of frames to wait (PAUSE).
Then, line -> if (isBusy) return; within keyPressed() forbids the rest of the block to run.
So no key changes happen as long as isBusy = true!

At the end of draw(), there is -> if (frameCount == frameDelay) isBusy = false;
which turns off the busy state when current frameCount reaches stipulated frameDelay.

Well, take a look at it for yourself:

/* Move Object Example Modded (v1.0)
 * by GoToLoop (2013/Jul)
 *
 * http://forum.processing.org/topic/keypressed-problem
 *
 * http://forum.processing.org/topic/
 * how-to-move-an-object-diagonally-using-keycode
 *
 * http://forum.processing.org/topic/
 * how-do-i-make-an-object-disappear-upon-collision
 *
 * http://forum.processing.org/topic/persistent-button-press
 *
 * http://studio.processingtogether.com/sp/pad/export/ro.9bY07S95k2C2a/latest
 */

// Object's variables:
static int x, y;     // positions
int w, h;            // dimensions
int ww, hh;          // radii
boolean ballOrBox;   // current shape

// Object's constants:
final static byte  SPX  = 30, SPY = 20; // speed movement
final static byte  BOLD = 4;            // border thickness
final static color COLOUR = #0000FF;    // #blue

// General constants:
final static short FPS = 60, PAUSE = 3*FPS; // 3 seconds of wait
final static color BG  = #FFFF00;       // #yellow

// General boolean variables:
static boolean north, south, west, east;

// Timer variables:
boolean isBusy;
int frameDelay;

void initVars() {
  x = width>>1;    // center of screen 
  y = height>>1;

  w = width/10;    // 1/10th size of screen
  h = height/10;

  ww = w>>1;       // distances from center (radii)
  hh = h>>1;
}

void setup() {
  size(800, 600);
  smooth();            // turn on drawing smoothness
  frameRate(FPS);      // set frames / second

  rectMode(CENTER);    // coordinates are relative from center
  ellipseMode(CENTER);

  fill(COLOUR);        // object's paint color
  stroke(0);           // #black
  strokeWeight(BOLD);  // object's border thickness

  initVars();
}

void draw() {
  background(BG);

  moveObj();
  checkBorder();

  if (ballOrBox)    ellipse(x, y, w, h);
  else              rect(x, y, w, h);

  // Re-allows key state changes when a certain # of frame counts has passed:
  if (frameCount == frameDelay)  isBusy = false;
}

void keyPressed() {
  if (isBusy)  return;  // Prohibit key state changes!

  final int k = keyCode;

  if (k == ' ' | k == ENTER | k == RETURN)
    ballOrBox = !ballOrBox;

  else if (k == UP    | k == 'W')   north = true;
  else if (k == DOWN  | k == 'S')   south = true;
  else if (k == LEFT  | k == 'A')   west  = true;
  else if (k == RIGHT | k == 'D')   east  = true;

  else if (k == BACKSPACE | k == 'J') {
    isBusy = true;                    // stop key state changes!
    resetKeyStates();                 // zero all key states!
    frameDelay = frameCount + PAUSE;  // reactivation alarm duration
  }
}

void keyReleased() {
  final int k = keyCode;

  if      (k == UP    | k == 'W')   north = false;
  else if (k == DOWN  | k == 'S')   south = false;
  else if (k == LEFT  | k == 'A')   west  = false;
  else if (k == RIGHT | k == 'D')   east  = false;
}

static void resetKeyStates() {
  north = south = west = east = false;
}

static void moveObj() {
  if (north)  y -= SPY;
  if (south)  y += SPY;
  if (west)   x -= SPX;
  if (east)   x += SPX;
}

void checkBorder() {
  if (x > width-ww)    x = width-ww;
  else if (x < ww)     x = ww;

  if (y > height-hh)   y = height-hh;
  else if (y < hh)     y = hh;
}

helmutapp..

Re: Persistent Button Press

2 months ago

This is great food for thought - I'm just sorting out my 6 monitor setup, but later today I will try to code it up based on this.

Thanks so much!

helmutapp..

Re: Persistent Button Press

2 months ago

Think that's done it!!!

I've had to modify it, as my sorting update is running in another class and was on a timer, that messed things up.

But it made me realise I only want to update the sorting when there is a vote (or maybe a new entry)

So this seems to work better all round:

(thanks for busting through that mental block, GoTo, I couldn't have done it without you!!!)

void display(){
myVSorting.display();
if (someVoted) { // maybe || someEntry also
myVSorting.update();
updated=true;
someVoted=false; //maybe someEntry=false;
}
if (updated){
isBusy=true;
resetKeyStates();
frameDelay = frameCount + (PAUSE);
updated=false;
}
if (frameCount == frameDelay){
isBusy = false;
}
}