you need to call question2() from draw()

Thank you for your response. I tried  that and All it does is skip to the 2nd question without asking first at all

[EDITED]

I think there's more to it...

you need to check if firstname is not "" anymore (ENTER has been pressed) before you call question2()

1. if ( !firstname.equals("") ) {
2.     question2() ;
3. }

I think....

note the ! before firstname

see
http://processing.org/reference/String.html

Awesome that works. I don't mean to bombard you with questions. now that it goes to the 2nd question

you could use a similar approach and say instead of

1. void keyReleased()
2. {
3.   if (keyCode == BACKSPACE) 
4.   {
5.     if (typing.length() > 0) 
6.     {
7.       typing = typing.substring(0, typing.length()-1);
8.     }
9.   } 
10.   else if (keyCode != SHIFT && keyCode != CONTROL && keyCode != ALT)
11.   {
12.     typing = typing + key;
13.   }}

here

1. case ENTER:
2.     firstname = typing;
3.     question2();   
   
4.     break;

later you could have states of program and say

1. state = getName;
2. state = getYesNo;
3. state = play;

etc.

with

1. final int getName=0;
2. final int getYesNo=1;
3. final int play=2;

and in draw() do different things depending on state (use switch)
and in keyPressed() too do different things depending on state (use switch)

thank you so much. you are very helpful. As the program is right now, it executes until trying to retrieve y/n where it just flashes back to the second question. is there a way to fix that with out using states.

this can't work

1.   case 'y':
2.     answer = key;
3.     text("Let's play!", indent, 40);
4.     break;
5.   case 'n':
6.     background(255);   
   
7.     text("You said no :(", indent, 40);

in a global var before setup()

1. int answerToYesNo = -1;

and modify the code above to

1.   case 'y':
2.     answer = key;
3.     answerToYesNo = 1;
4.     break;
5.   case 'n':
6.     background(255);    
7.     answerToYesNo = 2;
8.     break;
9. 
   

since the values -1 and 1 and 2 are hard to read you could give them names before setup() and say

1. final int heHasntAnsweredYet = -1;
2. final int heAnsweredYes = 1;
3. final int heAnsweredNo  = 2;

and use those vars (constants) instead of -1 and 1 and 2 above - better readable

states: easy. Useful.

Before setup

1. final int getName=0;
2. final int getYesNo=1;
3. final int play=2;
4. final int HeWontPlay=3;
5. 
   
6. int state = getName;

in draw()

1. background(255);   
2. switch (state) {
3. case getName:
4.     question1();
5.     break;
6. case getYesNo:
7.     question2();
8.     break;
9. case play:
10.    text("Let's play!", indent, 40);
11.    break;
12. case HeWontPlay:
13.    text("You said no :(   ", indent, 40);
14.    break;
    
15. } // switch
    

hello,

or shorter:
in draw()

1. switch (answer) {
2. case 0:
3.   question1();
4.  
5.   if ( !firstname.equals("") ) {
6.     question2() ;
7.   }
8.   break;
9. case 'y':
10.  
11.    text("Let's play!", indent, 40);
12.    break;
13. case 'n':
14.    text("You said no :(   ", indent, 40);
15.    break;
16. }

Greetings, Chrisir   

is it possible to have switch in set up? so if two different "states" each state has own setup

" is it possible to have switch in set up? so if two different "states" each state has own setup"
It is possible, but then it would be configuration, depending on a constant or a value in a file: setup() is called only once per run.

I agree with PhiLho...

But why did you ask? What do you want to achieve?

Maybe if you tell us that we can help.

You can also post your code as it is and I will have a look tonight (european time)

hello,

the program below shows the general idea when using states.
I put in a mini game, too.
States are cool once you know what they are for.

In other programming languages, he goes through step by step from
beginning to end once.
There you could ask for the name then ask if he or she wants to
play then play. (the way you wanted to program your sketch first)

In processing, draw() is run again and again, 60 times per second.
The output on the screen is only updated at the end of draw() each time.

Therefore you can not  ask for the name, then ask if he or she wants to
play: It would be on the screen all together. And give a little mess.

That's where states come in: only that is drawn that is needed in
the current state. When your stuff for the state is done, proceed to the next
state.

Proceed to the next state can be e.g.: He won. Game is over, new state
is he or she won. Show message "You won."
Proceed to the next state can be also done by a timer, so after 1 second or so.
That's handy if you want to show a message for 1 or 2 seconds and then move on.

Note how I use state not only in draw() but also in the build-in input functions

• keyReleased()
• keyPressed()
  
• mouseReleased ()

It's longwinded but you know where you stand and what to do everywhere in your program.

You don't have to understand the game stuff, I just wanted to give a silly example for a Game.
Put in your own game there.
I just wanted to show how to proceed to the state where he or she did win and
how to start all over again.

Hope this helps.

Greetings, Chrisir     

1. //
2. // the possible state of the program (constants)
3. final int getName       =0;
4. final int getYesNo      =1;
5. final int playStarting  =2;
6. final int playing       =3;
7. final int userWon       =4;
8. final int HeWontPlay    =5;
9. //
10. // the current state of the program (a variable)
11. int state = getName;
12. //
13. // a timer to control the step from state playStarting to state playing:
14. int timerPlayStarting=0;
15. // a timer to control the step from state userWon to state getYesNo (to play again):
16. int timerPlayWon=0;
17. //
18. PFont F = createFont("CenturyGothic", 16, true);
19. String firstname="";
20. String typing="";
21. int indent;
22. // char answer = 0;
23. //
24. // game stuff just to show an example
25. int boxsize = 50;
26. int cols, rows;
27. color [][] colorGrid ;
28. int x;
29. int y;
30. //
31. void setup()
32. {
33.   size (500, 500);
34.   indent = width/5;
35.   //
36.   // game stuff just to show an example
37.   setGameGrid();
38. }
39. //
40. void draw()
41. {
42.   background(255);  
43.   switch (state) {
44.   case getName:
45.     question1();
46.     break;
47.   case getYesNo:
48.     question2();
49.     break;
50.   case playStarting:
51.     text("Let's play!", indent, 40);
52.     // wait 3 seconds with a timer
53.     if (timerPlayStarting + 1000 < millis() ) {
54.       // after 3 sec, play
55.       state=playing;
56.     }
57.     break;
58.   case playing:
59.     drawGameGrid();
60.     // did user win?
61.     if (checkGameGridWon ()) {
62.       state = userWon;
63.       timerPlayWon = millis();
64.     }
65.     break; 
66.   case userWon:
67.     //
68.     drawGameGrid();
69.     fill(0);
70.     text("You won.", indent, 40);
71.     // wait
72.     if (timerPlayWon + 1000 < millis() ) {
73.       // after 3 sec, start over
74.       setGameGrid();
75.       state=getYesNo;
76.     }
77.     break;
78.   case HeWontPlay:
79.     text("You said no :(   ", indent, 40);
80.     break;
81.   } // switch
82.   //
83. }// func
84. //
85. void keyReleased()
86. {
87.   switch (state) {
88.   case getName:
89.     if (keyCode == BACKSPACE)
90.     {
91.       if (typing.length() > 0)
92.       {
93.         typing = typing.substring(0, typing.length()-1);
94.       }
95.     }
96.     else if (keyCode != SHIFT && keyCode != CONTROL && keyCode != ALT)
97.     {
98.       typing = typing + key;
99.     }
100.     break;
101.   } // switch
102. } // func
103. //
104. void keyPressed()
105. {
106.   switch (state) {
107.   case getName:
108.     switch(keyCode) {
109.     case ENTER:
110.       firstname = typing;
111.       state = getYesNo;
112.       break;
113.     } // inner switch
114.     break;
115.   case getYesNo:
116.     switch (key) {
117.     case 'y':
118.       //answer = key;
119.       state=playStarting;      
120.       timerPlayStarting = millis();
121.       break;
122.     case 'n':
123.       //answer = key;
124.       state=HeWontPlay;
125.       break;
126.     } // inner switch
127.   } // outer switch
128. } // func
129. //
130. void question1()
131. {
132.   background (255);
133.   textFont(F);
134.   fill(0);
135.   text("What is your first name:", indent, 40);
136.   text(typing, indent*2.78, 40);
137. }
138. //
139. void question2()
140. {
141.   background (255);
142.   textFont(F);
143.   fill(0);
144.   text("Do you want to play a game " +firstname+"? y/n", indent, 40);
145. }
146. //
147. // ------------------------------------------------------------
148. // from here on playing stuff (by adkins380, forum)
149. //
150. void setGameGrid() {
151.   // game stuff just to show an example
152.   cols = 3; // width/boxsize;
153.   rows = 3; // height/boxsize;
154.   colorGrid = new color [cols][rows] ;
155.   for (int i = 0; i < cols; i++) {
156.     for (int j = 0; j < rows; j++) {
157.       colorGrid [i][j] =  color ( 255 );
158.     } // for
159.   } // for
160. } // func
161. //
162. void drawGameGrid() {
163.   for (int i = 0; i < cols; i++) {
164.     for (int j = 0; j < rows; j++) {
165.       x = i*boxsize+140;
166.       y = j*boxsize+180;
167.       fill ( colorGrid [i][j] );   // fill(#1AC4FF); //   fill(255);
168.       stroke(0);
169.       rect(x, y, boxsize, boxsize);
170.     } // for
171.   } // for
172.   fill(0);
173.   text("Your goal: color all cells with the mouse.", indent, height-40);
174. } // func
175. //
176. boolean checkGameGridWon () {
177.   for (int i = 0; i < cols; i++) {
178.     for (int j = 0; j < rows; j++) {
179.       if ( colorGrid [i][j] == color (255) )
180.         return false;
181.     } // for
182.   } // for
183.   return true;
184. }
185. //
186. void mouseReleased () {
187.   // gets called automatically when Mouse is released.
188.   // then checks which cell is pressed and set random color.
189.   //
190.   // we want the mouse to work only during state playing :
191.   switch (state) {
192.   case playing:
193.     int x;
194.     int y;
195.     for (int i = 0; i < cols; i++) {
196.       x = i*boxsize+140;
197.       if  (mouseX >= x && mouseX < x + boxsize) {
198.         for (int j = 0; j < rows; j++) {
199.           y = j*boxsize+180;
200.           if (mouseY >= y && mouseY < y + boxsize) {
201.             colorGrid [i][j] =  color ( random(0, 255), random(0, 255), random(0, 255));
202.             return; // leave function immediately
203.           } // if
204.         } // for
205.       } // if
206.     } // for
207.     break;
208.   } // switch
209. } // func
210. //