For the record, Zoho marked your first two messages as spam because they had the word "otther" in it!
I could mark them as not spam, but I deleted them to avoid duplication with this thread.

Thank you for the information my first problem is done. Now the second : How give the information to processing when my particle is lock and i don't creat a new one !!! who have a solution :)

I made some changes to your code:
- You type the ArrayList, which is nice, but then you don't need to cast the result of get(). Actually, you used once the for (Atome atm : listeA) form, you should generalize it.
- Usage of booleans can be simplified.
- I used dist() which does the same thing than your formula.
- The diameter is part of the data of the Atom, so I made a field for it: thus, no need to pass it on each method.
- Molecule has no need for an Atom field.
- The "ClassAtom2D" part of the method names is redundant (and reduce readability of the code): we already know it is part of the said class!

Now the relevant part (the other remarks are more stylistic):
Before adding an atom, you need to loop over all the atoms. Update them (to be sure lock is up to date), then if one of them is locked, just don't add anything.

1. Molecule mlcl ;
2. color colorAtom = color( 0, 0, 0, 255) ; // blanc
3.  
4. void setup() {
5.   size (400, 400) ; frameRate(25) ;
6.   mlcl = new Molecule() ;
7.  }
8.  
9. void draw() {
10.   background(255, 30, 30) ;
11.   // fonction class Molecule
12.   // call Molecule for Atom
13.   mlcl.displayAtoms(colorAtom) ; // class.void(diameter of atome)
14.   mlcl.updateAtoms() ;
15.   mlcl.moveAtoms() ;
16.   // call Molecule
17.   mlcl.draw() ;
18. }
19.  
20. void mousePressed()
21. {
22.   mlcl.addAtom(mouseX, mouseY ) ;
23. }
24.  
25. class Molecule
26. {
27.   ArrayList<Atome> listeA; // Crée une liste d'après une class ou une librairie.
28.  
29.   Molecule()
30.   {
31.     listeA = new ArrayList<Atome>();
32.   }
33.  
34.   //::::::::::::::::::::ATOME:::::::::::::::
35.   //:::::::::::add point to molecule
36.   void addAtom(float nAX, float nAY)
37.   {
38.     for (Atome atm : listeA)
39.     {
40.       atm.update();
41.       if (atm.lock) return; // Don't add a new atom
42.     }
43.    
44.     Atome atm = new Atome(nAX, nAY, 0, 25);
45.     listeA.add(atm) ;
46.   }
47.  
48.   //::::::::::::::::::::Display / Update / Mvt
49.   void displayAtoms(color cA)
50.   {
51.     for (Atome atm : listeA)
52.     {
53.       atm.display(cA) ;
54.     }
55.   }
56.  
57.   //::::::::::::::::::::::::update
58.   void updateAtoms()
59.   {
60.     for (Atome atm : listeA)
61.     {
62.       atm.update() ;
63. //      println(atm.lock_()) ;
64.     }
65.   }
66.  
67.   //:::::::::::::::mouvement
68.   void moveAtoms()
69.   {
70.     for (Atome atm : listeA)
71.     {
72.       atm.move(2.0 , 2.0) ;
73.     }
74.   }
75.  
76.   //::::::::::::MOLECULE::::::::::::::::::::::::::::::::::::
77.   //::::::draw molecule
78.   void draw()
79.   {
80.     //draw molecule
81.     fill(0,0,0,30) ;
82.     stroke(255,255,255,255) ;
83.     strokeWeight(1) ;
84.   
85.     beginShape() ;
86.     for (Atome a : listeA ) { vertex(a.x, a.y) ; }
87.     endShape(CLOSE) ;
88.   }
89.  
90.   //::::::update atome
91.  
92. //::::::::::::::::::
93.  
94. }
95. class Atome
96. {
97.   float x, y, z ;
98.   float diam;
99.  
100.   boolean inside, lock ;
101.  
102.   color inAtom = color (255, 255, 255, 255) ; // noir
103.  
104.   Atome (float aX, float aY, float aZ, int d )
105.   {
106.     x = aX ; y = aY ; z = aZ ; diam = d ;
107.   }
108.  
109.   // Detection the cursor is on the atom
110.   boolean detection2D()
111.   {
112.     return dist(x, y, mouseX, mouseY) < diam / 2;
113.   }
114.  
115. //::::::::::2D
116.   void move ( float aMX, float aMY)
117.   {
118.     float nx = random( -aMX, aMX );
119.     float ny = random( -aMY, aMY );
120.   
121.     x += nx ;
122.     y += ny ;
123.   }
124.  
125.   // update atome ( position, detection...)
126.   void update() {
127.  
128.     strokeWeight(diam) ;
129.   
130.     inside = detection2D() ;
131.     if(mousePressed && inside)   { lock = true; }
132.     if(!mousePressed)            { lock = false; }
133.     if(lock)                     { x = mouseX; y = mouseY; }
134.   }
135.  
136.   // Display the property of Atome
137.   void display ( color cA ) {
138.  
139.     strokeWeight(diam) ;
140.     if(inside) {
141.       fill(cA) ; stroke(cA) ;
142.     } else {
143.       fill(inAtom) ; stroke(inAtom) ;
144.       inside = false ;
145.     }
146.     point (x, y) ;
147.     // test
148.   }
149. //:::::::::::::::
150. }

Hello PhiLho ,
I thought make a simple code, but you show me I'm very for of my purpose.
I read your correction it's very simple and efficient, incredible.

Big thanks for this big help.


StanLEpunK