You can use JAVA2D as a renderer as well.

Pressing space seems to clear the screen, so clarify what your problem is exactly.

Basically, I just need to make the mouse PGraphics transparent. When I move the mouse, the ellipse shows up, but it stays drawn to the screen. I've tried redrawing the background as transparent, but it just does nothing.

No need to call background() on the mouse's PGraphics, it is naturally transparent. And indeed, you can use JAVA2D for it.
One of your problem is that you use the cumulative drawing paradigm for your sketch.
It is OK for a paint application but since you need to do also real-time drawings on this surface (the mouse), you should do the drawings off-screen, on another PGraphics.
Thus, you can layer the current painting, the mouse, and any other stuff you need to show.

As PhiLho pointed out, you should be doing the drawing to a PGraphics. So there are some fundamental problems with your current sketch. I made some quick alterations, see the adapted code below.

Adapted Code

1. import controlP5.*;
2. ControlP5 slider;
3.  
4. PGraphics canvas;
5.  
6. int r = 255;
7. int g = 255;
8. int b = 255;
9. float s = 50;
10.  
11. float br, bg, bb;
12.  
13. void setup() {
14.   size(screen.width, screen.height);
15.   smooth();
16.   canvas = createGraphics(width-350, height, JAVA2D);
17.   canvas.beginDraw();
18.   canvas.smooth();
19.   canvas.background(br, bg, bb);
20.   canvas.endDraw();
21.   cursor(CROSS);
22.   slider = new ControlP5(this);
23.   slider.addSlider("r", 0, 255, 10, 10, 255, 30);
24.   slider.addSlider("g", 0, 255, 10, 50, 255, 30);
25.   slider.addSlider("b", 0, 255, 10, 90, 255, 30);
26.   slider.addSlider("s", 0, 100, 10, 130, 255, 30);
27.   slider.addSlider("br", 0, 255, 10, 510, 255, 30);
28.   slider.addSlider("bg", 0, 255, 10, 550, 255, 30);
29.   slider.addSlider("bb", 0, 255, 10, 590, 255, 30);
30. }
31.  
32. void draw() {
33.   background(0);
34.   drawMenu();
35.   image(canvas, 350, 0);
36.  
37.   fill(0);
38.   stroke(r, g, b);
39.   strokeWeight(s);
40.   ellipse(mouseX, mouseY, s/2, s/2);
41.  
42.   stroke(r, g, b);
43.   strokeWeight(s);
44.   if (mousePressed && mouseButton == LEFT && mouseX > 350) {
45.     canvas.beginDraw();
46.     canvas.stroke(r, g, b);
47.     canvas.strokeWeight(s);
48.     canvas.line(mouseX-350, mouseY, pmouseX-350, pmouseY);
49.     canvas.endDraw();
50.   }
51. }
52.  
53. void drawMenu() {
54.   noStroke();
55.   fill(0);
56.   rect(0, 0, 350, height);
57.   fill(r, g, b);
58.   ellipse(100, 300, s, s);
59.   fill(br, bg, bb);
60.   ellipse(100, 500, 50, 50);
61.   fill(200, 0, 0);
62.   textSize(48);
63.   text("SAVE", 90, height-90);
64. }
65.  
66. void keyPressed() {
67.   if (key == ' ') {
68.     canvas.beginDraw();
69.     canvas.background(br, bg, bb);
70.     canvas.endDraw();
71.   }
72.   if (key == 'z' || key == 'Z') {
73.     color c = canvas.get(mouseX-350, mouseY);
74.     slider.controller("r").setValue(red(c));
75.     slider.controller("g").setValue(green(c));
76.     slider.controller("b").setValue(blue(c));
77.   }
78.   if (key == 'x' || key == 'X') {
79.     color c = canvas.get(mouseX-350, mouseY);
80.     slider.controller("br").setValue(red(c));
81.     slider.controller("bg").setValue(green(c));
82.     slider.controller("bb").setValue(blue(c));
83.   }
84. }
85.  
86. void mouseReleased() {
87.   if (mouseX <= 350 && mouseY >= 650) {
88.     String savePath = selectOutput("Save Image");
89.     canvas.save(savePath);
90.   }
91. }

Thanks a lot!