[Need help] How to build GUI?

Contributed Library Questions

luckm4n

[Need help] How to build GUI?

in Contributed Library Questions • 1 years ago

How to build GUI with this script?

import processing.opengl.*;
import java.text.*;
import lsystem.*;

import peasy.*;
PeasyCam cam;
Grammar grammar;

float distance =50;
int depth = 4;
float alph = radians(15); //rotateX
float beta = radians(15); //rotateY
float delta = radians(15); //rotateZ
String production = "";

void setup() {
size(900, 700, OPENGL);
configureOpenGL();
configureCamera();
setupGrammar();
noStroke();
}

void configureCamera(){
cam = new PeasyCam(this, 100);
cam.setMinimumDistance(100);
cam.setMaximumDistance(500);
}

void configureOpenGL(){
hint(ENABLE_OPENGL_4X_SMOOTH);
hint(DISABLE_OPENGL_ERROR_REPORT);
}

void setupGrammar(){
int generations = 5;
String axiom = "F";
grammar = new StochasticGrammar(this, axiom);
grammar.addRule('F', "GH[\\+F]F__[-_F]__[-_F]__[\\F]");
grammar.addRule('F', "GH_[\\+F]F[-_F]_[-_F]_[//F]");
grammar.addRule('F', "GH__[\\+F]_F[-_F][-_F][\\F]");
grammar.addRule('G', "GH");
production = grammar.createGrammar(generations);
distance *= pow(0.5, generations);
}

void draw() {
background(#ffffff);
lights();
render();
}

void render() {
translate(0, -50, 0); // center the plant empirically set looks OK to me
lightSpecular(0, 175, 0);
specular(0, 255, 0);
shininess(1.0);
CharacterIterator it = new StringCharacterIterator(production);
for (char ch = it.first(); ch != CharacterIterator.DONE; ch = it.next()) {
    switch (ch) {
    case 'F':
      translate(0, distance/2, 0);
      box(distance/9, distance, distance/9);
      translate(0, distance/2, 0);
      fill(0, 175, 0);
      break;
    case 'G':
      translate(0, distance/2, 0);
      box(distance/9, distance, distance/9);
      translate(0, distance/2, 0);
      break;
    case 'H':
      translate(0, distance/2, 0);
      box(distance/9, distance, distance/9);
      translate(0, distance/2, 0);
      break;
    case '+':
      rotateX(alph);
      break;
    case '-':
      rotateX(-alph);
      break;
    case '_':
      rotateY(beta);
      break;
    case '^':
      rotateY(-beta);
      break;
    case '\\':
      rotateZ(delta);
      break;
    case '/':
      rotateZ(-delta);
      break;
    case '[':
      pushMatrix();
      break;
    case ']':
      popMatrix();
      break;
    default:
      System.err.println("character " + ch + " not in grammar");
    }
}
}

Replies(1)

jbum

Re: [Need help] How to build GUI?

1 years ago

I've built l-system programs with interfaces before. The most common thing to do is make a way to control the

level of recursion, which controls the amount of detail in the tree. You can also control branch angle, trunk thickness, randomness, and so on.

In this program, recursion is controlled by the variable "generations". A simple fix that uses the mouse to change this is shown here. I replaced the setupGrammar with this version, which fixes a problem with distance, and adds a global variable to keep track of the current value.

int lastGenerations = 5I r;
void setupGrammar(){
int generations = lastGenerations;
String axiom = "F";
grammar = new StochasticGrammar(this, axiom);
grammar.addRule('F', "GH[\\+F]F__[-_F]__[-_F]__[\\F]");
grammar.addRule('F', "GH_[\\+F]F[-_F]_[-_F]_[//F]");
grammar.addRule('F', "GH__[\\+F]_F[-_F][-_F][\\F]");
grammar.addRule('G', "GH");
production = grammar.createGrammar(generations);
distance = 50*pow(0.5, generations);
}

Then at the top of the draw function, I added this code.

int generations = (int) map(mouseY,height,0,2,7);

if (generations != lastGenerations) {

lastGenerations = generations;

setupGrammar();

}

This could be modified to use a slider, but the mechanics are still essentially the same.

Everytime I've worked with L-Systems in the past, I've encountered the same two problems:

1) When generations is at a high level, the program grinds to a halt and becomes unresponsive while it is generating the detailed tree. This happens very quickly. The only way to deal with it, while remaining responsive to the user, is to modify the program to use Threads, which adds considerable complexity.

2) This program was carefully designed to work with a generations set to 5. Some of the variables (such as camera placement) assume it. Because of these design flaws, the tree doesn't look good except at 5. Fixing it so that the tree doesn't grow out of the frame requires a good understanding of the scaling properties of the particular L-system you are working with.

Top Reply