Noob trying to create gradients from an image

Programming Questions

archi.syn..

Noob trying to create gradients from an image

in Programming Questions • 2 years ago

Hi all,

I'm just getting going with Processing and want to create a gradient with the individual pixels of an image. I've got it to the point where it's sort of working. The result is close to a gradient but there are inconsistencies as you can see. I think I'm misunderstanding the color datatype or pixel[]. Any help would be great.

PImage images;

PImage img = createImage(400,300, RGB);

void setup() {

size(400, 300);

images = loadImage("DSCF1166.JPG");

images.loadPixels();

img.loadPixels();

noLoop();

}

void draw() {

color[] test = sort(images.pixels);

for(int i = 0; i <= 119999; i++) {

println(test[i]);

img.pixels[i] = test[i];

}

img.updatePixels();

image(img, 0,0);

}

Replies(4)

PhiLho

Re: Noob trying to create gradients from an image

2 years ago

RGB data isn't continuous... While being close numerically, #5500FF and #550100 represent a big jump in colorimetry. At best, you can sort by hue, for example, but you need a special sort.
Mmm, I did that in the past...
...
Found back:

PImage niceImage;
SortableColor[] colors;
PImage sortedImage;
boolean bSortOnHue;
void setup()
{
size(1000, 800);
noLoop();
niceImage = loadImage("G:/Images/backdrop.png");
image(niceImage, 0, 0);
}
void draw() {} // Enable events
void mousePressed()
{
bSortOnHue = mouseButton == RIGHT;
niceImage.loadPixels();
int colorNb = niceImage.pixels.length;
colors = new SortableColor[colorNb];
println("Making sortable color array");
for (int i = 0; i < colorNb; i++)
{
colors[i] = new SortableColor(niceImage.pixels[i]);
}
println("Sorting the array");
Arrays.sort(colors, new ColorComparator());
println("Done, making the sorted image");
sortedImage = niceImage.get(); // Clone as quick creation way
sortedImage.loadPixels();
for (int i = 0; i < colorNb; i++)
{
sortedImage.pixels[i] = colors[i].originalColor;
}
sortedImage.updatePixels();
image(sortedImage, width - sortedImage.width, height - sortedImage.height);
println("Done");
redraw();
}
class SortableColor
{
color originalColor;
float brightness;
float hue;
SortableColor(color c)
{
originalColor = c;
brightness = brightness(c);
hue = hue(c);
}
}
class ColorComparator implements Comparator<SortableColor>
{
int compare(SortableColor sc1, SortableColor sc2)
{
if (bSortOnHue)
return int(sc1.hue - sc2.hue);
return int(sc1.brightness - sc2.brightness);
}
}

m3rsault

Re: Re: Noob trying to create gradients from an image

7 months ago

Hi, I'm trying to run this script, and I ran into an issue where I needed to "import java.util.Arrays;". But now am getting the following error:

The method sort(T[], Comparator<? super T>) in the type Arrays is not applicable for the arguments (gradient.SortableColor[], gradient.ColorComparator)

Any thoughts on how to fix this would be really helpful. Thanks!

rapatski

Re: Noob trying to create gradients from an image

2 years ago

Oh on the subject of colorsorting, check out this wonderful set Cedric (or/and friends?) did: http://www.flickr.com/photos/onformative/sets/72157626506665897/with/5680665072/

PhiLho

Re: Noob trying to create gradients from an image

7 months ago

Since my code has no "gradient" in it, perhaps you can show your version, so we can understand where the problem is.

Top Reply