NullPointerException

Programming Questions

xlotraw

in Programming Questions • 1 month ago

I'm still a beginner in coding and decided to practice basic algorithms and how to make objects display at a given time after pressing play. My question is why does the following code yield the error message "NullPointerException"? The bold blue line is the one that is highlighted with the error message. Basically, I was trying to create a sketch that would create a button at a random location every 2 seconds. What am I overlooking? Thanks in advance for all the help.

Button[] buttons;

Timer timer;

int totalButtons = 0;

void setup() {

size(800, 800);

smooth();

buttons = new Button[100];

timer = new Timer(2000);

timer.start();

}

void draw() {

background(255);

buttons = new Button[100];

if (timer.isFinished()) {

buttons[totalButtons] = new Button();

totalButtons++;

if (totalButtons >= buttons.length) {

totalButtons = 0;

}

timer.start();

}

for (int i = 0; i < totalButtons; i++) {

buttons[i].display();

}

class Timer {

int savedTime;

int totalTime;

Timer(int totalTime_) {

totalTime = totalTime_;

}

void start() {

savedTime = millis();

}

boolean isFinished() {

int passedTime = millis() - savedTime;

if (passedTime > totalTime) {

return true;

}

else {

return false;

}

class Button {

color c;

float xpos;

float ypos;

float r;

Button() {

c = color(0, 0, 200);

xpos = random(width);

ypos = random(height);

r = 8;

}

void display() {

fill(c);

ellipse(xpos, ypos, r*2, r*2);

}

Replies(7)

asimes

Re: NullPointerException

1 month ago

Remove:

buttons = new Button[100];

from draw(). The error is being thrown because you are wiping out your Button elements and then still trying to use their display() method.

xlotraw

Re: NullPointerException

1 month ago

I tried removing this and the error persisted.

quarks

Re: Re: NullPointerException

1 month ago

I hope you removed the line from draw and not setup

tfguy44

Re: NullPointerException

1 month ago

Button[] buttons; // This says "Prepare to have an array of buttons here."
buttons = new Button[100]; // This says "Reserve spaces for 100 buttons here."
-- A step is missing here. --
buttons[i].display(); // This says "Draw the ith button."

What step is missing?
You marked a place in memory where buttons would be.

You made sure there was enough memory at that place for 100 buttons.

BUT... You never actually created any buttons!

The missing step is
buttons[i] = new Button(); // "Create a button at position i."

Since you want 100 buttons, and you only want to create them once, add this to setup():

for (int i = 0; i < totalButtons; i++) {
buttons[i] = new Button();
}

xlotraw

Re: NullPointerException

1 month ago

That is a very good point. However, I tried inserting those three lines to setup and it's still giving me an error message. If I delete the blue bolded line, it doesn't draw any buttons. However, if I keep that line there, it draws one button and then immediately crashes, reading "NullPointerException". Any tips on how I should proceed?

PhiLho

Re: NullPointerException

1 month ago

First, see the Why do I get a NullPointerException? article (n case you don't understand what is an NPE).
Second, show your current code showing the error, perhaps you have misplaced something or made another error.

Actually, the point of tfguy44 is valid in most sketches, but void here, as the array is progressively built when the timer goes off. If I apply the advice of asimes, your sketch works...

So, go back to the state you show in your first message and try again the solution given by asimes.

asimes

Re: NullPointerException

1 month ago

The sketch does work by removing the correct buttons = new Button[100]:

Button[] buttons;
Timer timer;
int totalButtons = 0;
void setup() {
size(800, 800);
smooth();
buttons = new Button[100];
timer = new Timer(2000);
timer.start();
}
void draw() {
background(255);
//buttons = new Button[100];
if (timer.isFinished()) {
buttons[totalButtons] = new Button();
totalButtons++;
if (totalButtons >= buttons.length) {
totalButtons = 0;
}
timer.start();
}
for (int i = 0; i < totalButtons; i++) {
buttons[i].display();
}
}
class Timer {
int savedTime;
int totalTime;
Timer(int totalTime_) {
totalTime = totalTime_;
}
void start() {
savedTime = millis();
}
boolean isFinished() {
int passedTime = millis() - savedTime;
if (passedTime > totalTime) {
return true;
}
else {
return false;
}
}
}
class Button {
color c;
float xpos;
float ypos;
float r;
Button() {
c = color(0, 0, 200);
xpos = random(width);
ypos = random(height);
r = 8;
}
void display() {
fill(c);
ellipse(xpos, ypos, r*2, r*2);
}
}

That being said, tfguy44 has a good point, just make all the buttons at the beginning and only display as many as needed. Same sketch with some tweaks:

Button[] buttons;
Timer timer;
int totalButtons = 0;
void setup() {
size(800, 800);
// Unless you add other objects there is no need to call this more than once
fill(0, 0, 200);
smooth();
buttons = new Button[100];
for (int i = 0; i < buttons.length; i++) buttons[i] = new Button();
timer = new Timer(2000);
timer.start();
}
void draw() {
background(255);
if (timer.isFinished()) {
totalButtons++;
if (totalButtons >= buttons.length) {
totalButtons = 0;
// ...code for randomizing button positions could go here...
}
timer.start();
}
for (int i = 0; i < totalButtons; i++) buttons[i].display();
}
class Timer {
int savedTime, totalTime;
Timer(int totalTime_) {
totalTime = totalTime_;
}
void start() {
savedTime = millis();
}
boolean isFinished() {
// This does the same thing as the original code
// It is a shorthand that returns true or false based on the condition
return (millis()-savedTime > totalTime);
}
}
class Button {
// Unlike Timer this constructor does not take arguments
// There is no need to store c or r because they are always the same
float xpos, ypos;
Button() {
xpos = random(width);
ypos = random(height);
}
void display() {
ellipse(xpos, ypos, 16, 16);
}
}

Top Reply