Multiple text files

Programming Questions

ksunger

in Programming Questions • 2 years ago

Right now I'm having trouble getting my program to read the multiple text files I have in my data folder. My counter is working for the images, but not the text files. This is what I have so far, and when my mouse hovers over the first picture, the name is displayed below, but when the mouse hovers over the other pictures, I get an error saying "ArrayIndexOutOfBoundsException: 1". The names of my pictures and the corresponding text files are the same names (0.jpg, 0.txt)

PImage[] images = new PImage[8];
String[] names = new String[8];

void setup() {
size(900, 700);
for (int i=0; i <images.length; i++) {
    images[i] = loadImage(i + ".jpg");
}
for (int i=0; i < names.length; i++) {
    names = loadStrings(i + ".txt");
}
}

void draw() {
background(0);

float w = float(width) / images.length;

for (int i=0; i < images.length; i++) {
    float x = i*w;
    float y = 0;
    imageMode(CORNER);
    image( images[i], x, y, w, w);

    // check for rollover
    if (mouseX > x && mouseX <= x+w && mouseY > y && mouseY <=y+w) {
      noFill();
      stroke(255);
      rect(x, y, w-1, w);
      imageMode(CENTER);
      image(images[i], width/2, 400);
      text(names[i], x+40, y+150);
      }
    }

}

Replies(4)

blindfish

Re: Multiple text files

2 years ago

The problem is that you don't reference the index when you try to store each separate text file in the names array:

names = loadStrings(i + ".txt");

should be

names[i] = loadStrings(i + ".txt");

However, if the text files only contain individual names or short phrases it doesn't seem worth splitting these into separate text files: loadStrings() automatically splits separate lines from a single text file into an array* so you really only need a single text file with the names on separate lines, assuming you can tie them to their associated image with a numerical index.

* you may find that will be your next problem: because loadStrings returns an array and you're storing each file in an array you're creating a 2d array. Still assuming your text files only contain a single line, and as long as you know that they at least have a single line, you should be able to get away with referencing the first item in the loadStrings array:

text(names[i][0], x+40, y+150);

ksunger

Re: Re: Multiple text files

2 years ago

I had tried doing names[i] and it would give me an error saying "Cannot convert from String[] to String" but the program actually ran when I took out the index. I going to try putting everything into a single .txt file and see how that goes.

blindfish

Re: Multiple text files

2 years ago

Sorry it was late when I answered last night - I should have been more thorough! This issue comes back to the fact that loadStrings returns an array, so you're essentially creating a 2d array which means you also need to declare it as such:

String[][] names = new String[8][];

Then you should find that the following works:

for (int i=0; i <images.length; i++) {
images[i] = loadImage(i + ".jpg");
// since you know they're both the same length there's no need for a separate loop here
names[i] = loadStrings(i + ".txt");
}

However, as I said, creating a separate file for each entry is pretty inefficient. For simple data you can use single entries on new lines (or even multiple comma separated values on each line) and for more complex data you might opt for something like XML.

ksunger

Re: Re: Multiple text files

2 years ago

Thank you so much! It's working now :D

Top Reply