Null Pointer (only with P2D) when loading multiple images to PGraphics objects

Core Library Questions

liamos

Null Pointer (only with P2D) when loading multiple images to PGraphics objects

in Core Library Questions • 3 months ago

HI all- long time watcher, first time poster.

I'm loading 20 images to PGraphics objects and tiling them to the screen. Everything works perfectly when no renderer is specified (PDE 2.01) but I can't use mask(). So trying to use P2D, P3D, OpenGL instead. This notably slows the image load time on running the sketch, but the images load okay. If I try to reload 20 new images I get a NPE as per the error message below. I must stress that this doesn't happen if P2D etc not specified, so I don't think it's a problem with my sketch as such. I'm doing some other stuff with the image data (copying brightness values to an array) which could be taking some time, so I'm worried this is a nasty threading issue.

The code is too big to post, but I'll try to recreate in a simpler sketch. In the meantime, all comments and ideas welcome.

java.lang.RuntimeException: java.lang.NullPointerException
at com.jogamp.common.util.awt.AWTEDTExecutor.invoke(AWTEDTExecutor.java:58)
at jogamp.opengl.awt.AWTThreadingPlugin.invokeOnOpenGLThread(AWTThreadingPlugin.java:100)
at jogamp.opengl.ThreadingImpl.invokeOnOpenGLThread(ThreadingImpl.java:205)
at javax.media.opengl.Threading.invokeOnOpenGLThread(Threading.java:172)
at javax.media.opengl.Threading.invoke(Threading.java:191)
at javax.media.opengl.awt.GLCanvas.display(GLCanvas.java:483)
at processing.opengl.PGL.requestDraw(PGL.java:1155)
at processing.opengl.PGraphicsOpenGL.requestDraw(PGraphicsOpenGL.java:1602)
at processing.core.PApplet.run(PApplet.java:2141)
at java.lang.Thread.run(Thread.java:662)
Caused by: java.lang.NullPointerException
at rastogramPlayer1.mapImageDataToSignal(rastogramPlayer1.java:166)
at rastogramPlayer1.loadRandomImages(rastogramPlayer1.java:139)
at rastogramPlayer1.keyPressed(rastogramPlayer1.java:287)
at processing.core.PApplet.keyPressed(PApplet.java:3355)
at processing.core.PApplet.handleKeyEvent(PApplet.java:3173)
at processing.core.PApplet.dequeueEvents(PApplet.java:2610)
at processing.core.PApplet.handleDraw(PApplet.java:2281)
at processing.opengl.PGL$PGLListener.display(PGL.java:2643)
at jogamp.opengl.GLDrawableHelper.displayImpl(GLDrawableHelper.java:576)
at jogamp.opengl.GLDrawableHelper.display(GLDrawableHelper.java:561)
at javax.media.opengl.awt.GLCanvas$7.run(GLCanvas.java:1054)
at jogamp.opengl.GLDrawableHelper.invokeGLImpl(GLDrawableHelper.java:1024)
at jogamp.opengl.GLDrawableHelper.invokeGL(GLDrawableHelper.java:899)
at javax.media.opengl.awt.GLCanvas$8.run(GLCanvas.java:1065)
at java.awt.event.InvocationEvent.dispatch(InvocationEvent.java:199)
at java.awt.EventQueue.dispatchEventImpl(EventQueue.java:666)
at java.awt.EventQueue.access$400(EventQueue.java:81)
at java.awt.EventQueue$2.run(EventQueue.java:627)
at java.awt.EventQueue$2.run(EventQueue.java:625)
at java.security.AccessController.doPrivileged(Native Method)
at java.security.AccessControlContext$1.doIntersectionPrivilege(AccessControlContext.java:87)
at java.awt.EventQueue.dispatchEvent(EventQueue.java:636)
at java.awt.EventDispatchThread.pumpOneEventForFilters(EventDispatchThread.java:269)
at java.awt.EventDispatchThread.pumpEventsForFilter(EventDispatchThread.java:184)
at java.awt.EventDispatchThread.pumpEventsForHierarchy(EventDispatchThread.java:174)
at java.awt.EventDispatchThread.pumpEvents(EventDispatchThread.java:169)
at java.awt.EventDispatchThread.pumpEvents(EventDispatchThread.java:161)
at java.awt.EventDispatchThread.run(EventDispatchThread.java:122)

Replies(9)

amnon.owed

Re: Null Pointer (only with P2D) when loading multiple images to PGraphics objects

3 months ago

Could be threading. Depends on how/where you load the images.

You can check for null, before you use the image(s) to solve the NPE.

Post a code example that displays the problem. Otherwise you can't get help nor file a bug report.

liamos

Re: Null Pointer (only with P2D) when loading multiple images to PGraphics objects

3 months ago

Wow, thanks for the speedy reply. I've trimmed down the sketch to what's below. The data folder has 20 200x200 images in it that are loaded. As I say, they load when my loadImages() method is called from setup, but calling via a keypress event causes the NPE. If you comment out the P2D parameter in size() and createGraphics(), it's fine.

Apologies for the formatting below, I can't seem to get the insert code button to work.

PGraphics [] images;
float [][] arrays;
int nImages = 20, nCols =5, nRows =4; //grid of 5 columns and 4 rows
int screenW = 200*nCols; //images are 200x200px
int screenH = 200*nRows;
int nPixels;

void setup() {
size(screenW, screenH); //, P2D); //comment out P2D to avoid NPE
nPixels = 200*200;
images = new PGraphics[nImages];
arrays = new float [nImages][nPixels];
loadImages();
}

void draw() {
displayImages();
}

void loadImages() {
for (int p=0;p<nImages;p+=1) {
    PImage temp = loadImage("data/image"+(p+1)+".bmp"); // Load images into temp PImage
    images[p] = createGraphics(200, 200);//, P2D);
    images[p].beginDraw();
    images[p].colorMode(HSB);
    images[p].image(temp, 0, 0);                   //Draw the image onto the PGraphics object
    images[p].endDraw();
    copyToArray(p);
}
}

float [] copyToArray(int p) {
float [] array = new float [nPixels];
for (int i=0; i<images[p].height; i+=1) {
    for (int j=0;j<images[p].width;j+=1) {
      array [j+(i*200)] = map(brightness(images[p].pixels[j+(i*images[p].width)]), 0, 255, -1.0F, 1.0F);
    }
}
return array;
}

void displayImages() {
for (int i=0;i<nImages;i+=1) {
    int colIndex = i%nCols;
    int rowIndex = floor(i/(nRows+1));
    image(images[i], colIndex*200, rowIndex*200);
}
}

void keyPressed() {
switch(key) {
case ' ':
    loadImages();             //pressing spacebar calls loadImages(), and triggers NPE
    break;
default:
    break;
}
}

amnon.owed

Re: Null Pointer (only with P2D) when loading multiple images to PGraphics objects

3 months ago

Perhaps the purpose of some parts of this sketch got lost in the trimming, for example:

Why reload the same images, instead of keeping an original copy?
What's the point of drawing an image to a PGraphics?
copyToArray returns an array into nothing?

But the basic problem seems to be that you do a lot of things in the loadImages() method that take more than 1/60 of a second. The default JAVA2D renderer probably/apparantly waits for all this to finish, but the OpenGL renderer just carries on, causing a NPE.

As suggested before, the easiest way to solve this is to check for null. In your displayImages() method change:

image(images[i], colIndex*200, rowIndex*200);

...into...

if (images[i] != null) image(images[i], colIndex*200, rowIndex*200);

liamos

Re: Null Pointer (only with P2D) when loading multiple images to PGraphics objects

3 months ago

Yeah I'm doing all that stuff for the particular application I'm working on- the images get loaded randomly from a large pool so that the onscreen grid can be changed, I need to be able to operate on images (e.g. rotation) and have the changes copied out to the array (e.g. rather than trying to read pixels and rotate with some matrix arithmetic) and the returned array is actually passed on to another process, but I cut all that out here.

I thought of setting up a flag to check when the array has finished loading, but I'll give the 'check for null' a shot first. Thanks again.

liamos

Re: Null Pointer (only with P2D) when loading multiple images to PGraphics objects

3 months ago

The null check doesn't seem to work. The line causing the problem contains the pixels[] lookup:

array [j+(i*200)] = images[p].pixels[j+(i*200)];

If I c hange that to a simple assignment e.g.

array [j+(i*200)] = 50;

The problem disappears.

I don't know anything about renderers or threading, so not really sure what's going on here. I realise I'm trying to do a lot by reading from the pixels array, but I didn't think the renderer would cause an NPE as I'm triggering the array read from a key press, rather than from within draw(). Tricky...

liamos

Re: Null Pointer (only with P2D) when loading multiple images to PGraphics objects

3 months ago

Tried implementing a flag to check when the reads from pixels[] were complete as per below, but no luck.

PGraphics [] images;
float [][] arrays;
int nImages = 10, nCols =5, nRows =4;
int screenW = 200*nCols;
int screenH = 200*nRows;
int nPixels;
boolean isCopied = false;
void setup() {
size(screenW, screenH, P2D); //comment out P2D to avoid NPE
nPixels = 200*200;
images = new PGraphics[nImages];
arrays = new float [nImages][nPixels];
loadImages();
}
void draw() {
displayImages();
}
void loadImages() {
for (int p=0;p<nImages;p+=1) {
PImage temp = loadImage("data/image"+(p+1)+".bmp"); // Load images into temp PImage
images[p] = createGraphics(200, 200, P2D);
images[p].beginDraw();
images[p].colorMode(HSB);
images[p].image(temp, 0, 0);
images[p].endDraw();
copyToArray(p);
}
}
float [] copyToArray(int p) {
float [] array = new float [nPixels];
isCopied=false;
for (int i=0; i<images[p].height; i+=1) {
for (int j=0;j<images[p].width;j+=1) {
array [j+(i*200)] = images[p].pixels[j+(i*200)];
}
}
isCopied=true;
return array;
}
void displayImages() {
for (int i=0;i<nImages;i+=1) {
int colIndex = i%nCols;
int rowIndex = floor(i/(nRows+1));
if (isCopied) {
image(images[i], colIndex*200, rowIndex*200);
}
}
}
void keyPressed() {
switch(key) {
case ' ':
loadImages();
break;
}
}

liamos

Re: Null Pointer (only with P2D) when loading multiple images to PGraphics objects

3 months ago

An even-more-stripped-back version of the sketch which still exhibits the same behavior. Comment out both occurrences of P2D and all is well.

Does anyone think this constitutes a bug?

PGraphics img;
float [] array;
int nPixels;
void setup() {
size(200, 200, P2D);
frameRate(25);
nPixels = width*height;
array = new float [nPixels];
loadSingleImage(0);
}
void draw() {
image(img, 0, 0);
}
void loadSingleImage(int p) {
PImage temp = loadImage("data/image"+(p+1)+".bmp"); // Load imgs into temp PImage
img = createGraphics(200, 200, P2D);
img.beginDraw();
img.image(temp, 0, 0);
img.endDraw();
}
void copyToArray() {
for (int i=0; i<height; i+=1) {
for (int j=0;j<width;j+=1) {
array [j+(i*width)] = img.pixels[j+(i*width)];
}
}
}
void keyPressed() {
switch(key) {
case ' ':
loadSingleImage(int(random(20)));
copyToArray();
break;
}
}

amnon.owed

Re: Null Pointer (only with P2D) when loading multiple images to PGraphics objects

3 months ago

Ok, I can reproduce the error with your small code example. However this is not a bug, but a coding error.

In your copyToArray() method you use pixels from the PGraphics called img. While in the past it wasn't required in many cases, it has always been formally required to call loadPixels before you use the pixel array. Doing so in this case solves the error. In other words place the following line at the beginning of the copyToArray() method:

img.loadPixels();

While you should formally always call loadPixels before using a pixel array anyway, you can additionally / alternatively move line 20 (createGraphics) to setup(). It is a costly and unnecessary operation. You already reload and redraw the image on the PGraphics canvas. Even if you wanted to clear it, a call to background() would be more efficient. Moving the creation of PGraphics to setup() will also solve the error (but you should include loadPixels anyway to prevent exactly the types of errors you run into).

liamos

Re: Null Pointer (only with P2D) when loading multiple images to PGraphics objects

3 months ago

Awesome, you nailed it. The call to createGraphics() in my method was dumb (there was a reason for this in earlier versions of the code but I should have moved it out). By the way, I think can actually get away without the call to loadpixels() which means performance holds up, but will keep an eye out for buggy behavior as a result.

Thanks!

Top Reply