Loading...
Logo
Processing Forum
Processing with Other Languages
curoiusbrain
curoiusbr..

Not running in browser or javascript mode, why ?

in Processing with Other Languages  •  17 days ago  
Hi,
This code is working well in java mode but when I tried uploading it on openprocessing.org it doesn't show any thing other than background color so I tried tested it in javascript mode and but still it is not working. 

help! I am missing anything ?


Copy code
  2. int rectsize=50, up, down, right, left;
  3. Rectpush[] rect;
  4. void setup()
  5. {
  6.   size(600, 300);
  7.   rect = new Rectpush[8];
  8.   for (int i=0;i<rect.length;i++) {
  9.     float x = random(0, width-50);
  10.     float y = random(0, height-50);
  11.     rect[i] = new Rectpush(x, y, rectsize, i );
  12.   }
  13. }
  14.  
  15. void draw()
  16. {
  17.   background(#00CAFF);
  18.     noStroke();
  19.   for (int i=0;i<rect.length;i++) {
  20.     if ( rect[i].x< mouseX && mouseX < rect[i].x+rectsize && rect[i].y< mouseY && mouseY < rect[i].y+rectsize) {
  21.       fill(#FFC800);
  22.       if (right==1) rect[i].x++;
  23.       if (left==1) rect[i].x--;
  24.       if (down==1) rect[i].y++;
  25.       if (up==1) rect[i].y--;
  26.     }
  27.     else {
  28.       fill(255);
  29.     }
  30.     rect[i].update();
  31.   }
  32. }
  33. void keyPressed() {
  34.   if (key == CODED) {
  35.     if (keyCode == UP) up=1;
  36.     if (keyCode == DOWN) down=1;
  37.     if (keyCode == LEFT) left=1;
  38.     if (keyCode == RIGHT)right=1;
  39.   }
  40. }
  41.  
  42. void keyReleased()
  43. {
  44.   up=0;
  45.   down=0;
  46.   right=0;
  47.   left=0;
  48. }
    49.  
class 

Copy code

  3.  
  4. class Rectpush {
  5.   float x, y;
  6.   int rectsize;
  7.   private int i;
  8.   Rectpush(float _x, float _y, int _rectsize, int _i)
  9.   {
  10.     x = _x;
  11.     y = _y;
  12.     i = _i;
  13.     rectsize = _rectsize;
  14.   }
  15.   void update()
  16.   {
  17.     rect(x, y, rectsize, rectsize);
  18.     fill(#FF0077);
  19.     textAlign(CENTER);
  20.     text( i ,x+25,y+30);
  21.   }
  22. }

Replies(3)

quarks
quarks

Re: Not running in browser or javascript mode, why ?

17 days ago
You cannot use the same name as a function. rect is a Processing function so you can't use this for your array. In the code below I have changes the name of the array to rects and it works fine in JS mode.



Copy code
  1. int rectsize=50, up, down, right, left;
  2. Rectpush[] rects;

  4. void setup()
  5. {
  6.   size(600, 300);
  7.   rects = new Rectpush[8];
  8.   for (int i=0;i<rects.length;i++) {
  9.     float x = random(0, width-50);
  10.     float y = random(0, height-50);
  11.     rects[i] = new Rectpush(x, y, rectsize, i );
  12.   }
  13. }

  15. void draw()
  16. {
  17.   background(#00CAFF);
  18.   noStroke();
  19.   for (int i=0;i<rects.length;i++) {
  20.     if ( rects[i].x< mouseX && mouseX < rects[i].x+rectsize && rects[i].y< mouseY && mouseY < rects[i].y+rectsize) {
  21.       fill(#FFC800);
  22.       if (right==1) rects[i].x++;
  23.       if (left==1) rects[i].x--;
  24.       if (down==1) rects[i].y++;
  25.       if (up==1) rects[i].y--;
  26.     }
  27.     else {
  28.       fill(255);
  29.     }
  30.     rects[i].update();
  31.   }
  32. }

  34. void keyPressed() {
  35.   if (key == CODED) {
  36.     if (keyCode == UP) up=1;
  37.     if (keyCode == DOWN) down=1;
  38.     if (keyCode == LEFT) left=1;
  39.     if (keyCode == RIGHT)right=1;
  40.   }
  41. }

  43. void keyReleased()
  44. {
  45.   up=0;
  46.   down=0;
  47.   right=0;
  48.   left=0;
  49. }

  51. class Rectpush {
  52.   float x, y;
  53.   int rectsize;
  54.   private int i;

  56.   Rectpush(float _x, float _y, int _rectsize, int _i)
  57.   {
  58.     x = _x;
  59.     y = _y;
  60.     i = _i;
  61.     rectsize = _rectsize;
  62.   }

  64.   void update()
  65.   {
  66.     rect(x, y, rectsize, rectsize);
  67.     fill(#FF0077);
  68.     textAlign(CENTER);
  69.     text( i, x+25, y+30);
  70.   }
  71. }

GoToLoop
GoToLoop

Re: Not running in browser or javascript mode, why ?

17 days ago
This 1 is an eternal classic: don't use same labels for both variables & methods if JS compatibility is desired!

You've declared a variable labeled rect . But rect is also the label for rect() method!
So, you've overshadowed Processing's own rect() ! 
Copy code
    // http://forum.processing.org/topic/not-running-in-browser-or-javascript-mode-why

final static int NUM = 8, DIM = 50;
final RectPush[] rects = new RectPush[NUM];

boolean up, down, right, left;

void setup() {
  size(600, 300);
  textAlign(CENTER);
  rectMode(CORNER);

  for (int i=0; i!=NUM; i++) {
    final int x = (int) random(width  - DIM);
    final int y = (int) random(height - DIM);
    rects[i] = new RectPush(x, y, DIM, i);
  }
}

void draw() {
  background(#00CAFF);
  noStroke();

  for (int i=0; i!=NUM; i++) {
    final RectPush r = rects[i];

    if (r.x < mouseX & mouseX < r.x + DIM & r.y < mouseY & mouseY < r.y + DIM) {
      fill(#FFC800);

      if (right)   ++rects[i].x;
      if (left)    --rects[i].x;
      if (down)    ++rects[i].y;
      if (up)      --rects[i].y;
    }

    else   fill(-1);

    rects[i].update();
  }
}

void keyPressed() {
  if (keyCode == UP)     up    = true;
  if (keyCode == DOWN)   down  = true;
  if (keyCode == LEFT)   left  = true;
  if (keyCode == RIGHT)  right = true;
}

void keyReleased() {
  up = down = right = left = false;
}

class RectPush {
  int x, y;
  int dim;
  int i;

  RectPush(int _x, int _y, int _dim, int _i) {
    x = _x;
    y = _y;
    i = _i;
    dim = _dim;
  }

  void update() {
    rect(x, y, dim, dim);
    fill(#FF0077);
    text(i, x+25, y+30);
  }
}
curoiusbrain
curoiusbr..

Re: Not running in browser or javascript mode, why ?

17 days ago
         

Stupid me .......... thanks a lot ! :)
Top Reply

Statistics

  • 3 Replies
  • 90  Views
  • 0 Followers

Actions

Related Posts