Networking between android and server on Wifi (ConnectBot type of thing)

Android Processing

wi11turner

Networking between android and server on Wifi (ConnectBot type of thing)

in Android Processing • 10 months ago

Greetings all.

I am struggling to successfully network my android devise with a server I have on the same Wifi network.

Any guidance would be much appreciated.

I want to view some sensor values on my android devise.

I have a server writing a message on a given IP and Port. (This happens to be a arduino wifi project, simply I am broadcasting two sensor values)

I want to view these sensor values on my android devise. (I can do this using my pc/java processing, telnet, etc, but not with android processing)

I am aware of oscP5 libraries and such but, for my simple little set up all I require to do is to display the message I am broadcasting on my android devise as it sits as a client. Just seeing the message on the screen would be great! For example I have used ConnectBot and I can see them this way. I'd rather make my own program so I can develop it further.

Please suggest any areas I should research! (Networking with Java... I gathered:) )

Many thanks guys.

EDIT: Yes i am a newbie, but i can make android applications minus networking stuff.

Replies(6)

berengerr

Re: Networking between android and server on Wifi (ConnectBot type of thing)

10 months ago

I have setup something like this for a future project a few days ago. Well not exactly as I wanted to work the other way around. My goal was to send accelerometer data from my phone to my computer it's a very basic example where I send just the y value and use it to rotate a rectangle.

for further details you can check this post on which I heavily based the code I use : https://forum.processing.org/topic/oscp5-for-processing-android#25080000001066218

desktop sketch :

import oscP5.*;
import netP5.*;
OscP5 oscP5;
NetAddress myRemoteLocation;
float ex, wy, ze;
void setup() {
size(400,400);
frameRate(25);
/* start oscP5, listening for incoming messages on port 12000 */
oscP5 = new OscP5(this,12000);
// send to phone address
myRemoteLocation = new NetAddress("192.168.1.11",12001);
background(0);
rectMode(CENTER);
}
void draw() {
background(0);
fill(255);
wy = map(wy,-10,10,0,TWO_PI);
translate(width/2,height/2);
rotate(wy);
rect(0,0,200,20);
}
void mousePressed() {
OscMessage myMessage = new OscMessage("/test");
myMessage.add(123);
oscP5.send(myMessage, myRemoteLocation);
println("standard sketch, sending to "+myRemoteLocation);
}
/* incoming osc message are forwarded to the oscEvent method. */
void oscEvent(OscMessage theOscMessage) {
/* print the address pattern and the typetag of the received OscMessage */
print("### received an osc message.");
print(" addrpattern: "+theOscMessage.addrPattern());
println(" typetag: "+theOscMessage.typetag());
//background(random(255));
if (theOscMessage.checkAddrPattern("/wy")==true) {
wy = theOscMessage.get(0).floatValue();
//println(" med : "+ med);
return;
}
}

and the android sketch :

/* osc send-receive, android sketch */
import oscP5.*;
import netP5.*;
OscP5 oscP5;
NetAddress myRemoteLocation;
void setup() {
/* start listening on port 12001, incoming messages must be sent to port 12001 */
oscP5 = new OscP5(this,12001);
// send to computer address
myRemoteLocation = new NetAddress("192.168.1.13",12000);
}
float x;
void draw() {
background(0);
fill(255);
rect(x,0,100,100);
}
void mousePressed() {
/* send a message to your remote location on mouse (touch) click */
OscMessage myMessage = new OscMessage("/test");
myMessage.add(123);
oscP5.send(myMessage, myRemoteLocation);
println("android sketch, sending to "+myRemoteLocation);
}
/* incoming osc message are forwarded to the oscEvent method. */
void oscEvent(OscMessage theOscMessage) {
x = random(255);
}

you need to have the AccelerometerManager.java file linked to your android sketch. It is available under file-> examples -> Sensor -> accelerometer for this to work. You also need to enable 'internet' permissions

I guess it could help you to get started let me know if you have questions. I

Have fun

wi11turner

Re: Networking between android and server on Wifi (ConnectBot type of thing)

10 months ago

Thanks berrengerr,

I have tried osp5 protocols but my server code does not construct a osp5 message. (It is a arduino wifi sheild)

Do you have any idea how to read server data without the need for a osp5 message?

Or use the osp5 library to read a stream of data from a given ip and port?

Thanks

berengerr

Re: Networking between android and server on Wifi (ConnectBot type of thing)

10 months ago

I'm not a arduino guy, I didn't know you couldn't build OSC messages from arduino, sorry I can't help.

wi11turner

Re: Networking between android and server on Wifi (ConnectBot type of thing)

9 months ago

I think the OSC message can be written in ardiuno,

I'm aware OSC messages are Java based and the arduino languague is C++.

Could anyone else please shed some light on my basic network question?

(Using android processing to read some non-OSP5 wifi server data)

Thanks,

andreas.s..

Re: Networking between android and server on Wifi (ConnectBot type of thing)

9 months ago

Hi, OSC itself is a protocol ( http://opensoundcontrol.org/introduction-osc) used to send control messages across networks to allow applications and devices to talk to each other. The raw material of this protocol is a stream of bytes and is therefore language independent and can be implemented by any programming language, there is even an Arduino library github.com/recotana/ArdOSC which should allow you to send OSC back and forth from your device to Arduino. The beauty of OSC is that it packages data in a simple format so that it can be written and read easily. It is network-protocol independent and can be send/received over TCP, UDP, Multicast, etc..

If you only want to read a stream of bytes you dont necessarily need OSC but could only use a basic client/server setup. First you need to know which network protocol you are using TCP or UDP? processing's examples come with TCP client/server sketches which you could use to get started. oscP5 comes with a network library, netP5, which is included in the oscP5 package - you can use netP5 for TCP or UDP communication, find 2 examples below:

/* using TCP with netP5 example */
import netP5.*;
TcpClient tcpc;
TcpServer tcps;
void setup() {
/* lets create a TCP server and a TCP client,
* both will be talking to each other.
* First we create a listener for the server and the client.
* A listener will receive NetMessages which contain our data.
* NetListener is an interface and requires to implement netEvent
* and netStatus.
*/
NetListener nl1 = new NetListener() {
public void netEvent(NetMessage m) {
println("netEvent (tcps) : "+ new String( m.getData() ) );
}
public void netStatus(NetStatus s) {
println("netStatus (tcps) : "+s);
}
};
NetListener nl2 = new NetListener() {
public void netEvent(NetMessage m) {
println("netEvent (tcpc) : "+ new String( m.getData() ) );
}
public void netStatus(NetStatus s) {
println("netStatus (tcpc) : "+s);
}
};
/* now lets create the server first. The server will listen for
* clients at port 4000. since we expect bytes from the client, the 3rd
* argument (TcpServer.MODE_STREAM) is a static variable setting
* the mode of the server to bytes (default is String);
*/
tcps = new TcpServer( nl1, 4000, TcpServer.MODE_STREAM );
/* after the server is running, create a client which will connect
* to the newly create server at 127.0.0.1:4000 (127.0.0.1 is locahost).
* we also need to set the mode to stream since we want to receive and
* send bytes.
*/
tcpc = new TcpClient( nl2, "127.0.0.1", 4000, TcpServer.MODE_STREAM );
}
void draw() {
}
void keyPressed() {
/* use key 1 and 2 to send data from the server to the client and vice versa. */
switch(key) {
case( '1' ) :
println("sending from tcpc to tcps");
tcpc.send( "Hello World from TCP Client to TCP Server.".getBytes() );
break;
case( '2' ) :
println("sending from tcps to tcpc");
tcps.send( "Hello World from TCP Server to TCP Client.".getBytes() );
break;
}
}

/* using UDP with netP5 example */
import netP5.*;
UdpClient udpc;
UdpServer udps;
void setup() {
/* lets create a UDP server and a UDP client, as opposed to the TCP
* example here only the server will be able to listen for uncoming messages,
* for that we create a listener for the server.
* A listener will receive NetMessages which contain our data.
* NetListener is an interface and requires to implement netEvent
* and netStatus.
*/
NetListener nl1 = new NetListener() {
public void netEvent(NetMessage m) {
println("netEvent (udps) : "+ new String( m.getData() ) );
}
public void netStatus(NetStatus s) {
println("netStatus (udps) : "+s);
}
};
/* since by default UDP does not provide a handshake mechanism to establish a
* connection, our client will not be able to receive messages. With UDP only the
* Server will listen for and receive incoming UDP messages.
* TCP on the other side uses handshake to establish a connection which
* will then be dedicated and stable until the server or the client terminates.
* With UDP there is no stable/continuous connection, the server takes what it gets
* no matter who sent it.
* more info about TCP and UDP over at wikipedia
* UDP http://en.wikipedia.org/wiki/User_Datagram_Protocol
* TCP http://en.wikipedia.org/wiki/Transmission_Control_Protocol
*/
/* our UDP server will listen at port 12000, the client will send messages to
* 127.0.0.1:12000 (127.0.0.1 is localhost).
*/
udps = new UdpServer( nl1 , 12000 );
udpc = new UdpClient( "127.0.0.1" , 12000 );
}
void draw() {
}
void keyPressed() {
/* use key 1 to send data from the client to the server. */
switch(key) {
case( '1' ) :
println("sending from udpc to udps");
udpc.send( "Hello World from UDP Client to UDP Server.".getBytes() );
break;
}
}

metalpuzz..

Re: Networking between android and server on Wifi (ConnectBot type of thing)

7 months ago

Hi, I have also a arduino wifi sheild.

I want to send "1" (by wifi with my android phone) and write "HIGH" in a led (arduino).

¿Do you know how can I do that?

Thanks!