Mysterious Color Problem

Programming Questions

masurr

in Programming Questions • 1 year ago

Hi.

I'm new to Processing so I don't really know much about it :D That's the reason I came here.

I have a mysterious problem and I can't solve it on my own.

I had to draw a grid. Done.

Second thing is to change color from left to right. Sounds easy, doesn't it?

I don't get why the horizontal lines aren't colored. What did I do wrong?

float r = 255;
void setup() {
size (500, 500);
}
void draw() {
noLoop();
colorMode(HSB);
for (int i = 0; i <= width; i += 10) {
for (int j = 0; j <= height; j += 10) {
r -= 0.1;
stroke(r, 255, 255);
line (i, 0, i, height); //This is colored by "stroke()"
line (0, j, width, j); //This isn't
}
}
}

Replies(8)

calsign

I agree... this behavior is quite strange. The problem is probably something obvious that I, too, am missing. What makes it even stranger is that reversing the order of the for loops changes which lines are drawn with the right color and which ones are not. This suggests that the lines whose counters are changed by the inner for loop are not drawn. (Do I have that backwards?)

cedrickie..

Re: Mysterious Color Problem

1 year ago

Calsign, i was confused for a sec as well and didn't get it. but its actually obvious...

I would probably do the coloring different in the first place but in your special case the problem is something else.

Think about it, you dont need a nested loop like you would do when drawing a grid of dots.

all you need is one single loop with the horizontal and vertical lines. the problem with your horizontal lines is that you draw them much more often than just once. the first you draw is red, then green, blue etc... but after all you draw some red lines over them again, thats why they appear red.

float r = 255;
void setup() {
size (500, 500);
}
void draw() {
noLoop();
colorMode(HSB);
for (int i = 0; i <= width; i += 10) {
r -= 10;
println(r);
stroke(r, 255, 255);
line (i, 0, i, height); //This is colored by "stroke()"
line (0, i, width, i); //This isn't
}
}

masurr

Re: Mysterious Color Problem

1 year ago

I don't really get why the horizontal lines are drawn multiple times but I get what you said.

I thought the nested loop would be good if someone changed the "size()".

In that case I'll just edit "i <= width" and I get the same results :)

Thank you for answering that fast and please forgive me if I wrote anything wrong, English isn't my first language.

cedrickie..

Re: Mysterious Color Problem

1 year ago

also the vertical ones are drawn several times, but all in the same color.

that was a quick one, but if i am right, this is how it would look like if you could see it during the drawing process.

guess it explains it quite well...

void setup() {
size (500, 500);
frameRate(100);
}
int count = 0;
int count2 = 0;
void draw() {
float r = 255;
colorMode(HSB);background(100);
for (int i = 0; i <= count; i += 10) {
for (int j = 0; j <= count2; j += 10) {
r -= 0.1;
stroke(r, 255, 255);
line (i, 0, i, height); //This is colored by "stroke()"
line (0, j, width, j); //This isn't
}
}
count+=10;
if (count>=width && count2<height) {
count2+=10;
count = 0;
}
}

masurr

Re: Mysterious Color Problem

1 year ago

I think I got it. Again, thanks for your help.

PhiLho

Re: Mysterious Color Problem

1 year ago

Cedric is right.
You could have written your initial code with two separate loops instead of one, allowing to have different width and height:

void setup() {
size(500, 500);
}
int STEP = 10;
void draw() {
noLoop();
colorMode(HSB);
float r = 255;
for (int i = 0; i <= width; i += STEP) {
r -= 255.0 / (width / STEP);
stroke(r, 255, 255);
line(i, 0, i, height);
}
r = 255;
for (int j = 0; j <= height; j += STEP) {
r -= 255.0 / (height / STEP);
stroke(r, 255, 255);
line(0, j, width, j);
}
}

Try with eg. size(800, 500).

masurr

Re: Mysterious Color Problem

1 year ago

Thats amazing. I tried to do something similar to your "STEP" but I didn't get it right.

Thank you for making me understand Processing better. :)

PhiLho

Re: Mysterious Color Problem

1 year ago

I made a STEP constant because thus, you can change it in one place, and it is updated everywhere it is needed. Of course, you can make STEP_X and STEP_Y instead, for example.
Adding constants to parametrize sketches is often a good idea, as long as these constants are used in at least two places.

Top Reply