P3D Object creation...

Programming Questions

kris_proc..

in Programming Questions • 4 months ago

Hello,

I'm a problem, I want to create 3D object when condition are true.

The problem is that when this condition is fulfilled the object disappears.

I try but I can not find a solution.

Here's the code:

float rx;
float ry;
int a=0;

void setup(){

size(300,300,P3D);

}

void draw(){

background(204);
translate(width/2,height/2,0);
if (mousePressed && (mouseButton == LEFT)) {

rotateX(rx);
rotateY(ry);

rx =map (mouseX, 150,width,-PI,PI);
ry =map (mouseY, 150,height,-PI,PI);

//print(rx);
//print(ry);

}else{ }

rotateX(rx);
rotateY(ry);

if(a == 0){

pushMatrix();
box(30);
popMatrix();
a=1;
}

}

This code shows that the condition is true, but once the cube is not existing.

Replies(6)

tfguy44

Re: P3D Object creation...

4 months ago

float rx;
float ry;
boolean a=true;
void setup() {
size(300, 300, P3D);
}
void draw() {
background(204);
//lights();
//noStroke();
translate(width/2, height/2, 0);
if (mousePressed && (mouseButton == LEFT)) {
rx =map (mouseX, 150, width, -PI, PI);
ry =map (mouseY, 150, height, -PI, PI);
}
rotateX(rx);
rotateY(ry);
scale(30);
if (a) {
box(1);
}
}
void keyPressed(){
if( key == ' ' ){
a=!a;
}
}

Pressing space bar will toggle the variable a, which is the condition used to determine if the cube is drawn or not.
I removed several things that did nothing from your code, including:

- An else block that was empty.

- A push/popMatrix() pair that did nothing.

kris_proc..

Re: P3D Object creation...

4 months ago

Hi,I'm sorry I can not express myself, I would say that what I wanted was that the activation condition creates the cube but despite that after disabling the cube is displayed, existing.

v.k.

So you need to store them some where after created, that could be a custom box class, but can be done just storimg the position of the box. I used an ArrayList of PVectors for that, and the mouse to change condition...

ArrayList<PVector> pos = new ArrayList<PVector>();
boolean condition;
void setup() {
size(400, 400, P3D);
smooth();
}
void draw() {
background(255);
for(PVector p:pos){
pushMatrix();
translate(p.x, p.y);
box(10);
popMatrix();
}
// that could be done inside mousePressed()
// and would need no condition...
if(condition){
pos.add(new PVector (random(width), random(height)));
condition = false;
println("ok done! Now there are "+ pos.size() + " box(es)");
}
}
void mousePressed(){
condition = true;
println("add a box? " + condition);
}

kris_proc..

Re: P3D Object creation...

4 months ago

Thank you very much, this is exactly what I was looking for!I hope so to incorporate the dimensions of the boxes at the same time.Again thank you =)

v.k.

Re: P3D Object creation...

4 months ago

You can sure make another array to hold the dimensions, but there is where an OOP approach becomes handy. So it will be easier to evolve the code, change your mind, add features, etc.Some thing like

[edit] added z translation

ArrayList<BBox> boxes = new ArrayList<BBox>();
void setup() {
size(400, 400, P3D);
smooth();
}
void draw() {
background(255);
for (BBox b:boxes) {
b.display();
}
}
void mousePressed() {
boxes.add(new BBox());
println("ok done! Now there are "+ boxes.size() + " box(es)");
}
class BBox {
PVector pos;
float sz;
color c;
BBox() {
pos = new PVector( random(width), random(height), random(-100, -300));
sz = random (4, 40);
c = color(random(255), random(255), random(255));
}
void display() {
noFill();
stroke(c);
pushMatrix();
translate(pos.x, pos.y, pos.z);
box(sz);
popMatrix();
}
}

v.k.

Re: P3D Object creation...

4 months ago

ops, i forgot to add z translation in he first time i posted. Corrected in the code above already ;)

Top Reply