Null pointer and number format exceptions

hatsaresi..

Null pointer and number format exceptions

in Integration and Hardware • 1 year ago

I keep getting a NumberFormatException, I think due to garbage data from the arduino every once in a while, but it also seems to cause a NullPointerException, for which I have no explanation. The code runs successfully for a while, until it gets some bad data. Sometimes even seemingly good data will cause it to crash. I can't seem to figure out how to catch this thing properly to keep it from crashing. Please help?

// Processing code for this example

// Graphing sketch

// This program takes ASCII-encoded strings
// from the serial port at 9600 baud and graphs them. It expects values in the
// range 0 to 1023, followed by a newline, or newline and carriage return

// Created 20 Apr 2005
// Updated 18 Jan 2008
// by Tom Igoe
// This example code is in the public domain.

import processing.serial.*;

Serial myPort;        // The serial port
int xPos = 1;         // horizontal position of the graph

void setup () {
// set the window size:
size(1900, 1020);

// List all the available serial ports
println(Serial.list());
// I know that the first port in the serial list on my mac
// is always my Arduino, so I open Serial.list()[0].
// Open whatever port is the one you're using.
myPort = new Serial(this, Serial.list()[0], 9600);
// don't generate a serialEvent() unless you get a newline character:
myPort.bufferUntil('\n');
// set inital background:
background(0);
}
float inByte = 0;
float[] inByteA = new float[2];
int[] inInt = new int[2];
String[] inString = new String[2];
int x = 0;
int y = 0;

void draw () {
// everything happens in the serialEvent()
}

void serialEvent (Serial myPort) {
// get the ASCII string:
String trimmedString = trim(myPort.readStringUntil('\n'));
try {
    inString = splitTokens(trimmedString, ",");
}
catch (Exception e) {
    println("dumbass: "+e);
    delay(2000);
}
//println(inString[1]);
// print(":");
// println(inString[1]);

for (int i = 0; i < inString.length; i++) {
    if (inString[i] != null) {

      // convert to an int and map to the screen height:
      try {
        inByte = float(inString[i]);
      }
      catch (NumberFormatException excp) {
        inByte = 0;
        println("fucking: "+excp);
      }
      inByteA[i] = map(inByte, 0, 1023, 0, height);
      String temp = inString[i];
      println(temp);
      try {
        inInt[i] = Integer.parseInt(temp);
      }
      catch (Exception e) {
        println("goddamn: "+e);
        inInt[i]=0;
        println("i: "+i);
      }
      finally {}

      if (inInt[i]>=1) {
        print(i);
        print(":");
        println(inInt[i]);
      }
    }
}
// at the edge of the screen, go back to the beginning:
if (xPos >= width) {
    xPos = 0;
    background(0);
}
else if (inInt[0]!=0 || inInt[1]!=0) {
    // draw the line:
    stroke(127, 34, 255);
    line(xPos, height/2, xPos, height/2 - inByteA[0]);
    stroke(216, 24, 24);
    line(xPos, height/2, xPos, height/2 + inByteA[1]);

    // increment the horizontal position:
    xPos++;
}
}

Replies(7)

hatsaresi..

Re: Null pointer and number format exceptions

1 year ago

Played with this some more, it seems like the map function is causing the initial problem. However, the values it chokes on look valid. I'm starting to wonder if I found a bug...

PhiLho

Re: Null pointer and number format exceptions

1 year ago

I move this from Programming Questions because we cannot run your code without your hardware.
So we also cannot answer your question as your code isn't trivial. You have to indicate where the exception occurs. There are several places where it can happen.

hatsaresi..

Re: Null pointer and number format exceptions

1 year ago

Ok, I think I figured out part of the problem. Occasionally two lines of data are arriving as one, so instead of something like:

I am getting:

0,00,0

So the splitTokens function is trying to put:

{0,00,0}

into an array which only has a length of two, not three.

I'm still not clear on why this in itself causes a null pointer exception, but I'm still a newbie.

At least I have an idea of what the problem is now, but I still don't know the best way to solve it. I think with this new information this thread may be better off in programming questions, but I'll leave that up to you.

PhiLho

Re: Null pointer and number format exceptions

1 year ago

Well, again, show the line where you have the NPE, and we will explain how to avoid it.

hatsaresi..

Re: Null pointer and number format exceptions

1 year ago

OK, here are the errors I get after modifying the code a bit with some try/catch blocks.

inInt: java.lang.NumberFormatException: For input string: "0 "
i: 1
inByteA: java.lang.ArrayIndexOutOfBoundsException: 2
trimmedString: "0,0 ,0"
0
inInt: java.lang.ArrayIndexOutOfBoundsException: 2
error, disabling serialEvent() for /dev/ttyUSB0
java.lang.reflect.InvocationTargetException
    at sun.reflect.GeneratedMethodAccessor1.invoke(Unknown Source)
    at sun.reflect.DelegatingMethodAccessorImpl.invoke(DelegatingMethodAccessorImpl.java:25)
    at java.lang.reflect.Method.invoke(Method.java:597)
    at processing.serial.Serial.serialEvent(Unknown Source)
    at gnu.io.RXTXPort.sendEvent(RXTXPort.java:772)
    at gnu.io.RXTXPort.eventLoop(Native Method)
    at gnu.io.RXTXPort$MonitorThread.run(RXTXPort.java:1641)
Caused by: java.lang.ArrayIndexOutOfBoundsException: 2
    at Vibration_Sensors.serialEvent(Vibration_Sensors.java:107)
    ... 7 more

And here is the current code in it's entirety with relevant lines highlighted:

// Processing code for this example

// Graphing sketch

// This program takes ASCII-encoded strings
// from the serial port at 9600 baud and graphs them. It expects values in the
// range 0 to 1023, followed by a newline, or newline and carriage return

// Created 20 Apr 2005
// Updated 18 Jan 2008
// by Tom Igoe
// This example code is in the public domain.

import processing.serial.*;

Serial myPort;        // The serial port
int xPos = 1;         // horizontal position of the graph

void setup () {
// set the window size:
size(1900, 1020);

// List all the available serial ports
println(Serial.list());
// I know that the first port in the serial list on my mac
// is always my Arduino, so I open Serial.list()[0].
// Open whatever port is the one you're using.
myPort = new Serial(this, Serial.list()[0], 9600);
// don't generate a serialEvent() unless you get a newline character:
myPort.bufferUntil('\n');
// set inital background:
background(0);
}
float inByte = 0;
float[] inByteA = new float[2];
int[] inInt = new int[2];
String[] inString = new String[2];
int x = 0;
int y = 0;

void draw () {
// everything happens in the serialEvent()
}

void serialEvent (Serial myPort) {
// get the ASCII string:
String trimmedString = trim(myPort.readStringUntil('\n'));
try {
    inString = splitTokens(trimmedString, ",");
}
catch (Exception e) {
    println("inString: "+e);
    delay(2000);
}
//println(inString[1]);
// print(":");
// println(inString[1]);

for (int i = 0; i < inString.length; i++) {
    if (inString[i] != null) {

      // convert to an int and map to the screen height:
      try {
        inByte = float(inString[i]);
      }
      catch (NumberFormatException excp) {
        inByte = 0;
        println("inByte: "+excp);
      }
      try {
        inByteA[i] = map(inByte, 0, 1023, 0, height);
      }
      catch (Exception e) {
        println("inByteA: "+e);
        println("trimmedString: \""+trimmedString+"\"");
        delay(2000);
      }
      String temp = inString[i];
      println(temp);
      try {
        inInt[i] = Integer.parseInt(temp);
      }
      catch (Exception e) {
        println("inInt: "+e);
        inInt[i]=0;
        println("i: "+i);
      }
      if (inInt[i]>=1) {
        print(i);
        print(":");
        println(inInt[i]);
      }
    }
}
// at the edge of the screen, go back to the beginning:
if (xPos >= width) {
    xPos = 0;
    background(0);
}
else if (inInt[0]!=0 || inInt[1]!=0) {
    // draw the line:
    stroke(127, 34, 255);
    line(xPos, height/2, xPos, height/2 - inByteA[0]);
    stroke(216, 24, 24);
    line(xPos, height/2, xPos, height/2 + inByteA[1]);

    // increment the horizontal position:
    xPos++;
}
}

PhiLho

Re: Null pointer and number format exceptions

1 year ago

You don't show a NullPointerException (NPE), but an ArrayIndexOutOfBoundsException, which is quite a different thing!
That's why this topic is here: we are entirely dependent on your information, as we cannot run your code. Indeed, it is more a Programming Question, but if you cannot isolate the code in an easy to run sketch, it is dependent on the output of the hardware.

At least, you analyzed the origin of the problem. Your code does a bit too much try/catch, as Processing rarely throws exceptions in its functions (splitToken(), float()), and runtime errors like NPE or out of bounds exceptions can be checked before they happen (is value null? is index in the bounds?).
The main problem is to know what to do with the erroneous transmissions. If that's a bug on the Arduino side, you can try and fix it. If that's a transmission issue, you have to deal with the faulty string, either rejecting it or trying to replace the wrong values with fake values. If you receive 3.140.7, we don't know if that's 3.14 0.7 or 3.1 40.7, so it is hard to split accurately.

Here is a simplified version of your code:

// get the ASCII string:
String trimmedString = trim(myPort.readStringUntil('\n'));
println("trimmedString: >" + trimmedString + "<");
inString = splitTokens(trimmedString, ",");
println("inString: " + inString.length);
if (inString.length > inByteA.length) {
return; // Or take corrective measures
}
for (int i = 0; i < inString.length; i++) {
// convert to an int and map to the screen height:
try {
// Use a method that can throw an exception, to detect the issue
// Or just use float() without the try/catch and get a zero for an incorrect value
inByte = Float.valueOf(inString[i]);
}
catch (NumberFormatException excp) {
inByte = 0;
println("inByte: "+excp);
}
inByteA[i] = map(inByte, 0, 1023, 0, height);

I don't understand why, after parsing inString[i] to a float, you attempt to parse it to an int. Seems redundant.

To answer your legitimate question "why an exception?", you get the array index out of bounds because as you analyzed, you have a string with two commas instead of one, so split returns three values instead of two, and i goes too far with regard to the target array. As you can see, I address the issue up front, no need to enter the loop and see the issue in the middle of the code.

hatsaresi..

Re: Null pointer and number format exceptions

1 year ago

I think the NPE I was getting was indeed caused by a null value. I have now eliminated the problem and simplified my code. You were right about the int being redundant, it was not even needed. Here is my solution in case you are interested, or for the chance it may help someone later on. Thanks for all your help!

import processing.serial.*;

Serial myPort;        // The serial port
int xPos = 1;         // horizontal position of the graph

void setup () {
// set the window size:
size(1900, 1020);

// List all the available serial ports
println(Serial.list());
// I know that the first port in the serial list on my mac
// is always my Arduino, so I open Serial.list()[0].
// Open whatever port is the one you're using.
myPort = new Serial(this, Serial.list()[0], 9600);
// don't generate a serialEvent() unless you get a newline character:
myPort.bufferUntil('\n');
// set inital background:
background(0);
}

void draw () {
// everything happens in the serialEvent()
}

void serialEvent (Serial myPort) {
String myString = "";
String trimmedString = "";
String[] inString = new String[2];
float[] inByteA = new float[2];

// get the ASCII string:
myString = myPort.readStringUntil('\n');
//Trim off white space
trimmedString = trim(myString);
//Make sure string conatins only 1-4 digits a comma and then 1-4 digits. Otherwise set to 0.
if (!trimmedString.matches("\\d{1,4},\\d{1,4}")) {
    trimmedString = "0";
    println("Bad data detected: "+myString);
    delay(1000);
}
//Data should be clean at this point or ignored.

//Split string into an array to handle data from multiple sensors.
inString = splitTokens(trimmedString, ",");

//For each sensor, map the value for graphing.
for (int i = 0; i < inString.length; i++) {
    // convert to a float and map to the screen height:

    inByteA[i] = map(float(inString[i]), 0, 1023, 0, height);
    //println(map(inByte, 0, 1023, 0, height));
}

// at the edge of the screen, go back to the beginning:
if (xPos >= width) {
    xPos = 0;
    background(0);
}
//Ignore if 0 or less, otherwise, graph it!
else if (inByteA[0] > 0 || inByteA[1] > 0) {
    // draw the line:
    stroke(127, 34, 255);
    line(xPos, height/2, xPos, height/2 - inByteA[0]);
    stroke(216, 24, 24);
    line(xPos, height/2, xPos, height/2 + inByteA[1]);

    // increment the horizontal position:
    xPos++;
}
}