// Bouncing Ellipses
// forum.processing.org/topic/using-arrays-to-create-and-change-circles

private static final byte ellipseTotal = 3;
private static final MyEllipse[] my = new MyEllipse[ellipseTotal];

final void setup() {
    size (500, 500);
    frameRate(60);
    smooth();
    noStroke();

    my[0] = new MyEllipse(
    120, 70, // initX, initY
    50, 40, // sizeX, sizeY
    7, 3, // movX, movY
    #0000FF); // colour

    my[1] = new MyEllipse(
    320, 400, // initX, initY
    40, 50, // sizeX, sizeY
    3, 7, // movX, movY
    #00FF00); // colour

    my[2] = new MyEllipse(
    250, 250, // initX, initY
    30, 30, // sizeX, sizeY
    -7, 4, // movX, movY
    #FF0000); // colour
}

final void draw() {
    background(0);

    for ( byte index=0; index<ellipseTotal ; my[index++].everything() );
}

private final class MyEllipse {
    int x, y;
    int szX, szY;
    int mvX, mvY;
    color cor;

    MyEllipse (
    int initX, int initY, 
    int sizeX, int sizeY, 
    int movX, int movY, 
    color colour ) {

        x   = initX;
        y   = initY;
        szX = sizeX;
        szY = sizeY;
        mvX = movX;
        mvY = movY;
        cor = colour;
    }

    private final void everything() {
        update();
        display();
    }

    private final void update() {
        if ( x < (szX>>1) || x > width  - (szX>>1) )    mvX *= -1;
        if ( y < (szY>>1) || y > height - (szY>>1) )    mvY *= -1;

        x += mvX;
        y += mvY;
    }

    private final void display() {
        fill(cor);
        ellipse(x, y, szX, szY);
    }
}