Need urgently help - sinus fluctuations

Programming Questions

judithstr..

Need urgently help - sinus fluctuations

in Programming Questions • 10 months ago

Hi everybody,

i'm working on my bachelorthesis, in which i'm working with lissajous-figures an I'm a beginner in programming.

Here my problem:

Some strange things seem to happen to my figures when i run the sketch: the frequency ratio changes suddenly.

I want to draw different kinds of frequency ratios, but the have to be constant until i want to change them.

Can somebody help me?

Here is the code:

float x = 0;

float y = 0;

float a = 8;

float b = 2;

float ar = 0;

void setup() {

size(500,400);

background(0);

frameRate(25);

smooth();

}

void draw(){

background(0);

translate(250, 200);

noFill();

stroke(50);

for(int i=0;i<2000;i=i+1){

x = x + sin(a)*1;

y = y + sin(b)*1;

stroke(255);

strokeWeight(1);

point(x,y);

a=a+0.01;

b=b+0.025;

}

Thank you!

Judith

Replies(3)

benja

Re: Need urgently help - sinus fluctuations

10 months ago

i think changing 'a' and 'b' over time will affect the shape of the figures. To have "rotaing" figures you might want to change delta over time instead. Here is an example, maybe that helps:

float x, y;
float ampA =200;
float ampB =100;
float a = 0.25;
float b = 0.5;
float delta = 0;

void setup() {
size(500, 400);
background(0);
frameRate(25);
smooth();
stroke(255);
strokeWeight(1);
}

void draw() {
background(0);
translate(250, 200);

// increase delta
delta = delta+0.05;

for (float t = 0 ; t<100 ; t = t + 0.05) {
    // calculate x and y
    x = ampA * sin((a*t)+delta);
    y = ampB * sin(b*t);

    point(x, y);
}
}

PhiLho

Re: Need urgently help - sinus fluctuations

10 months ago

Reset the variables on each draw() call to get a stable result:

float x;
float y;
float a;
float b;
float ai = 0.01;
float bi = 0.025;
void setup() {
size(500, 400);
background(0);
frameRate(25);
smooth();
}
void draw() {
background(0);
translate(250, 200);
noFill();
stroke(50);
stroke(255);
strokeWeight(1);
x = y = 0;
a = 8;
b = 2;
for (int i = 0; i < 2000; i++) {
x += sin(a);
y += sin(b);
point(x, y);
a += ai;
b += bi;
}
}
// Change the increments; adjust the factors as wished
void keyPressed()
{
if (key == 'a')
{
ai *= 1.1;
}
else if (key == 'A')
{
ai /= 1.1;
}
else if (key == 'b')
{
bi *= 1.1;
}
else if (key == 'B')
{
bi /= 1.1;
}
}

judithstr..

Re: Re: Need urgently help - sinus fluctuations

10 months ago

Thank you guys!

I have to study this new input and I will report in the next days. Probably, I have new questions for you ;-)

Top Reply