Multiple GLModel render

gmassol

in Contributed Library Questions • 1 year ago

Hey there,

I have a little questions about GLModel rendering with GLGraphics library (I'm using Processing 1.5.1).

I have 3 GLModels, one with a bunch of cubes, one with lines and a last one is a point cloud. They all have their own colors and alpha. If I render them all together without lighting, everything seems to be just fine, but once I enable one light, then it seems like only one of the model is lighted correctly and the colors and alpha values of the other 2 ones are completely ignored.

The code looks something like that:

// GLGraphic rendering
GLGraphics renderer = (GLGraphics)g;
renderer.beginGL();

    background(0);

    // Render Lights
    float lightX = map(mouseX, 0, width, 640, 0);
    float lightY = map(mouseY, 0, height, 0, 480);
    float lightZ = 800;

    if (lightType == 0) {
      renderer.ambientLight(255, 255, 255, lightX, lightY, lightZ);
    } else if (lightType == 1) {
      float dirX = lightX;
      float dirY = lightY;
      float dirZ = 0 + lightZ;
      float n = sqrt(dirX * dirX + dirY * dirY + dirZ * dirZ);
      dirX /= n;
      dirY /= n;
      dirZ /= n;
      renderer.directionalLight(255, 255, 255, -dirX, -dirY, dirZ);
    } else if (lightType == 2) {
      renderer.pointLight(51, 102, 126, lightX, lightY, lightZ);
    } else if (lightType == 3) {
      float dirX = lightX;
      float dirY = lightY;
      float dirZ = 0 + lightZ;
      float n = sqrt(dirX * dirX + dirY * dirY + dirZ * dirZ);
      dirX /= n;
      dirY /= n;
      dirZ /= n;
      renderer.spotLight(255, 255, 255, lightX, lightY, lightZ, dirX, dirY, dirZ, 2*PI, 40);
    }

    // Render Models
    cubes.render();
    pointCloud.render();
    linesModel.render();

renderer.endGL();

I've checked that article http://www.sjbaker.org/steve/omniv/opengl_lighting.html about openGL color and I understand the overall logic, but I can't seem to figure out what's the pb here... Do I need to assign one light per model? Any help on that would be great.

Thanks!

Replies(12)

andres

Re: Multiple GLModel render

1 year ago

which model is correctly lit? Do all your models have the normal vectors properly defined?

gmassol

Re: Multiple GLModel render

1 year ago

Thanks for the reply. I actually try to display 4 models, a group of spheres, some cubes, lines and points. Only the lines and points do not have the normal defined properly. But even when I want to display the spheres and cubes (for which the normals are properly defined) it doesn't display correctly, it seems like the light only have effect on one of them and the other one is shown in plain color, even with the ambient light the colors are not shown correctly... For example if I display only the cubes then it's all good, then I display the spheres together with it and only the spheres are shown correctly (the cubes turn all white), it's quite strange...

Well, maybe I'll try to make a simple sketch to test and share it here, the code of the current sketch is a über mess, anything else it could be except the normals?

Thanks a lot!

andres

Re: Multiple GLModel render

1 year ago

It is difficult to say without looking at the code, but my impression is the problem might be due to a bug in your sketch.

If you take the GLDirectional example from the Models category in GLGraphics, and modify it slightly so it uses two different GLModel objects, the lights appear to be calculated correctly:

import processing.opengl.*;
import codeanticode.glgraphics.*;
GLModel sphere1, sphere2;
void setup() {
size(640, 360, GLConstants.GLGRAPHICS);
sphere1 = createSphere(40, 60);
sphere1.setTint(204);
sphere2 = createSphere(40, 20);
sphere2.setTint(204);
}
void draw() {
GLGraphics renderer = (GLGraphics)g;
renderer.beginGL();
noStroke();
background(0);
float dirY = (mouseY / float(height) - 0.5) * 2;
float dirX = (mouseX / float(width) - 0.5) * 2;
directionalLight(204, 204, 204, dirX, dirY, 1);
translate(width/2, height/2, 0);
renderer.model(sphere1);
rotateY(frameCount * 0.01);
translate(150, 0, 0);
renderer.model(sphere2);
renderer.endGL();
}

If you can reproduce your problem with a simpler sketch, please post it in this thread.

gmassol

Re: Multiple GLModel render

1 year ago

Thanks for the reply and advice Andres, I agree that the pb is most likely coming from a bug in my code :-P

I'm trying to reproduce all this on a 'simpler' sketch now and will post it here when I'm done.

bjlotus

Re: Multiple GLModel render

1 year ago

Hello there, I'm going through something similar here: I'm creating 5 spheres, actually an icosahedron which is subdivided. Each of them has a detail level, min. is 0, which displays a regular icosahedron, and max. is 4, which looks like a sphere.

Inside its creation function, the vertices are coloured to some red colour, but when I render them applying lights, the first one looks red, and ther rest takes the colour specified in the light, which I set to white. If I turn the lights off, all of display in plain red as it should.

Relevant code here:

this is the model that returns the createSphere() function:

//MODELO GLGRAPHICS
GLModel model = new GLModel(this, glvert.size(), TRIANGLES, GLModel.STREAM);
// Sets the coordinates.
model.updateVertices(glvert);
// Sets the normals.
model.initNormals();
model.updateNormals(glnorm);
// Sets indices
int[] indexArr = new int[faceIndx.size()];
for( int i=0; i<faceIndx.size(); i++){
int v1 = (int) faceIndx.get(i);
indexArr[i] = v1;
}
model.initIndices(faceIndx.size());
model.updateIndices(indexArr);
// Sets color
float[] colors = new float[glnorm.size()*4];
for( int i=0; i<glnorm.size()*4; i+=4){
colors[i] = 1; //R
colors[i+1] = 0.2; //G
colors[i+2] = 0.2; //B
colors[i+3] = 1; //Alpha
}
model.initColors();
model.updateColors(colors);
//RETURN DEL MODELO
return model;

Here I create the models stored in an array, using i also to set the sphere detail (0 to 4). This code is in setup():

int radI = 50; //radio inicial
for (int i=0; i<spheres.length; i++){
spheres[i] = createSphere(i, radI);
}

Then, in draw(), I set a directional light (taken from one of the examples) and render:

//ICOSPHERES --------------------------------
GLGraphics renderer = (GLGraphics)g;
renderer.beginGL();
//LUCES
lightX = mouseX;
lightY = mouseY;
lightZ = 100;
float dirX = width/2 - lightX;
float dirY = height/2 - lightY;
float dirZ = 0 - lightZ;
float n = sqrt(dirX * dirX + dirY * dirY + dirZ * dirZ);
dirX /= n;
dirY /= n;
dirZ /= n;
directionalLight(255, 255, 255, -dirX, -dirY, -dirZ);
//DISPLAY
int xpos = 100;
for ( GLModel m : spheres ){
pushMatrix();
translate(xpos, height/2, 0);
m.render();
popMatrix();
xpos+=150;
}
renderer.endGL();

The result is this:

Any idea what's going on here? Have you gmassol got your sketch to work propperly?

Thanks in advance, cheers!

Jon

bjlotus

Re: Multiple GLModel render

1 year ago

I've also tested this directly on the GLDirectional example, adding:

// Sets color
float[] colors = new float[normals.size()*4];
for( int i=0; i<normals.size()*4; i+=4){
colors[i] = 1; //R
colors[i+1] = 0.2; //G
colors[i+2] = 0.2; //B
colors[i+3] = 1; //Alpha
}
model.initColors();
model.updateColors(colors);

Right before the "return: model;" line in the createSphere function.

As a result, the sphere in the center displays red, and the one rotating displays white. If both are being created by the same function, shouldn't be the same? What am I missing?

cheers!

gmassol

Re: Multiple GLModel render

11 months ago

Hey,

No I didn't manage to make it work, maybe it was my normals that were wrong or something, I gave up. I have a similar problem than yours now though where I'm creating few distinct models and the light setting seems to be applied correctly only on the first model, no idea why. Let me know if you make some progress ;-)

G.

bjlotus

Re: Multiple GLModel render

11 months ago

hey there,

At the moment, after testing some time with direct calls to opengl lights and stuff, I kinda "solved" this situation... but it's just a workaround that suits what I'm trying to do.

Apparently, when you set lights on GLGraphics, those are set on the opengl LIGHT0... So instead of setting the vertices colour, or using the model.setTint(), I'm calling lights/materials directly. First I set some lights with glgraphics, and if I want to add another, just enable LIGHT1, LIGHT2 and so on.

It'd be great to have some feedback from Andres, since I started using opengl and glgraphics just about a week ago and I feel a complete newbie talking about this :)

cheers!

***EDIT***

After several tests, even if a try to set lights directly on opengl, things get a little messed up, and I get the same behaviour: only the first rendered model gets the correct light settings.

I've tried to re-write my sketch without GLGraphics, by using VBO's directly, and the lights settings seem to work ok. I'd like to keep using GLGraphics thou, since it saves from writing a lot of code and has lots of great functionalities. :S

andres

Re: Multiple GLModel render

11 months ago

I can confirm this is a bug in GLGraphics. I won't be releasing a new version of the library at this time, fortunately there is a simple workaround for this issue. Set the light again for each model, following the model drawing call by noLights(), i.e.:

void draw() {
//ICOSPHERES --------------------------------
GLGraphics renderer = (GLGraphics)g;
renderer.beginGL();
//DISPLAY
int xpos = 100;
for (GLModel m : spheres ) {
//LUCES
float lightX = mouseX;
float lightY = mouseY;
float lightZ = 100;
float dirX = width/2 - lightX;
float dirY = height/2 - lightY;
float dirZ = 0 - lightZ;
float n = sqrt(dirX * dirX + dirY * dirY + dirZ * dirZ);
dirX /= n;
dirY /= n;
dirZ /= n;
directionalLight(255, 255, 255, -dirX, -dirY, -dirZ);
pushMatrix();
translate(xpos, height/2, 0);
m.render();
popMatrix();
xpos+=150;
noLights();
}
renderer.endGL();
}

I hope this helps!

bjlotus

Re: Multiple GLModel render

11 months ago

Hi Andres,

THANKS for replying. I'll give it a try!

Since I was stucked with this, I started learning/testing VBOs and textures... therefore: MORE PROBLEMS... even started a topic about that.

As soon as i get this working, i'll come back to lights and test your solution.

Thanks!

bjlotus

Re: Multiple GLModel render

11 months ago

I've tested your solution and works as expected when using the predefined lights. It's not working when using directly opengl... or there're parameters that are set automatically for each model that messes up the scene.

i.e. using the lights described here in your site:

//ICOSPHERES --------------------------------
GLGraphics renderer = (GLGraphics)g;
renderer.beginGL();
//DISPLAY
int xpos = 100;
GL gl = renderer.gl;
for ( GLModel m : spheres ){
//LUCES
//gl.glShadeModel(gl.GL_FLAT);
gl.glEnable(GL.GL_LIGHTING);
gl.glDisable(GL.GL_COLOR_MATERIAL);
gl.glEnable(GL.GL_LIGHT0);
gl.glMaterialfv(GL.GL_FRONT_AND_BACK, GL.GL_AMBIENT, new float[]{0.1,0.1,0.1,1}, 0);
gl.glMaterialfv(GL.GL_FRONT_AND_BACK, GL.GL_DIFFUSE, new float[]{1,0,0,1}, 0);
gl.glLightfv(GL.GL_LIGHT0, GL.GL_POSITION, new float[] {-1000, 600, 2000, 0 }, 0);
gl.glLightfv(GL.GL_LIGHT0, GL.GL_SPECULAR, new float[] { 1, 1, 1, 1 }, 0);
pushMatrix();
translate(xpos, height/2, 0);
gl.glEnable(gl.GL_NORMALIZE);
scale(50);
m.render();
popMatrix();
noLights();
xpos+=150;
}
renderer.endGL();

I got all white spheres. If I set some reflectionon the models, it gets closer to the desired scene, but not exactly. I'm guessing there are parameters being set within the model?

It'd be great, if there's a way, to bypass those lights settings.

Thanks a lot for your time Andrés. Regards,

andres

Re: Multiple GLModel render

11 months ago

By disabling GL_COLOR_MATERIAL you are overriding the diffuse and ambient properties of the models with your own material settings. However, there are two problems: you are using the same GL_DIFFUSE color for all the models, and then the GL_SPECULAR component is dominating the other color components.

Top Reply