Newton's Cradle Programming Help!

Programming Questions

gs_sikh

Newton's Cradle Programming Help!

in Programming Questions • 1 year ago

Hi, I started processing a little while ago and wanted to know if any one can help in learning how to move the Newton's Cradle program that I am trying to write.

What I have so far is just drawing. Basically I am trying to get the ball on the left to move up and hit the other balls and the right goes up, and a continuation.

void setup() {
size (800, 300);
smooth();
noStroke();
}

void draw() {
background(255);
fill(59,54,54);
rect(195, 0, 5, 150) ;
rect(320, 0, 5, 150);
rect(445, 0, 5, 150);
rect(570, 0, 5, 150);

fill(0);
ellipse(195, 210, 125, 125);
ellipse(320, 210, 125, 125);
ellipse(445, 210, 125, 125);
ellipse(570, 210, 125, 125);

}

Thank You!

Replies(8)

allonestr..

Re: Newton's Cradle Programming Help!

1 year ago

I think that there are two ways to approach this:

• animate the left end ball going up and coming down, then do the same with the right end ball

• do the physics properly where each ball acts under gravity and bounces correctly when it hit a neighbouring ball

The latter is much much harder but, if you get it right, much more realistic. It is harder because computer animation is frame-based, whereas real life happens continuously.

So, looking at the first way, you need to have the ball on its string describing a circular arc around its pivot (the top of the string). Any point on an arc has the (x, y) co-ordinates

(stringLength * cos(rotationAngle), stringLength * sin(rotationAngle))

In real life the rotationAngle doesn't change by the same amount from one frame to the next but, for your first go, don't worry about that.

jas0501

Re: Newton's Cradle Programming Help!

1 year ago

modeling the physics would be preferred as then if you moved 2 balls to start the momentum would be transferred to 2 on collision. 2 stopping and the other 2 moving. If 3 then 1 stopping and 3 still moving, 4 would just be 4 pendulums.

If you raised 1 at each end then they both would just bounce, if timed perfectly.

You might first just try modeling a single ball and

1. raising it and letting it swing

2. applying a force to it and seeing it swing.

Once you have that add some kind of decay due to friction to decrease the amplitude and you have your movement model.

Then you just need to transfer the momentum upon collision, with is part 2 above. Each ball can only transfer/receive momentum equal to its mass so some keep swinging, others start, and some stop.

Note if you raise ball 1 & 2 and hold ball 3 fixed, the momentum transfer to ball 4 is 2x so it would really fly, as no momentum is retained by 3.

see http://en.wikipedia.org/wiki/Pendulum for ideas on the math.

Chrisir

Re: Newton's Cradle Programming Help!

1 year ago

My Code goes back to allonestrings first idea - that's hard enough...

/*
Newton cradle
The left and right arm are moving.
The middle arms are static.
The left and the right arm are both using the
same angle "rotationAngle" (degree=0..360!).
The left and the right arm are represented by the points
posVector1 (left arm) and posVector2 (right arm) which are
the center of the moving balls.
Depending on variable "phase" (program state) only the left or only the right arm
is changed (posVector1 or posVector2 in draw | switch) whereas the angle "rotationAngle" is always
changed. So both arms are always drawn but one is only changed when "phase" says so.
The variable "phase" is very important and goes from 0 to 3 and back to 0.
The variable "phase" determines which arm is moving where. It is evaluated
in draw() through the switch block. When the limit is reached the next phase is
started and the direction of the movement changed (by var rotationAngleAdd).
*/
//
final int base = 235; // left arms circles center)
final int myDistance = 125; // between arms
//
PVector posVector1 = new PVector(); // Left arm
PVector posVector2 = new PVector(); // right arm
//
int stringLength=210;
//
float rotationAngle = 90;
float rotationAngleAdd = 1.7; // positiv: go left
//
int phase = 0;
//
void setup() {
size (900, 300);
smooth();
fill(255, 2, 2);
stroke(255, 2, 2);
strokeWeight(10);
//noStroke();
posVector1.set (stringLength * cos(radians(rotationAngle)),
stringLength * sin(radians(rotationAngle)),
0);
posVector2.set (stringLength * cos(radians(rotationAngle)),
stringLength * sin(radians(rotationAngle)),
0);
}
//
void draw() {
background(255);
// testing:
println(phase);
//
// angle for both arms
rotationAngle += rotationAngleAdd;
// now eval switch
switch (phase) {
case 0:
// left side going left
posVector1.set (stringLength * cos(radians(rotationAngle)),
stringLength * sin(radians(rotationAngle)),
0);
if (rotationAngle>130) {
rotationAngleAdd = -abs(rotationAngleAdd); // negativ: going right
phase=1;
}
break;
case 1:
// left side going right
posVector1.set (stringLength * cos(radians(rotationAngle)),
stringLength * sin(radians(rotationAngle)),
0);
if (rotationAngle<=90) {
rotationAngleAdd = -abs(rotationAngleAdd); // positiv: go left
phase=2;
}
break;
case 2:
// right side going right
posVector2.set (stringLength * cos(radians(rotationAngle)),
stringLength * sin(radians(rotationAngle)),
0);
if (rotationAngle<=40) {
rotationAngleAdd = abs(rotationAngleAdd); // neg
phase=3;
}
break;
case 3:
// right side going left
posVector2.set (stringLength * cos(radians(rotationAngle)),
stringLength * sin(radians(rotationAngle)),
0);
if (rotationAngle>=90) {
rotationAngleAdd = abs(rotationAngleAdd); // positiv
phase=0; // and back to start
}
break;
default:
// error
println ("Oups - Code shouldn't be here...");
break;
} // switch
//
// draw static arms
line(base+myDistance, 0, base+myDistance, 150 );
line(base+2*myDistance, 0, base+2*myDistance, 150);
ellipse(base+myDistance, 210, myDistance, myDistance);
ellipse(base+2*myDistance, 210, myDistance, myDistance);
//
// draw moving arms
// moving arm left
line (base, 0,
base+posVector1.x, posVector1.y );
ellipse( base+posVector1.x, posVector1.y, myDistance, myDistance);
//
// moving arm right
line (base+3*myDistance, 0,
base+3*+myDistance+posVector2.x, posVector2.y );
ellipse( base+3*myDistance+posVector2.x, posVector2.y, myDistance, myDistance);
//
}

gs_sikh

Re: Newton's Cradle Programming Help!

1 year ago

Thank You to all those who helped!

allonestr..

Re: Newton's Cradle Programming Help!

1 year ago

It's a while since I've done a diagram.

Here's one of why I think that the physics route isn't right when gs_sikh declared him/herself new to Processing.

As I said, real life happens continuously, but computer life happens incrementally. This means that when the balls meet, they don't bounce elastically as they do in a real Newton's cradle, but overlap. In fact, in animation we test for collision by tesing for overlap.

In my diagram collision happens between frames 2 and 3. So if I do the collision reaction in frame_3 then it's too late.

I think that the only way to get the physics route to work is to (cheat and) use differentiation to find out what time the bob reaches the same angle as its neighbour, and work out the collision from there even if it happens between frames.

I should declare that I speak from bitter experience. Here are my (pre-Processing) Flash attempts:

http://allonestring.co.uk/run/flash/cradle01.htm

http://allonestring.co.uk/run/flash/cradle02.htm

http://allonestring.co.uk/run/flash/cradle03.htm

Chrisir

Re: Newton's Cradle Programming Help!

1 year ago

Hello,

Sure, for a beginner the way I did it, is probably much easier than real physics would be.

@allonestring: Hello, I am not sure about your approach.

When you look at
http://www.processing.org/learning/topics/circlecollision.html
for instance, you'll see it's not based on overlaping but on
calculation of the centers of the two circles:

// get distances between the balls components
PVector bVect = new PVector();
bVect.x = b[1].x - b[0].x;
bVect.y = b[1].y - b[0].y;
// calculate magnitude of the vector separating the balls
float bVectMag = sqrt(bVect.x * bVect.x + bVect.y * bVect.y);
if (bVectMag < b[0].r + b[1].r){
// get angle of bVect

They don't overlap, they just bounce at an exact moment.

Well, I don't understand half of what's going on in the Code but it looks very impressive.
Ira Greenberg even takes into account the mass of the balls and the speed.

Greetings, Chrisir

allonestr..

Re: Newton's Cradle Programming Help!

1 year ago

Lines 6 and 7 in your example say

find the distance between the two centres

if that distance is less than the sum of the radii

{ do collision stuff }

that is, if the balls are overlapping, do collision stuff.

Chrisir

Re: Newton's Cradle Programming Help!

1 year ago

oups, you're right

but we could put <=
there instead.

And we could check it before drawing?

But you're more experienced, I looked at your site... Wow...

Top Reply