Nyartoolkit- issue when attempting to increase resolution of webcam?

dreamweav..

Nyartoolkit- issue when attempting to increase resolution of webcam?

in Contributed Library Questions • 5 months ago

Hi,

I am having an issue here that when I am attempting to increase the resolution of the webcam when using the nyartoolkit library which is working fine on processing 1.5, the object does not render the object 'face on' even if

the marker is straight in front of the camera, it will load the object slanted.

It looks fine when opened on the original example resolution (640,480), you can see the object 'face on'

however if the resolution increased to anything higher than that, like 768x576 this is what happens:

this is the current code:

/**

NyARToolkit for proce55ing/1.0.0

airmail(at)ebony.plala.or.jp

最も短いARToolKitのコードです。

Hiroマーカを用意してください。

This sample program is most small sample as simpleLite.

The marker is "patt.hiro".

import processing.video.*;

import jp.nyatla.nyar4psg.*;

Capture cam;

MultiMarker nya;

void setup() {

size(768,576,P3D);

colorMode(RGB, 100);

println(MultiMarker.VERSION);

cam=new Capture(this,768,576);

nya=new MultiMarker(this,width,height,"camera_para.dat",NyAR4PsgConfig.CONFIG_PSG);

nya.addARMarker("patt.hiro",90);

}

void draw()

{

if (cam.available() !=true) {

return;

}

cam.read();

nya.detect(cam);

background(0);

nya.drawBackground(cam);//frustumを考慮した背景描画

if((!nya.isExistMarker(0))){

return;

}

nya.beginTransform(0);

fill(0,0,255);

translate(0,0,20);

box(40);

nya.endTransform();

}

Does anyone know why this could be happening? Or provide any suggestions? Am i missing something obvious here, as I am a beginner still.

Thanks

Appreciate any input, it would be greatly helpful for me and I sincerely appreciate it if you do

Replies(10)

mattcompe..

Re: Nyartoolkit- issue when attempting to increase resolution of webcam?

5 months ago

Unfortunately I do not have a solution for you, but I can confirm I've also been dealing with the same problem when using nyartoolkit both with processing 1.5 and 2.0b8. At first I thought it was just an issue for wide screen resolutions, but it seems to occur at all resolutions above 640 x 480.

amnon.owed

Re: Nyartoolkit- issue when attempting to increase resolution of webcam?

5 months ago

I ran into the same problem. While it's stated nowhere, this library can't handle higher resolutions. The solution / workaround is to adapt the dimensions of your input to something that it can handle like 640x480 or around these dimensions. Unfortunately the documentation is not very transparent either...

mattcompe..

Re: Nyartoolkit- issue when attempting to increase resolution of webcam?

5 months ago

Is there an alternative AR library you might recommend to use with Processing?

amnon.owed

Re: Nyartoolkit- issue when attempting to increase resolution of webcam?

5 months ago

Not really.

There is this one: http://code.google.com/p/simple-artoolkit-processing/

But it's hasn't been updated in a long time and I haven't used it myself.

mattcompe..

Re: Nyartoolkit- issue when attempting to increase resolution of webcam?

5 months ago

As a follow-up then, is it somehow possible to draw the AR output to an off screen buffer so that it can be resized and displayed at full screen resolution (I understand the quality would be poor, but at least you would get a fullscreen display).

nyatla

Re: Nyartoolkit- issue when attempting to increase resolution of webcam?

5 months ago

Hello,

ARToolkit is detecting a posture from the intersection angle of the straight line of the marker.
Therefore, the angle of two line closer to 90 degrees when it is taken from the front, it is not possible to calculate the exact posture. (It can be get position)

If you need correctly posture, you have to avoid capturing marker from the front.

mattcompe..

Re: Nyartoolkit- issue when attempting to increase resolution of webcam?

5 months ago

Hi nyatla, I assume you are the author of the library given your username. Are you planning a new release compatible with Processing 2.0? Thanks for your great work on the project, I've enjoyed using it a great deal.

nyatla

Re: Re: Nyartoolkit- issue when attempting to increase resolution of webcam?

5 months ago

NARToolkit for processing 1.3.1 can work on 2.0 beta 8.
However, required jar is different by 2.0 and 1.5.

For 2.0, please see examples/2.x. It uses NyAR4psg2b.jar + NyARToolkit.jar
For 1.5, please see examples/1.x. It uses NyAR4psg.jar + NyARToolkit.jar

Thanks

dreamweav..

Re: Nyartoolkit- issue when attempting to increase resolution of webcam?

5 months ago

Thanks for the responses.

So this is definitely a universal problem that at the moment cannot be fixed due to the library itself being unable to handle higher resolutions.

I guess the only solution is to minimise the resolution of the screen to make the webcam capture larger.

Thanks

mattcompe..

Re: Nyartoolkit- issue when attempting to increase resolution of webcam?

5 months ago

If all you are looking to do is have the AR displayed larger, then I've cobbled together some rough code that draws everything to a PGraphics which is later resized to display at a higher resolution. It would be nice if the library could support higher input resolution at some point for more robust detection pattern detection. Code below:

import codeanticode.gsvideo.*;
import processing.opengl.*;
import jp.nyatla.nyar4psg.*;
MultiMarker augmentedReality;
GSCapture webCam;
PMatrix3D markerMatrix;
PMatrix3D projectionMatrix;
final String CAM_PATH = "camera_para.dat";
final String PATT_PATH = "/patts";
int markerSize = 100;
PGraphics buffer;
void setup() {
size(1280, 960, OPENGL);
buffer = createGraphics(640, 480, P3D);
initializeWebCam();
initializeAugmentedReality();
}
void draw() {
if (webCam.available()) {
webCam.read();
augmentedReality.detect(webCam);
background(0);
image(webCam, 0, 0, 1280, 960);
if (augmentedReality.isExistMarker(0)) {
markerMatrix = augmentedReality.getMarkerMatrix(0);
projectionMatrix = augmentedReality.getProjectionMatrix();
buffer.beginDraw();
//BEGINNING OF CODE FROM NYAR SOURCE
float far=projectionMatrix.m23/(projectionMatrix.m22+1);
float near=projectionMatrix.m23/(projectionMatrix.m22-1);
buffer.frustum(
(projectionMatrix.m02-1)*near/projectionMatrix.m00,
(projectionMatrix.m02+1)*near/projectionMatrix.m00,
(projectionMatrix.m12-1)*near/projectionMatrix.m11,
(projectionMatrix.m12+1)*near/projectionMatrix.m11,
near, far);
//END OF CODE FROM NYAR SOURCE
buffer.pushMatrix();
buffer.setMatrix(markerMatrix);
buffer.noStroke();
buffer.lights();
buffer.sphere(50);
buffer.popMatrix();
buffer.endDraw();
PImage bufferImage = buffer.get();
image(bufferImage, 0, 0, 1280, 960);
}
}
}
void initializeAugmentedReality() {
augmentedReality = new MultiMarker(this, 640, 480, CAM_PATH, NyAR4PsgConfig.CONFIG_PSG);
augmentedReality.addARMarker(PATT_PATH + "/4x4_" + 2 + ".patt", markerSize);
}
void initializeWebCam() {
String[] cameraList = GSCapture.list();
if (cameraList.length == 0)
{
println("There are no cameras available for capture.");
exit();
}
else {
println("Available cameras:");
for (int i = 0; i < cameraList.length; i++) {
println(cameraList[i]);
}
webCam = new GSCapture(this, 640, 480, cameraList[0]);
webCam.start();
/*
// You can get the resolutions supported by the
// capture device using the resolutions() method.
// It must be called after creating the capture
// object.
int[][] res = cam.resolutions();
for (int i = 0; i < res.length; i++) {
println(res[i][0] + "x" + res[i][1]);
}
*/
/*
// You can also get the framerates supported by the
// capture device:
String[] fps = cam.framerates();
for (int i = 0; i < fps.length; i++) {
println(fps[i]);
}
*/
}
}

Top Reply