Hi to all
To learn processing I've coded a SkyboxViewer. And - what should I say - I really like processing!
And I was suprised - only about 100 lines of code are enough to create an acceptable SkyboxViewer.
If you know about another SkyboxViewer coded with processing, please let me know it!

Hope you like it...   ;-) Gerd

1. /**
2.  * SkyboxViewer v1.0   2010-08-02   by Ing. Gerd Platl.
3.  *                     tested with processing 1.2.1
4.  *
5.  * Demonstrates use of u/v coords in vertex() and effect on texture().
6.  * The textures get distorted using the P3D renderer, but they look great using OPENGL.
7.  *
8.  * Please read a detailed description about how skyboxes works at Friedrich A.Lohmuellers page
9.  *   http://www.f-lohmueller.de/pov_tut/backgrnd/p_sky9.htm
10.  *
11.  * How to view skyboxes:
12.  * - download a skybox examples (6 texture images) e.g. from
13.  *     http://www.f-lohmueller.de/pov_tut/skyboxer/skyboxer_3.htm
14.  * - create a SkyboxViewer/data subdirectory for this project
15.  * - copy texture images to the SkyboxViewer/data subdirectory
16.  * - set the skybox name in this project:  see 'skyboxName = "<filename>";'  
17.  * - start this SkyboxViewer and look around...
18.  *
19.  *   mouse input:
20.  *      left mouse button   rotate skybox
21.  *     right mouse button   zoom skybox
22.  *
23.  *   key input:         r   reset
24.  *             left/right   auto scroll to left/right
25.  *                up/down   scroll up/down
26.  *                  blanc   stop scrolling
27.  *                  + / -   zoom in/out
28.  *                    esc   quit            
29.  */
30. import processing.opengl.*;
31. float rotx = 0.0;   // rotation about x-axis
32. float roty = 0.0;   // rotation about y-axis
33. float rotd = 0.0;   // rotation delta x
34. float maxd = 0.01;  // maximum rotation delta x
35. float fov  = 1.8;   // vertical field-of-view angle (in radians)
36. // set skybox filename without orientation part here...
37. String skyboxName = "Orientation";  
38. //String skyboxName = "Skybox_Water222";  
39.      
40. void setup()
41. {
42.   size(800, 600, OPENGL);
43. //  size(screenWidth, screenHeight, OPENGL);  // fullscreen
44.   frameRate(60);
45.   loadSkybox(skyboxName, ".jpg");
46. }
47. void draw()
48. {
49.   background(0);
50.   noStroke();  // comment it to see cube edges
51.   if (fov < 0.1) fov = 0.1;
52.   if (fov > 3.0) fov = 3.0;
53.   perspective(fov, float(width)/height, 1, 100000);
54.   translate(width/2.0, height/2.0, -100);
55.   if (rotd > maxd) rotd = maxd;
56.   else if (rotd < -maxd) rotd = -maxd;
57.   roty += rotd;
58.   rotateX(rotx);
59.   rotateY(roty);
60.   TexturedCube();
61. }
62. float p = 40000;   // half skybox size
63. float m = -p;
64. // create cube edges
65. PVector P000 = new PVector (m,m,m);
66. PVector P010 = new PVector (m,p,m);
67. PVector P110 = new PVector (p,p,m);
68. PVector P100 = new PVector (p,m,m);
69. PVector P001 = new PVector (m,m,p);
70. PVector P011 = new PVector (m,p,p);
71. PVector P111 = new PVector (p,p,p);
72. PVector P101 = new PVector (p,m,p);
73. PImage tex1,tex2,tex3,tex4,tex5,tex6;   // texture images
74. // load six skybox images as cube texture
75. void loadSkybox(String skyboxName, String fExt)
76. {
77.   tex1 = loadImage(skyboxName + "_front" + fExt);
78.   tex2 = loadImage(skyboxName + "_back" + fExt);
79.   tex3 = loadImage(skyboxName + "_left" + fExt);
80.   tex4 = loadImage(skyboxName + "_right" + fExt);
81.   tex5 = loadImage(skyboxName + "_base" + fExt);
82.   tex6 = loadImage(skyboxName + "_top" + fExt);
83.   textureMode(NORMALIZED);
84. }
85. // Assign six texture to the six cube faces
86. void TexturedCube()
87. {
88.   TexturedCubeSide (P100, P000, P010, P110, tex1);   // -Z "front" face
89.   TexturedCubeSide (P001, P101, P111, P011, tex2);   // +Z "back" face
90.   TexturedCubeSide (P000, P001, P011, P010, tex3);   // -X "left" face
91.   TexturedCubeSide (P101, P100, P110, P111, tex4);   // +X "right" face
92.   TexturedCubeSide (P110, P010, P011, P111, tex5);   // +Y "base" face
93.   TexturedCubeSide (P101, P001, P000, P100, tex6);   // -Y "top" face
94. }
95. // create a cube side given by 4 edge vertices and a texture
96. void TexturedCubeSide(PVector P1, PVector P2, PVector P3, PVector P4, PImage tex)
97. {
98.   beginShape(QUADS);
99.     texture(tex);
100.     vertex (P1.x, P1.y, P1.z, 1, 0);
101.     vertex (P2.x, P2.y, P2.z, 0, 0);
102.     vertex (P3.x, P3.y, P3.z, 0, 1);
103.     vertex (P4.x, P4.y, P4.z, 1, 1);
104.   endShape();
105. }
106. // handle mouse input
107. void mouseDragged()
108. {
109.   if (mouseButton == LEFT)
110.   { rotx += (pmouseY-mouseY) * 0.01;     // LEFT
111.     roty += (mouseX-pmouseX) * 0.01;
112.   }
113.   else fov -= (pmouseY-mouseY) * 0.005;  // RIGHT
114. }
115. // handle key input
116. void keyPressed()
117. {
118.   println (keyCode);
119.   if      (keyCode ==    82) { rotx = 0.0;   roty = 0.0;   rotd = 0.0; }   // r: Reset
120.   else if (keyCode ==  LEFT) rotd += -0.001; // auto scroll to left
121.   else if (keyCode == RIGHT) rotd += 0.001;  // auto scroll to right
122.   else if (keyCode ==    32) rotd = 0.0;     // space: stop scrolling
123.   else if (keyCode ==    UP) rotx += 0.01;   // scroll up
124.   else if (keyCode ==  DOWN) rotx -= 0.01;   // scroll down
125.   else if (keyCode ==   107) fov /= 1.01;    // +  zoom in
126.   else if (keyCode ==   109) fov *= 1.01;    // -  zoom out
127.   else if (keyCode ==    76) loadSkybox("another_Landscape", ".png");  // L: load
128. }

image orientation of cubic mapping: