Need to use data stored on an array only once using random choice of index! Arraylist?

Programming Questions

brtdesign

Need to use data stored on an array only once using random choice of index! Arraylist?

in Programming Questions • 2 years ago

Hey guys.

I'm trying to make something that is chosing random colors from an array of colors but once it chooses one it will remove it from the array to not be chosen again.

From what I know there is no simple way of removing indexes from arrays but with arraylists is possible. The problem I'm having is that I don't know how to get the data out of the arraylist properly do be used as colors.

Where I have cor = mycolours[int(rand1)]; I'd like to have something like cor = colors.get(int(rand1)); but I get this error " Cannot convert Object to int"

can someone tell me how to access it?

color[] mycolours = { #F9EC31, #37B34A, #1B75BB, #652D90, #EB008B, #BE1E2D};
PShape a, b, c, d, e, f, g, r_emote, drawing;
color cor, cor2, cor3, cor4, cor5, cor6;
float rand1;
float rand2;
float rand3;
float rand4;
float rand5;
float rand6;
ArrayList colors;
void setup(){
size(400,600);
smooth();
noStroke();
drawing = loadShape("r-emote.svg");
a = drawing.getChild("a");
b = drawing.getChild("b");
c = drawing.getChild("c");
d = drawing.getChild("d");
e = drawing.getChild("e");
f = drawing.getChild("f");
r_emote = drawing.getChild("r");
drawing.disableStyle();
shapeMode(CENTER);
background(255);
colors = new ArrayList();
colors.add(mycolours[0]);
colors.add(mycolours[1]);
colors.add(mycolours[2]);
colors.add(mycolours[3]);
colors.add(mycolours[4]);
colors.add(mycolours[5]);
// println(colors.get(3));

}

void draw(){

rand1 = random(6)-1;
// float wdf = (float)colors.get((int)rand1);
// println(colors.getKey(
// cor = colors.getKey([int(rand1)]);
cor = mycolours[int(rand1)];
fill(cor);
shape(a, width/2,height/2);


rand2 = random(5)-1;

cor2 = mycolours[int(rand2)];

fill(cor2);
shape(b, width/2,height/2);

    rand3 = random(6)-1;

cor3 = mycolours[int(rand3)];

fill(cor3);
shape(c, width/2,height/2);

    rand4 = random(6)-1;

cor4 = mycolours[int(rand4)];

fill(cor4);
shape(d, width/2,height/2);
rand5 = random(6)-1;
cor5 = mycolours[int(rand5)];
fill(cor5);
shape(e, width/2,height/2);
cor6 = mycolours[int(rand6)];
fill(cor6);
shape(f, width/2,height/2);
fill(0);
shape(r_emote, width/2,height/2);
// cor = mycolours[int(random(mycolours.length))];

//print(int(rand1));
//print("\t");
//print(int(rand2));
//print("\t");
//print(int(rand3));
//print("\t");
//print(int(rand4));
//print("\t");
//print(int(rand5));
//print("\t");
//print(int(rand6));
//print("\t");
noLoop();
}

Replies(3)

PhiLho

Re: Need to use data stored on an array only once using random choice of index! Arraylist?

2 years ago

General advice: use array for the shapes, and a loop to fill the array list. Or, better, you can do:
Integer[] mycolours = { #F9EC31, #37B34A, #1B75BB, #652D90, #EB008B, #BE1E2D };
ArrayList<Integer> colors = new ArrayList<Integer>();
Collections.addAll(colors, mycolours);
println(colors);
color col = (Integer) colors.get(3);

As you can see, color type is actually an int, which is stored as an Integer (a wrapper object) in the array list. The cast to Integer is then automatically unboxed to int (ie. color) in the last line.

Note that you don't need to remove items from the list to get random items without repeating: you can use Collections.shuffle(colors) to make the order to be random. Then just get the items in increasing order.

davbol

Re: Need to use data stored on an array only once using random choice of index! Arraylist?

2 years ago

allow me to suggest another approach. (one that i use quite frequently for all sorts of purposes)

you'll leave the original data array (in your case colors) as is. instead, create a seperate array of indices into your data, and shuffle that. so when you need a color, you'll access it via double indirection like this: colors[indices[i]] if you ever need to access the colors in their original order, you can still use single indirection: colors[i]

the advantages are that sometimes it's important to leave your source data alone, and it's really simple to create the array of shuffled indices (google for fisher-yates), plus it avoids all the wrapping and type conversion of the Collections class. here's an example, click mouse to shuffle:

color[] colors = { #F9EC31, #37B34A, #1B75BB, #652D90, #EB008B, #BE1E2D};
int n = colors.length;
int [] indices = new int[n];
void setup() {
size(600,100);
reindex();
}
void reindex() {
indices[0] = 0;
for (int i=1; i<n; i++) {
    int j = (int)(random(i+1));
    indices[i] = indices[j];
    indices[j] = i;
}
}
void draw() {
for (int i=0; i<n; i++) {
fill(colors[indices[i]]);
rect(i*100,0,100,100);
}
}
void mousePressed() {
reindex();
}

brtdesign

Re: Need to use data stored on an array only once using random choice of index! Arraylist?

2 years ago

thank you all both! I've managed to make it work with both!

Top Reply