Peasycam and picking library

boriskourt

in Contributed Library Questions • 2 years ago

I have been working on an extensive data visualization sketch recently and ran into an issue with the following two libraries:

The picking library: http://n.clavaud.free.fr/processing/picking-library/

and peasycam: http://n.clavaud.free.fr/processing/picking-library/

Both work within the sketch on their own, but the picking library stops being able to determine objects if peasycam is active.

The question: Since the picking library is fairly old now, I was wondering if there is a better alternative to 3D picking in an opengl sketch, or if there has been a workaround for making these two libraries work with each other.

Replies(15)

Chrisir

Re: Peasycam and picking library

2 years ago

For picking look at:

http://www.lagers.org.uk/s3d4p/index.html

http://www.lagers.org.uk/s3d4p/applets/s3d4p_shapepicker/index.html

For camera:

it should bei fairly easy to write your own camera, look at,
http://www.openprocessing.org/visuals/?visualID=28947
file AutoCamera.pde.

boriskourt

Re: Peasycam and picking library

2 years ago

on this picking example for that library:

http://www.lagers.org.uk/s3d4p/applets/s3d4p_shapepicker/S3D4P_Picking.pde

What sets up an object to be 'pickable'. Is it this line:

                
                 .drawMode(Shape3D.SOLID | Shape3D.WIRE);

I am currently using ellipses in a 3D space and I couldn't figure out how to attach this draw mode to an ellipse. When I tried to create a class instance for an ellipse I got an error that said that there is not such thing.

quarks

Re: Re: Peasycam and picking library

2 years ago

Shapes£D is not a picking library so does NOT make ellipses pickable.

This library provides a wide range of 3D shapes which can be created, coloured, textured etc. If you download the library and try out the examples you will see what I mean.

When a 3D shape is created using this library it is automatically made pickable and is detected with

Shape3D picked = Shape3D.pickShapeB(this,mouseX, mouseY);

fiveagon

Re: Peasycam and picking library

2 years ago

I wrote a picking class that takes a Collection of Objects that implement a Draggable interface. This may or may not be useful in 3D, though.

Picker.java
Draggable.java

You just have to make your class implement Draggable with two methods.

boolean contains(float x, float y);
void translate(float dX, float dY); // Basically, how do you add to your object's position?

These classes aren't a current part of my library, but feel free to add them directly to your sketch. If you need more help on how to get these classes set up, I'll be glad to help.

boriskourt

Re: Peasycam and picking library

2 years ago

Thank's for your reply,

I am currently not looking drag any objects around. I am showing a 3D data visualization and want to set up a way to display information based on where the user clicks. Think of a huge chart with a bunch of layers, and I need to show some extra information whenever a layer is clicked.

I will take a look at your picking example and see if it will fix my current issue though.

fiveagon

Re: Re: Peasycam and picking library

2 years ago

Right on, right on. Yeah, I wasn't sure if it would help you or not, but maybe somebody else would find it useful.

Chrisir

Re: Peasycam and picking library

2 years ago

have you looked at
http://processing.org/reference/screenX_.html

maybe you can store the x,y,z values and test the mouse-position with screenX etc. as in the example?

Greetings, Chrisir

boriskourt

Re: Peasycam and picking library

2 years ago

I have looked at screenX, unfortunately I need a more elegant solution as I have hundreds of objects that I want to be able to get at. I am still not sure of the best way to approach this.

I like ellipses due to their display value, they don't take up much space and create clear representations of the data.

Oh well, I will dig around further.

jeff_g

Re: Peasycam and picking library

2 years ago

I use color picking with PeasyCam and it works great.

jeff_g

Re: Peasycam and picking library

2 years ago

Guess you probably want to know how to apply the camera matrix... forgot to add that..

I do something like this.

PGraphics3D g3;
void setup() {
g3 = (PGraphics3D)g;
}
int pick() {
if (buffer != null) {
buffer.beginDraw();
buffer.background(getColor(-1)); // since background is not an object, its id is -1
buffer.noStroke();
buffer.setMatrix(g3.camera);
//draw stuff in the buffer using the color picking method
buffer.endDraw();
// get the pixel color under the mouse
color pick = buffer.get(mouseX, mouseY);
// get object id
int id = getId(pick);
return id;
}
return -1;
}
// color -2 gives 0, etc.
int getId(color c) {
return -(c + 2);
}
// id 0 gives color -2, etc.
color getColor(int id) {
return -(id + 2);
}

boriskourt

Re: Re: Peasycam and picking library

2 years ago

I am trying to decipher that, mostly new to me.

jeff_g

Re: Peasycam and picking library

2 years ago

Here is an example using PeasyCam with Color Picking.

import processing.opengl.*;
import peasy.*;
PGraphics buffer; // buffer
Cube[] cubes; // cubes
PeasyCam cam;
PGraphics3D g3;
void setup() {
// we use OPENGL for display
size(200, 200, OPENGL);
g3 = (PGraphics3D)g;
// buffer is created using applet dimensions
buffer = createGraphics(width, height, P3D);
cam = new PeasyCam(this, 100);
cam.setResetOnDoubleClick(false);
cam.setMinimumDistance(50);
// put cubes randomly in the scene
cubes = new Cube[10];
for (int i = 0; i < cubes.length; i++) {
cubes[i] = new Cube(
i, // identifiant
-15 + (int)random(30), // position x
-15 + (int)random(30), // position y
-15 + (int)random(30), // position z
5 + (int)random(15) // taille
);
}
}
void draw() {
background(255);
lights();
for (int i = 0; i < cubes.length; i++) {
cubes[i].display(this.g);
}
}
void mouseClicked() {
// draw the scene in the buffer
buffer.beginDraw();
buffer.background(getColor(-1)); // since background is not an object, its id is -1
buffer.noStroke();
buffer.setMatrix(g3.camera);
for (int i = 0; i < cubes.length; i++) {
cubes[i].drawBuffer(buffer);
}
buffer.endDraw();
// get the pixel color under the mouse
color pick = buffer.get(mouseX, mouseY);
// get object id
int id = getId(pick);
// if id > 0 (background id = -1)
if (id >= 0) {
// change the cube color
cubes[id].changeColor();
}
}
// id 0 gives color -2, etc.
color getColor(int id) {
return -(id + 2);
}
// color -2 gives 0, etc.
int getId(color c) {
return -(c + 2);
}
class Cube {
// variables
int id; // id
int x, y, z, w; // position (x, y, z) and width (w)
color c; // color (in scene, not buffer)
// constructor
public Cube(int id, int x, int y, int z, int w) {
this.id = id;
this.x = x;
this.y = y;
this.z = z;
this.w = w;
c = color(random(255), 250, 50);
}
// make the color change
public void changeColor() {
int r = (int)red(c);
int g = (int)green(c);
int b = (int)blue(c);
c = color(r, 255 - g, b);
}
// display the cube on screen
public void display(PGraphics ecran) {
ecran.fill(c);
drawCube(ecran);
}
// draw the cube in the buffer
public void drawBuffer(PGraphics buffer) {
color idColor = getColor(id);
buffer.fill(idColor);
drawCube(buffer);
}
private void drawCube(PGraphics g) {
g.pushMatrix();
g.translate(x, y, z);
g.box(w);
g.popMatrix();
}
}

boriskourt

Re: Re: Peasycam and picking library

2 years ago

Thank you! I have it implemented and am now drawing the ellipses using a modified cube class.

Here is the outcome of my sketch, first image is with all the ellipses unmodified, while the second is with me trying to click ellipses. Picking seems to only be affecting a few of the ellipses rather than all of them, do you have any idea why this could be? [Note: I have done this without transparency as well, although that shouldn't affect anything.]

jeff_g

Re: Peasycam and picking library

2 years ago

It appears like their all on the same 2d plane, so what you have is a blending of colors for any particular pixel except for those on the outside. So doing it without transparency may give you a better idea of what's going on in your buffer, since those are going to be sold colors with the last ellipse drawn taking the color for that pixel.

antiplast..

Re: Peasycam and picking library

1 years ago

You can use PeasyCam and Picking libraries together by applying the camera matrix to the picker buffer, at the very top of the draw() function :

PeasyCam cam;
Picker picker;
void setup() {
size(200, 200, P3D);
cam = new PeasyCam(this, 100);
cam.setMinimumDistance(50);
cam.setMaximumDistance(500);
}
void draw() {
cam.getState().apply(picker.getBuffer());
picker.start(1);
box(30);
picker.stop();
int id = picker.get(mouseX, mouseY);
}

Sorry for the late reply...

Top Reply