To remove one ball (the oldest in the list) when the maximum is exceeded...

1.   if (balls.size() > 10) { balls.remove(0); }

....or to remove all balls above the maximum...

1.   while (balls.size() > 10) { balls.remove(0); }

In this case the result will be the same, because just one ball is added and if needed removed.

But in other sketches it will produce a different result.

Remember in your previous post I've mentioned about activate/deactivate objects?
Since you have determined you want "x" Ball objects at most, you can use an Array in place of a List.
You just need to reactivate() them after some condition.

This online example uses this same strategy:
http://studio.processingtogether.com/sp/pad/export/ro.91nVQMnL$v06L/latest

Check it out this approach below:

// forum.processing.org/topic/one-element-in-the-array-taking-another-ones-place
// http://forum.processing.org/topic/create-new-object-with-mouse-click

final static int MAX = 4, FPS = 60, TIMER = 100;
final static Ball[] balls = new Ball[MAX];

int idx;

void setup() {
  size(800, 600);
  frameRate(FPS);
  smooth();

  for (int i=0; i!=MAX; balls[i++] = new Ball());
}

void draw() {
  background(0);

  if (frameCount % TIMER == 0)  balls[++idx % MAX].reactivate();

  for (Ball b: balls)   b.run();
}

class Ball {
  final static int DIM = 20;

  float x, y;
  float spX = 20, spY = 5;
  color c;

  boolean isDead = true;

  void reactivate() {
    isDead = false;

    x = random(DIM, width  - DIM);
    y = random(DIM, height - DIM);

    c = (color) random(#000000);
  }

  void run() {
    if (isDead)  return;

    display();
    move();
    bounce();
    gravity();
  }

  void gravity() {
    spY += .2;
  }

  void bounce() {
    if (x >= width  - DIM/2 | x < DIM>>1)  spX *= -1;
    if (y >= height - DIM/2 | y < DIM>>1)  spY *= -1;
  }

  void move() {
    x += spX;
    y += spY;
  }

  void display() {
    fill(c);
    ellipse(x, y, DIM, DIM);
  }
}

hi, thank you very much, this was what i needed
but instead of condition

if (frameCount % TIMER == 0)  balls[++idx % MAX].reactivate();

i want to add each new object by sending  osc message
int msg=0;

if (msg==1)  balls[++idx % MAX].reactivate();

but then something i don't understand happens
even i don't send any messages 
balls appear in masses and redraws
what is the cause of this?

Callback function draw() is invoked by default @ 60 FPS! We can control that issuing frameRate().
Also, each time it's invoked, frameCount is increased by 1.

So, if the condition to reactivate() those balls is merely msg == 1,
that's gonna happen very fast and outta control!

I suggest that you move the "re-spawning" to a dedicated function.
And call that once some "osc" happens or whatever.

Another option would be to "turn off" msg once a Ball is reactivated.

hi, thanx for replies and patience

I suggest that you move the "re-spawning" to a dedicated function.
And call that once some "osc" happens or whatever.

feel like idiot, i can't figure out how to do it, sorry

Another option would be to "turn off" msg once a Ball is reactivated.

my attempt, fail, i just get random dots which doesn't move

boolean msg;

 if(oscvalue==1){
    if(msg==false){
  balls[++idx % MAX].reactivate();
  for (Ball b: balls)   b.run();
  }
  msg = true;
  }
  else{
    msg=false;
   
  }


here is the effect i am aiming for, just want to activate each object when osc or something else is value 1

1. final static int MAX = 20, FPS = 60, TIMER = 100;
2. final static Ball[] balls = new Ball[MAX];
3. int idx, counter;
4. void setup() {
5.   size(800, 600);
6.   frameRate(FPS);
7.   smooth();
8.   for (int i=0; i!=MAX; balls[i++] = new Ball());
9. }
10. void draw() {
11.   //background(0);
12.   fill(255, 2);
13.   rect(0, 0, width, height);
14.   counter+=1;
15.   if (counter%50 == 0)  balls[++idx % MAX].reactivate();
16.   for (Ball b: balls)   b.run();
17. }
18. class Ball {
19.   int DIM=5;
20.   float x2, y2;
21.   float x, y;
22.   float spX, spY;
23.   color c;
24.   boolean isDead = true;
25.   void reactivate() {
26.     isDead = false;
27.     x = random(DIM, width  - DIM);
28.     y = random(DIM, height - DIM);
29.     c = (color) random(#000000);
30.     spX=random(0.01, 2);
31.     spY=random(0.01, 2);
32.     x2=random(width);
33.     y2=random(height);
34.   }
35.   void run() {
36.     if (isDead)  return;
37.     display();
38.     move();
39.     bounce();
40.     gravity();
41.   }
42.   void gravity() {
43.     spY += .2;
44.   }
45.   void bounce() {
46.     if (x >= width  - DIM/2 | x < DIM>>1)  spX *= -1;
47.     if (y >= height - DIM/2 | y < DIM>>1)  spY *= -1;
48.   }
49.   void move() {
50.     x += spX;
51.     y += spY;
52.   }
53.   void display() {
54.     fill(c);
55.     ellipse(x, y, DIM, DIM);
56.   }
57. }

... just want to activate each object when osc or something else is value 1.

Problem is, for how much long that value is gonna stay @ 1?
As I've mentioned already, draw() is invoked by default @ 60 FPS!
It means, for each second the condition remains true, 60 balls are respawned!!!

That's the reason why I've tipped about resetting the condition after a Ball is reactivated().

It means, for each second the condition remains true, 60 balls are respawned!!!

i understand that, here's my attempt to simulate if something=1 reactivate once only not on every frame
pressing q once does it but i fail to reset value back to 0 so next time pressing q does nothing
how to do it exactly?

int value;
boolean t=false;

   if (key == 'q'){
 
value=1;
}
 
  if (value == 1) { 
    if(t==true){
   balls[++idx % MAX].reactivate();
  
    }
    t = false;
    
  } else{
  t=true;
}
value=0;

I dunno where that value comes from and how long it stays active.
Thus you're gonna need an extra condition to avoid multiple re-spawnings.

This new condition is based on frameCount.
Every time a reactivate() happens, a variable called next is set FRAMES ahead of current frameCount.
So, as long current frameCount < next, a reactivate() won't happen, no matter how long value stays at 1.

In short, a reactivate() depends upon 2 conditions now.

Also, variable value is generated by a separate thread() each TIMER milliseconds @ CHANCE percent.
See how my example is doing now:

// forum.processing.org/topic/one-element-in-the-array-taking-another-ones-place
// http://forum.processing.org/topic/create-new-object-with-mouse-click

final static int MAX = 4, FPS = 60, FRAMES = 3*FPS;
final static int TIMER = 1000, CHANCE = 30;

final static Ball[] balls = new Ball[MAX];

int idx, next, value;
boolean isWorking = true;

void setup() {
  size(800, 600);
  frameRate(FPS);
  smooth();

  for (int i=0; i!=MAX; balls[i++] = new Ball());

  thread("MysteriousValueGenerator");
}

void draw() {
  background(0);

  final int fc = frameCount;

  if (fc > next & value != 0) {  
    balls[++idx % MAX].reactivate();
    next = fc + FRAMES;
  }

  for (Ball b: balls)   b.run();

  frame.setTitle("Value: " + value + "\tFrame: " + fc + "\tNext: " + next);
}

void MysteriousValueGenerator() {
  while (isWorking) {
    value = random(100) < CHANCE ? 1:0;
    delay(TIMER);
  }
}

class Ball {
  final static int DIM = 20;

  float x, y;
  float spX = 20, spY = 5;
  color c;

  boolean isDead = true;

  void reactivate() {
    isDead = false;

    x = random(DIM, width  - DIM);
    y = random(DIM, height - DIM);

    c = (color) random(#000000);
  }

  void run() {
    if (isDead)  return;

    display();
    move();
    bounce();
    gravity();
  }

  void gravity() {
    spY += .2;
  }

  void bounce() {
    if (x >= width  - DIM/2 | x < DIM>>1)  spX *= -1;
    if (y >= height - DIM/2 | y < DIM>>1)  spY *= -1;
  }

  void move() {
    x += spX;
    y += spY;
  }

  void display() {
    fill(c);
    ellipse(x, y, DIM, DIM);
  }
}