Pause and resume

Programming Questions

Alex Pilk..

in Programming Questions • 5 months ago

Hi, guys! I've been making a game and I wanna add pause function to it. But unfortunately there was a bug.

Here's a simplified version of my code.Each second an ellipse falls from the top of the screen.

UPDATE: If I press a key and pause the sketch, when I resume it - there are lots of circles in the top of the screen. How to get rid of that, so that after I resume it, everything is as it was before pause?

myClass[] myObject = new myClass[40];
boolean paused=false;
void setup() {
size(200, 400);
smooth();
for (int i=0; i<40; i++) {
myObject[i]=new myClass();
}
}
int t=0;
void draw() {
background(0);
if (!paused) {
for (t=0; millis()>t; t+=1000) {
myObject[t/1000].appear();
}
}else{t=millis();}
}
void keyPressed() {
paused=!paused;
}
class myClass {
int y;
float x=random(0, width);
void appear() {
ellipse(x, y, 20, 20);
y+=2;
}
}

Replies(11)

v.k.

Re: Pause and resume

5 months ago

That code looks strange to me, there is no declaration of "paused", no default constructor, and the for loop you made will fail in out of bounds error. I would thing it will not even compile. But it does :P :). Anyway if you add

boolean paused;

in global level the issue reported will be gone, until the array go out of bounds.

There is this article from wiki about classes.

A side note, replace

for (int i=0; i<40; i++) { }

for (int i=0; i<myObject.length; i++) {}

so if you change the size of the array things won't break,

PhiLho

Re: Pause and resume

5 months ago

You don't find suspicious that you didn't need to declare the paused variable?

paused is a Processing variable name, like width and frameCount. And it stops the animation thread!
Rename the variable to something else, eg. bpaused, declare it as global variable, and it will work.

[EDIT] v.k. was slightly faster than me, and indeed, no need to name it differently, making your own variable will shadow the Processing one.

v.k.

Re: Pause and resume

5 months ago

Shouldn't then "paused" get coloured when wrote in the PDE?

PhiLho

Re: Pause and resume

5 months ago

This variable has no official documentation, so it isn't highlighted.

GoToLoop

Re: Pause and resume

5 months ago

Some time ago, I tried to find out where Processing kept its field related to its running state.

Although we have loop() & noLoop(), we can't check nor switch it on/off w/ just 1 method!

So, I've looked at Processing's JavaDoc and was quite upset of not finding out anything about it!

In my point of view, I was puzzled of not having any field

where loop() & noLoop() set its run/pause state!

Then I've decided to look into Processing's source itself.

And after some perseverance, finally discovered the secret looping field!!!

Seems like those developers didn't want us to use it directly! HEHEHEH!!!

But here it is -> Your code tweaked to use field looping! Bon appétit:

UPDATE: Included some extras!

// http://forum.processing.org/topic/pause-and-resume

final static byte NUM = 50;
final static MyClass[] myObject = new MyClass[NUM];

void setup() {
  size(300, 600, P2D);
  smooth();
  noStroke();
  frameRate(NUM + 20);

  fill(MyClass.COLOUR);

  for ( int i=0; i!=NUM; myObject[i++] = new MyClass() );
}

void draw() {
  background(0);

  final int m = millis() / 1000;
  print(m + " - ");

  for ( int t=m % NUM; t--!=0; myObject[t].appear() );
} 

void keyPressed() {
  if (looping)  noLoop();
  else          loop();
}

void mousePressed() {
  keyPressed();
}

final class MyClass {
  static final color COLOUR = #00FFFF;
  static final byte  DIM = 20, SPD = 2;

  final short X = (short) random(DIM, width - DIM);
  short y;

  void appear() {
    ellipse(X, y += SPD, DIM, DIM);

    if (y > height)  y = (short) (-height << 1);
  }
}

Alex Pilk..

Re: Pause and resume

5 months ago

Oh, SORRY! Thanks for your responses! Forgot to declare it! It's strange that I didn't get an error.

So here is another bug. (I've updated the code). If I press a key and pause the sketch, when I resume it - there are lots of circles in the top of the screen. How to get rid of that, so that after I resume it, everything is as it was before pause?

adilapapa..

Re: Pause and resume (PLEASE HELP!)

5 months ago

You could edit your code so that it uses GoToLoop's 'looping' suggestion:

Remove the 'paused' variable and change the 'keyPressed()' part of your code to

void keyPressed() {
if (looping) noLoop();
else loop();
}

Then, change your 'draw' function to this:

void draw() {
background(0);
for (t=0; t<millis(); t+=1000) {
myObject[t/1000].appear();
}
}

If you run it now, it should work the way you want it to. :)

GoToLoop

Re: Pause and resume (PLEASE HELP!)

5 months ago

Function millis() returns how many milliseconds have transpired since program has started!

And it is continuous and not affected by noLoop(). I guess not even delay()!

So, when you unpause your program, millis() has not the same value since last pause!

For that, I've come up w/ my own time counter, which stops once variable looping is false !

Introducing -> my Seconds()!

It runs from a parallel thread(). Although far away from being precise, it fits your purposes I believe:

// http://forum.processing.org/topic/pause-and-resume

final static byte NUM = 50;
final static MyClass[] myObject = new MyClass[NUM];

int seconds;

void setup() {
  size(300, 600, P2D);
  smooth();
  noStroke();
  frameRate(NUM + 20);

  fill(MyClass.COLOUR);

  for ( int i=0; i!=NUM; myObject[i++] = new MyClass() );

  thread("mySeconds");
}

void draw() {
  background(0);

  print(seconds + " - ");

  int t = seconds % NUM;
  if (t == 0)   for (MyClass obj: myObject)  obj.y = 0;

  while (t-- != 0)   myObject[t].display();
} 

void keyPressed() {
  if (looping = !looping)  thread("mySeconds");
}

void mousePressed() {
  keyPressed();
}

void mySeconds() {
  while (looping) {
    ++seconds;
    delay(950);
  }
}

final class MyClass {
  static final color COLOUR = #00FFFF;
  static final byte  DIM = 20, SPD = 2;

  final short X = (short) random(DIM, width - DIM);
  short y;

  void display() {
    ellipse(X, y += SPD, DIM, DIM);
  }
}

v.k.

Re: Pause and resume (PLEASE HELP!)

5 months ago

what about this? :)

// array list so you can add and remove balls
ArrayList<FallClass> falls = new ArrayList<FallClass>();
boolean paused=false;
int time, interval = 500;
void setup() {
size(200, 400);
smooth();
// start with one ball
falls.add( new FallClass());
// time is counting
time = millis();
}
void draw() {
if (!paused) {
// clear screen only if running
background(0);
// add a ball every more or less half second
if(millis() - time > interval){
falls.add(new FallClass());
// determine a new random interval :) and reset timer
time = millis();
interval = int(random(300, 800));
}
// update, or... y++
for (FallClass f : falls ) {
f.update();
}
}
// display always, paused or not
for (FallClass f : falls ) {
f.display();
}
// remove balls that are out of screen, go backwards
if(falls.size() > 0){
for (int i = falls.size()-1; i > 0; i--){
if(falls.get(i).isDone()){
falls.remove(i);
}
}
}
//number of objects alive...
println(falls.size());
}
void keyPressed() {
paused=!paused;
}
// by convention classes starts with caps
class FallClass {
float sz = 20;
float y = - sz;
// for fun random speeds
float x, speed;
// a constructor
FallClass() {
x = random(0, width);
speed = random(1.8, 2.8);
}
void display() {
ellipse(x, y, sz, sz);
}
void update() {
y+=speed;
}
boolean isDone(){
return y > height + sz;
}
}

Alex Pilk..

Re: Pause and resume (PLEASE HELP!)

5 months ago

v.k., Thank you very much! You're code is working!

Alex Pilk..

Re: Pause and resume (PLEASE HELP!)

5 months ago

To GoToLoop: I appreciate your help but your code is too hard to read.

Notice, that I placed " else {t=millis();}", so I don't understand why that cannot fix problem with millis();

if (!paused) {
for (t=0; millis()>t; t+=1000) {
myObject[t/1000].appear();
}
} else {t=millis();}

Pause and resume

Replies(11)

Re: Pause and resume

Re: Pause and resume

Re: Pause and resume

Re: Pause and resume

Re: Pause and resume

Re: Pause and resume

Re: Pause and resume (PLEASE HELP!)

Re: Pause and resume (PLEASE HELP!)

Re: Pause and resume (PLEASE HELP!)

Re: Pause and resume (PLEASE HELP!)

Re: Pause and resume (PLEASE HELP!)

Statistics

Tags

Actions

Related Posts