Non-linear connections between two points in 3D space

clausneer..

Non-linear connections between two points in 3D space

in Contributed Library Questions • 6 months ago

Hi,

I'm having a hard time figuring this one out - I've the sample code as seen below, in order to draw a connection between two points. Thing is, I want the connection not to be a single line, but a random number of lines. Also, I want each line to have a random number of kinks (vertices) between the start point and the end point. Then, each kink (not including the start point and the end point), should have a slight random offset from what would be a straight line, resulting in a kind of 'blurry' connection, when applied to a bunch of start points and end points.

Now, I got it to work with a straight up example, connecting the left side of a box with the right side. Next step, which is where I'm stuck, is to get it to work in a larger network of points.

How do I get the interpolations/kinks to offset perpendicular to the connection?

Any help is appreciated,

Thanks in advance,

/Claus

import peasy.*;
PeasyCam cam;
float maxOff = 25.0; // maximum offset (deviation from the straight line)
ArrayList connections;
void setup() {
size(1200, 600, P3D);
cam = new PeasyCam(this, 500);
//cam.setYawRotationMode(); // maybe comment this out?
cam.setMinimumDistance(-1000);
cam.setMaximumDistance(1000);
generate();
}
void draw() {
background(0);
for (int i = connections.size()-1; i >= 0; i--) {
Connect c = (Connect) connections.get(i);
c.render();
}
noFill();
strokeWeight(.5);
stroke(255);
box(1000);
}
void generate() {
connections = new ArrayList(); // create an empty ArrayList
int num = int(random(1, 10)); // get random value for number of connections
for (int i = 0; i < num; i++) {
PVector start = new PVector(-500, 0, 0); // start-vector in left side of box
PVector end = new PVector(500, 0, 0); // end-vector in right side of the box
connections.add(new Connect(start, end, maxOff));
}
}
void mousePressed() {
generate();
}
class Connect {
// do random number of connections between start PVector and end PVector
// for each connection, do random interpolation calculation (number of 'kinks' on each curve)
// offset each 'kink' sligthly from what would be a straight line between start and end
int num;
float offset;
color c = color(#FFD848);
PVector start, end;
ArrayList interpolation;
// constructor
Connect(PVector _start, PVector _end, float _maxOff) {
start = _start;
end = _end;
offset = _maxOff;
// random number off interpolations
num = int(random(1, 10));
interpolation = new ArrayList();
for (float i = 0; i < 1; i += (1.0 / num)) {
PVector l;
l = PVector.lerp(start, end, i);
// THIS IS NOT CORRECT, AS IT NEEDS A PERPENDICULAR OFFSET, NOT JUST A Y-Z OFFSET
l.y = random(-offset, offset);
l.z = random(-offset, offset);
interpolation.add(l);
}
}
void render() {
stroke(c, 150);
strokeWeight(0.5);
noFill();
beginShape();
vertex(end.x, end.y, end.z);
for (int i = interpolation.size()-1; i >= 1; i--) {
PVector p = (PVector) interpolation.get(i);
vertex(p.x, p.y, p.z);
}
vertex(start.x, start.y, start.z);
endShape();
}
}

Replies(3)

amnon.owed

Re: Non-linear connections between two points in 3D space

6 months ago

Moved to contributed library questions, because this code requires a specific version of the peasyCam contributed library and a recent Processing 2.0 beta to run. Programming questions is only for code that can be run without additional libraries.

This is the kind of math question that you can find answers to all over the internet, but is then (for non-math people like myself) always a challenge to solve practically in Processing. My two techniques are either (A) find processing/java/c++ code that already does this and use/port it or (B) use Processing's visual output to step-by-step work towards the solution.

clausneer..

Re: Non-linear connections between two points in 3D space

6 months ago

amnon.owed,

Thanks for your reply - I agree that it is a challenge to solve practically in Processing. No matter how much i work with vector math, I keep screwing it up.

I will keep searching. Still, if anybody should have any input or ideas, it would definitely be appreciated!

Thanks!

/Claus

quarks

Re: Non-linear connections between two points in 3D space

6 months ago

How do I get the interpolations/kinks to offset perpendicular to the connection?

This is easy in 2D because the perpendicular is a single vector (PVector). Unfortunately for a line in 3D, the perpendicular is really a plane, so there are an infinite number of vectors that are perpendicular.

The code below shows how to create a zigzag line between 2 points in 2D space. It is easy to extend into 3D change line 40 to
PVector.random3D(delta);

The function makeZZline effectively starts with a straight line and then splitting this in 2 repeating the process with the new lines formed. It return an PVector array of the correct size for the zig-zag line.

import java.util.*;
int maxKinkLength = 60;
PVector[] zigzag;
PVector start, end;
public void setup() {
size(400, 300);
frameRate(20);
}
public void draw() {
background(0);
start = new PVector(0, height/2);
end = new PVector(width, height/2);
zigzag = makeZZline(start, end, maxKinkLength);
stroke(255);
strokeWeight(6);
for (int i = 1; i < zigzag.length; i++)
line(zigzag[i-1].x, zigzag[i-1].y, zigzag[i].x, zigzag[i].y);
}
public PVector[] makeZZline(PVector start, PVector end, float mkl) {
LinkedList<PVector> list = new LinkedList<PVector>();
// Add copies of the start and end positions
list.add(start.get());
list.add(end.get());
// Start at beginning of the list
int p = 0;
PVector mid = new PVector(), delta = new PVector();
while (p < list.size ()-1) {
PVector s = list.get(p);
PVector e = list.get(p+1);
if (PVector.dist(s, e) > mkl) {
// Find mid point
mid.set(s);
mid.add(e);
mid.div(2);
// Get random displacement
PVector.random2D(delta);
delta.mult(mkl/2.2f); // must divide by number > 2
// Add to mid point
mid.add(delta);
// New point to list
list.add(p+1, mid.get());
}
else { // Move to next point
p++;
}
}
return list.toArray(new PVector[list.size()]);
}

Top Reply