PeasyCam Conical Movement

datadream..

in Contributed Library Questions • 2 years ago

I am attempting to use the PeasyCam library to accomplish a birds eye view of my subject matter while constantly rotating in a circular movement above it. The camera should maintain a downward view towards the subject while essentially tracking in a circle.

At first I tried simply rotating the camera from looking directly towards my subject plane to the downward angle I desired. I then tried to apply a continual camera.rotateZ(value) in the draw loop, but since the peasycam library uses a type of arcball matrix transformation, it simply causes that current view to be rotated on the new Z axis instead of the world Z axis.

I could use a sin/cos function to make the camera orbit the subject plane by continually updating its position on each frame, as well as update the camera.lookAt() to make sure it is constantly pointed at the same x/y/z position of my subject, but I have my doubts about how the roll of the camera will be handled.

Some people may suggest simply doing a translate to center everything in the world and rotating the subject itself, but I would ideally like to keep all view changes isolated within the camera object.

Has anyone had experience doing this?

Replies(9)

amnon.owed

Re: PeasyCam Conical Movement

2 years ago

Much easier without PeasyCam...

import processing.opengl.*;
float distance = 75;
void setup() {
size(800,800,OPENGL);
perspective(PI/3.0, width/height,1,100000);
strokeWeight(5);
stroke(255);
}
void draw() {
background(0);
float x = cos(0.025*frameCount) * distance;
float y = -distance/2;
float z = sin(0.025*frameCount) * distance;
camera(x,y,z, 0,0,0, 0,1,0);
fill(255,0,0);
box(30);
}

datadream..

Re: PeasyCam Conical Movement

2 years ago

Thanks for the response, amnon.owed. My reason for using PeasyCam is to allow the user to freely move the view around the subject without dealing with the unintuitive aspects of a non-arcball type of rotation. Then after a period of inactivity, the camera would animate back to it's original position and continue the standard rotating birds-eye view.

datadream..

Re: PeasyCam Conical Movement

2 years ago

Still struggling with this. I tried using the camera function amnon.owed suggested, but it's providing undesirable results from the graphics I need to render to the HUD, not to mention incorporating a nice interactive control mode along with this increases the amount of time I need to put into just the camera code, neglecting what I am doing on the visualization itself (the time frame towards the deadline is closing in rapidly).

Apparently there's not even a setPosition() method for the PeasyCam object, so I can't move it about in a circular motion and then apply the lookAt() command like I originally thought I could. Instead, it seems like I need to be able to rotate the camera continually on all three axis, with varying amounts, in order to get it to move to the position I desire each frame while retaining the proper camera roll relative to the visual content.

I thought PeasyCam was supposed to be easy peasy. There has got to be a better way.

datadream..

Re: PeasyCam Conical Movement

2 years ago

Looking through the OCD documentation, I basically want the camera.circle() method (the camera orbits around the target at the current elevation)... but I don't think PeasyCam has such a method. I would much rather use PeasyCam as I am easily able to draw things to the HUD (which is critical) and I am accomplishing great interactive control of the camera (also fairly critical).

MrFeinberg

Re: PeasyCam Conical Movement

2 years ago

PeasyCam simply is not designed for what you're trying to do. It's intended to be a quick way to provide a mouse-drivable camera for quick sketching of a 3D idea. It's not meant to combine the flexibility of raw camera control with the drivability of OCD!

Just look at the PeasyCam source code to learn how to implement your own HUD. It's about 6 lines of code.

datadream..

Re: PeasyCam Conical Movement

2 years ago

Thanks for the reply, MrFeinberg. I'm continuing to use your library with a few workarounds in an attempt to achieve the desired effect in a similar way. While you're on, I'd appreciate it if you could take a look at my other question regarding PeasyCam as well: PeasyCam flickering on reset.

rbrauer

Re: PeasyCam Conical Movement

2 years ago

Did you ever get this implemented with PeasyCam? I wanted to try it out. I don't know if this is exactly what you wanted, but its not to bad I think.

import peasy.*;
import peasy.org.apache.commons.math.*;
import peasy.org.apache.commons.math.geometry.*;

PeasyCam pc;
CameraState state;
long deadTime;
boolean iniDead, start;

void setup() {
  size(400,400,P3D);
  pc = new PeasyCam(this, 0,0,0, 200);
  state = pc.getState();
}

void draw() {
  if(mouseX-pmouseX == 0 && mouseY-pmouseY == 0) {
    if(!iniDead) {
      deadTime = millis();
      iniDead = true;
    }
    if(millis()-deadTime >= 2000) {
      start = true;
      float[] look = pc.getLookAt();
      double disn = pc.getDistance();
      float[]rot = pc.getRotations();
      Rotation rotn = new Rotation(RotationOrder.XYZ, 
        (double)rot[0], (double)rot[1], (double)rot[2]);
      Rotation rotd = new Rotation(RotationOrder.XYZ,0,0,-.01);
      Vector3D npos = new Vector3D(
        (double)look[0], (double)look[1], (double)look[2]);
      state = new CameraState(rotd.applyTo(rotn), npos, disn);
    }
  } else {
    state = pc.getState();
    start = false;
    iniDead = false;
  }

  background(204);
  if(start)pc.setState(state, 0);
  box(25);
  pushMatrix();
  translate(0,0,-13);
  rect(-50,-50,100,100);
  popMatrix();
}

nakednous

Re: PeasyCam Conical Movement

2 years ago

Hi,

You can also use proscene and set a constraint:

import remixlab.proscene.*;
Scene scene;
AxisPlaneConstraint constraint;
void setup() {
size(640, 360, P3D);
//Scene instantiation
scene = new Scene(this);
scene.camera().setPosition(new PVector(0,200,200));
scene.camera().lookAt(scene.center());
constraint = new WorldConstraint();
constraint.setRotationConstraintType(AxisPlaneConstraint.Type.AXIS);
constraint.setRotationConstraintDirection(new PVector(0,0,1));
scene.camera().frame().setConstraint(constraint);
}
void draw() {
background(0);
fill(204, 102, 0);
box(20, 30, 50);
}

Please refer to the examples ConstrainedCamera and ConstrainedFrame.

Happy hacking,

datadream..

Re: PeasyCam Conical Movement

2 years ago

I ended up abandoning PeasyCam for this particular project, as I decided to remove a lot of user control and simply let them spin the world using rotateZ() and zoom in and out using scale(), and wrote my own methods for gradually resetting the transforms. I was having issues with the PeasyCam reset as well, which I was never able to successfully replicate in the PDE (all of this has been developed in eclipse, and the code I unfortunately can not share).

I am intruiged by ProScene, which I may have to try some time.

Top Reply