oscP5 + foreign characters in msg

marinero

oscP5 + foreign characters in msg

in Contributed Library Questions • 2 months ago

Hi,
I am trying to send a message using oscP5 from one sketch to the other. When I use latin characters the text appears fine on the other machine. When I use greek characters it arrives all mangled up.

I send the msg as follows:

OscMessage myMessage = new OscMessage("/test");
myMessage.add("αβγδ");
oscP5.send(myMessage, myRemoteLocation);

I know it is not a problem with processing displaying greek fonts because if I do a simple text("αβγ", 20,20) it displays the text just fine. It's when I parse the message as below:

void oscEvent(OscMessage theOscMessage)
{
searchTerm=theOscMessage.get(0).stringValue();
}

and I run:

text(searchTerm, 20,20);

that it comes out scrambled. As if the transferring of the message via oscP5 is messing it up. I noticed someone else having trouble with chinese as well.

Any ideas? Suggestions?

Much appreciated.

Replies(2)

dimkir

Re: oscP5 + foreign characters in msg

2 months ago

From your problem description It sounds like osc5 only supports latin characters to be transferred as a message.

The easiest solution would be to convert(encode) your greek characters before you send them with osc5 into some format which represents charactes only as latin letters and numbers. URLEncoded strings is a good example of such format.

So your plan of action would be:

1) get greek string

2) url encode greek string

3) send the url encoded string over the channel

4) once you receive the string, URLDecode it.

5) voila you have your original greek string.

Below is a simple sketch showing URLEncoding and URLDecoding:

(also here's copy of the sketh on github: https://github.com/dimkir/processingForumSnippets/tree/master/greekMessage)

import java.net.URLDecoder;
import java.net.URLEncoder;
import java.io.UnsupportedEncodingException;
String decodedGreek;
String originalGreek;
String urlEncodedGreek;
void setup(){
size(800, 600);
originalGreek = "Η ελληνική γλώσσα είναι μία από τις ινδοευρωπαϊκές γλώσσες";
try{
//
urlEncodedGreek = URLEncoder.encode(originalGreek, "UTF-8");
println(urlEncodedGreek);
// or sendMessage(urlEncodedGreek);
decodedGreek = URLDecoder.decode(urlEncodedGreek, "UTF-8");
println("This is greek again: " + decodedGreek);
}
catch(UnsupportedEncodingException ex)
{
println(ex.getMessage());
}
textFont(createFont("Arial", 32));
}
void draw(){
background(0);
fill(#00ff00);
text("original greek: " + originalGreek, 10 , 30, width - 10, 200);
fill(#ff0000);
text("urlencoded: " + urlEncodedGreek, 10, 150, width-10, 300);
fill(#0000ff);
text("decoded greek: " + decodedGreek, 10, 450, width- 10, 300);
noLoop();
}

On the picture you can see your original string in green. Then you URLEncode it ( the text in red is the way it's gonna look when urlencoded) and then convert it back (URLDecoded it to get blue string)

marinero

Re: Re: oscP5 + foreign characters in msg

2 months ago

Dear dimkir!!!

I tried your solution and it worked like a charm! Good thinking!

Thanks for your time and for supplying me with source code. It saved me lots of time :).

Take care!