PDF export: shapes misaligned

Core Library Questions

dubmonk

PDF export: shapes misaligned

in Core Library Questions • 4 months ago

Something is up with my attempt at rendering this sketch as a PDF. In the PDF render the ellipses are misaligned. The drawing outputs perfectly to the screen. Any help would be appreciated (trying to output for printing).

On screen render:

PDF render:

import processing.pdf.*;
boolean record = true;
PGraphics pdf;
int d = 300;
int r = 300;
float z = random(1, 5);
float rand;
int stepX = 15;
int stepY = 15;
color[] palette = {
#556270, #4ECDC4, #C7F464, #FF6B6B, #C44D58
};
void setup(){
//background (palette[(int)random(1, 5)]);
size(960, 645);
ellipseMode(CORNER);
smooth();
pdf = (PGraphics) createGraphics((width), (height), PDF, "frame.pdf");
noLoop();
}
void draw(){
if(record){
beginRecord(pdf);
println("Recording started.");
record = true;
}
float n = noise(d)*d;
noiseSeed(0);
noStroke();
background (#556270);
for (int y = stepY; y < height +d; y += d + stepY){
for (int x = stepX; x < width; x += d + stepX){
drawCircle(x, y, d);
}
}
if(record){
endRecord();
println("Recording stopped.");
record = false;
}
}
void drawCircle(float x, float y, float d){
//noFill();
noStroke();
fill(palette[(int)random(0, 5)]);
ellipse(x, y, d, d);
if(d > 2){
drawCircle(x, y, d/1.5);
}
}

Replies(2)

GoToLoop

Re: PDF export: shapes misaligned

4 months ago

A PGraphics instance needs to be initialized w/ beginDraw() & endDraw().

Also, you need to specify its own characteristics like ellipseMode(), smooth(), etc; apart from main screen surface!

Anyways, for recording PDFs, there's no need to create a separate PGraphics !

Here's your code w/o such:

// http://forum.processing.org/topic/pdf-export-shapes-misaligned

import processing.pdf.*;

final static boolean RECORD = true;

final static int DIAM = 300;
final static int STEP_X = 15, STEP_Y = 15;

final static float FRACT = 1.15;

final static color BG = #556270;

final color[] palette = {
  #4ECDC4, #C7F464, #FF6B6B, #C44D58
};

void setup() {
  size(960, 645);
  noLoop();

  initialize();
}

void draw() {
  if (RECORD) {
    final String path = dataPath("frame-####.pdf");
    beginRecord(PDF, path);

    initialize(); // initialize PDF's own graphics setup
  }

  background (BG);

  final int xx = width;
  final int yy = height + DIAM;

  for (int y = STEP_Y; y < yy; y += DIAM + STEP_Y) {
    for (int x = STEP_X; x < xx; x += DIAM + STEP_X) {
      drawCircle(x, y, DIAM);
    }
  }

  if (RECORD) {
    endRecord();
    println("Frame: #" + frameCount);
  }
}

void mouseClicked() {
  redraw();
}

void drawCircle(int x, int y, float d) {
  fill(palette[(color) random(palette.length)]);
  ellipse(x, y, d, d);

  if (d > 2) {
    drawCircle(x, y, d/FRACT);
  }
}

void initialize() {
  smooth();
  noStroke();
  ellipseMode(CORNER);
}