My initial way of approaching this would be to use an off screen image that will act as a "map". Make it a scaled down version of the image and make it black and white, not gray scale but black and white only. In that image create black/or white spots (depending on what your background color is) where you want there to be collision points. and when you move your character in the game check against the offscreen image.

Use a paint program to create a second image that is exactly the same size as the background image you want to use.

Now using a paint program change the copy by painting any area that is a building or other no-go area black (RGB 0,0,0) and any area where the pokemon can go white (RGB 255,255,255). The final image should have just 2 colours, black and white.

Assuming that you saved this image as mask.png then you can do something like this

1. int black, white;
2. PImage mask;

and in setup

1. black = color(0, 0, 0);
2. white = color(255, 255, 255);
3. mask = loadImage("mask.png");

and in your sketch you can check whether any position [x, y] with

1. if(mask.get(x,y) == black){
2. // collision
3. }
4. 
   
5. if(mask.get(x,y) == white){
6. // no collision
7. }

You can extend this idea to more than 2 colours to represent different types of hazard.

nice! very interesting thank you

I tried a small programm

it uses kobbys and quarks idea of an image and
the same size image in black and white.

the first image you see,
the second is in the background and
serves for the collisions.

a red ball is used to demonstrate the
collisions as reflections.

Later instead of the ball use your mighty game character. 

1. // see https://forum.processing.org/topic/my-first-game
2. PImage backgroundImage ;  // what you see
3. PImage backgroundImageForPGraphics ;  // for collisions
4. // see http://processing.org/learning/topics/circlecollision.html
5. Ball ball;
6. PGraphics pg;
7. final color colorBlack= color (0.0, 0.0, 0.0);
8. void setup () {
9.   size(700, 700);
10.   backgroundImage = loadImage ("Pokemon_RBY_PalletTown.png");
11.   backgroundImageForPGraphics = loadImage ("Pokemon_RBY_PalletTownForPGraphics.jpg"); 
12.   println("Loading - check");
13.   //
14.   pg = createGraphics(700, 700, P3D);
15.   //
16.   pg.beginDraw();
17.   pg.background(255);
18.   //pg.stroke(255);
19.   pg.image(backgroundImageForPGraphics, 300, 300);
20.   //pg.line(40, 40, mouseX, mouseY);
21.   pg.endDraw();
22.   ball = new Ball ( 320, 490, 4 );
23. }
24. void draw () {
25.   background (0);
26.   if (!keyPressed) {
27.     image(backgroundImage, 300, 300);
28.   }
29.   else
30.   {
31.     image(pg, 0, 0);
32.   }
33.   ball.draw();
34.   ball.move();
35.   ball.checkBoundaryCollision();
36.   ball.checkObjectCollision();
37. }
38. // =============================================================
39. class Ball {
40.   float x, y, r, m;
41.   PVector vel = new PVector(2.15, -1.35);
42.   // default constructor
43.   /*
44.   Ball() {
45.    }
46.    */
47.   Ball(float x, float y, float r) {
48.     this.x = x;
49.     this.y = y;
50.     this.r = r;
51.     m = r*.1;
52.   }
53.   void move() {
54.     x += vel.x;
55.     y += vel.y;
56.   }
57.   void checkBoundaryCollision () {
58.     //
59.     // that's for the screen, not for the image!
60.     //
61.     if (ball.x > width-ball.r) {
62.       ball.x = width-ball.r;
63.       vel.x *= -1;
64.     }
65.     else if (ball.x < ball.r) {
66.       ball.x = ball.r;
67.       vel.x *= -1;
68.     }
69.     else if (ball.y > height-ball.r) {
70.       ball.y = height-ball.r;
71.       vel.y *= -1;
72.     }
73.     else if (ball.y < ball.r) {
74.       ball.y = ball.r;
75.       vel.y *= -1;
76.     }
77.   }  // method
78.   void checkObjectCollision ( ) {
79.     // that's for the screen / your image
80.     color testColor;
81.     // test left / right
82.     testColor=pg.get(int(x+ ( vel.x)), int(y));
83.     println (testColor);
84.     if (testColor==colorBlack) {
85.       vel.x*=-1;
86.     }
87.     // test up / down
88.     testColor=pg.get(int(x), int(y+ (vel.y)));
89.     println (testColor + ": "  + red (testColor) + ", " +
90.       green(testColor)  + ", " +  blue (testColor) );
91.     if (testColor==colorBlack) {
92.       vel.y*=-1;
93.     }
94.   } // method
95.   void draw () {
96.     fill(255, 2, 2);
97.     ellipse(x, y, r*2, r*2);
98.   } // method
99. } // class
100. // -----------------------