2. // I2C device class (I2Cdev) demonstration Processing sketch for MPU6050 DMP output
3. // 6/20/2012 by Jeff Rowberg <jeff@rowberg.net>
4. // Updates should (hopefully) always be available at https://github.com/jrowberg/i2cdevlib
5. //
6. // Changelog:
7. //     2012-06-20 - initial release
8. 
   
9. /* ============================================
10. I2Cdev device library code is placed under the MIT license
11. Copyright (c) 2012 Jeff Rowberg
12. 
    
13. Permission is hereby granted, free of charge, to any person obtaining a copy
14. of this software and associated documentation files (the "Software"), to deal
15. in the Software without restriction, including without limitation the rights
16. to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
17. copies of the Software, and to permit persons to whom the Software is
18. furnished to do so, subject to the following conditions:
19. 
    
20. The above copyright notice and this permission notice shall be included in
21. all copies or substantial portions of the Software.
22. 
    
23. THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
24. IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
25. FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
26. AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
27. LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
28. OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
29. THE SOFTWARE.
30. ===============================================
31. */
32. 
    
33. import processing.serial.*;
34. import processing.opengl.*;
35. import toxi.geom.*;
36. import toxi.processing.*;
37. 
    
38. // NOTE: requires ToxicLibs to be installed in order to run properly.
39. // 1. Download from http://toxiclibs.org/downloads
40. // 2. Extract into [userdir]/Processing/libraries
41. //    (location may be different on Mac/Linux)
42. // 3. Run and bask in awesomeness
43. 
    
44. ToxiclibsSupport gfx;
45. 
    
46. Serial port;                         // The serial port
47. char[] teapotPacket = new char[14];  // InvenSense Teapot packet
48. int serialCount = 0;                 // current packet byte position
49. int aligned = 0;
50. int interval = 0;
51. 
    
52. float[] q = new float[4];
53. Quaternion quat = new Quaternion(1, 0, 0, 0);
54. 
    
55. float[] gravity = new float[3];
56. float[] euler = new float[3];
57. float[] ypr = new float[3];
58. 
    
59. void setup() {
60.     // 300px square viewport using OpenGL rendering
61.     size(300, 300, OPENGL);
62.     gfx = new ToxiclibsSupport(this);
63. 
    
64.     // setup lights and antialiasing
65.     lights();
66.     smooth();
67.   
68.     // display serial port list for debugging/clarity
69.     println(Serial.list());
70. 
    
71.     // get the first available port (use EITHER this OR the specific port code below)
72.     String portName = Serial.list()[0];
73.     
74.     // get a specific serial port (use EITHER this OR the first-available code above)
75.     //String portName = "COM4";
76.     
77.     // open the serial port
78.     port = new Serial(this, portName, 115200);
79.     
80.     // send single character to trigger DMP init/start
81.     // (expected by MPU6050_DMP6 example Arduino sketch)
82.     port.write('r');
83. }
84. 
    
85. void draw() {
86.     if (millis() - interval > 1000) {
87.         // resend single character to trigger DMP init/start
88.         // in case the MPU is halted/reset while applet is running
89.         port.write('r');
90.         interval = millis();
91.     }
92.     
93.     // black background
94.     background(0);
95.     
96.     // translate everything to the middle of the viewport
97.     pushMatrix();
98.     translate(width / 2, height / 2);
99. 
    
100.     // 3-step rotation from yaw/pitch/roll angles (gimbal lock!)
101.     // ...and other weirdness I haven't figured out yet
102.     //rotateY(-ypr[0]);
103.     //rotateZ(-ypr[1]);
104.     //rotateX(-ypr[2]);
105. 
     
106.     // toxiclibs direct angle/axis rotation from quaternion (NO gimbal lock!)
107.     // (axis order [1, 3, 2] and inversion [-1, +1, +1] is a consequence of
108.     // different coordinate system orientation assumptions between Processing
109.     // and InvenSense DMP)
110.     float[] axis = quat.toAxisAngle();
111.     rotate(axis[0], -axis[1], axis[3], axis[2]);
112. 
     
113.     // draw main body in red
114.     fill(255, 0, 0, 200);
115.     box(10, 10, 200);
116.     
117.     // draw front-facing tip in blue
118.     fill(0, 0, 255, 200);
119.     pushMatrix();
120.     translate(0, 0, -120);
121.     rotateX(PI/2);
122.     drawCylinder(0, 20, 20, 8);
123.     popMatrix();
124.     
125.     // draw wings and tail fin in green
126.     fill(0, 255, 0, 200);
127.     beginShape(TRIANGLES);
128.     vertex(-100,  2, 30); vertex(0,  2, -80); vertex(100,  2, 30);  // wing top layer
129.     vertex(-100, -2, 30); vertex(0, -2, -80); vertex(100, -2, 30);  // wing bottom layer
130.     vertex(-2, 0, 98); vertex(-2, -30, 98); vertex(-2, 0, 70);  // tail left layer
131.     vertex( 2, 0, 98); vertex( 2, -30, 98); vertex( 2, 0, 70);  // tail right layer
132.     endShape();
133.     beginShape(QUADS);
134.     vertex(-100, 2, 30); vertex(-100, -2, 30); vertex(  0, -2, -80); vertex(  0, 2, -80);
135.     vertex( 100, 2, 30); vertex( 100, -2, 30); vertex(  0, -2, -80); vertex(  0, 2, -80);
136.     vertex(-100, 2, 30); vertex(-100, -2, 30); vertex(100, -2,  30); vertex(100, 2,  30);
137.     vertex(-2,   0, 98); vertex(2,   0, 98); vertex(2, -30, 98); vertex(-2, -30, 98);
138.     vertex(-2,   0, 98); vertex(2,   0, 98); vertex(2,   0, 70); vertex(-2,   0, 70);
139.     vertex(-2, -30, 98); vertex(2, -30, 98); vertex(2,   0, 70); vertex(-2,   0, 70);
140.     endShape();
141.     
142.     popMatrix();
143. }
144. 
     
145. void serialEvent(Serial port) {
146.     interval = millis();
147.     while (port.available() > 0) {
148.         int ch = port.read();
149.         print((char)ch);
150.         if (aligned < 4) {
151.             // make sure we are properly aligned on a 14-byte packet
152.             if (serialCount == 0) {
153.                 if (ch == '$') aligned++; else aligned = 0;
154.             } else if (serialCount == 1) {
155.                 if (ch == 2) aligned++; else aligned = 0;
156.             } else if (serialCount == 12) {
157.                 if (ch == '\r') aligned++; else aligned = 0;
158.             } else if (serialCount == 13) {
159.                 if (ch == '\n') aligned++; else aligned = 0;
160.             }
161.             //println(ch + " " + aligned + " " + serialCount);
162.             serialCount++;
163.             if (serialCount == 14) serialCount = 0;
164.         } else {
165.             if (serialCount > 0 || ch == '$') {
166.                 teapotPacket[serialCount++] = (char)ch;
167.                 if (serialCount == 14) {
168.                     serialCount = 0; // restart packet byte position
169.                     
170.                     // get quaternion from data packet
171.                     q[0] = ((teapotPacket[2] << 8) | teapotPacket[3]) / 16384.0f;
172.                     q[1] = ((teapotPacket[4] << 8) | teapotPacket[5]) / 16384.0f;
173.                     q[2] = ((teapotPacket[6] << 8) | teapotPacket[7]) / 16384.0f;
174.                     q[3] = ((teapotPacket[8] << 8) | teapotPacket[9]) / 16384.0f;
175.                     for (int i = 0; i < 4; i++) if (q[i] >= 2) q[i] = -4 + q[i];
176.                     
177.                     // set our toxilibs quaternion to new data
178.                     quat.set(q[0], q[1], q[2], q[3]);
179. 
     
180.                     /*
181.                     // below calculations unnecessary for orientation only using toxilibs
182.                     
183.                     // calculate gravity vector
184.                     gravity[0] = 2 * (q[1]*q[3] - q[0]*q[2]);
185.                     gravity[1] = 2 * (q[0]*q[1] + q[2]*q[3]);
186.                     gravity[2] = q[0]*q[0] - q[1]*q[1] - q[2]*q[2] + q[3]*q[3];
187.         
188.                     // calculate Euler angles
189.                     euler[0] = atan2(2*q[1]*q[2] - 2*q[0]*q[3], 2*q[0]*q[0] + 2*q[1]*q[1] - 1);
190.                     euler[1] = -asin(2*q[1]*q[3] + 2*q[0]*q[2]);
191.                     euler[2] = atan2(2*q[2]*q[3] - 2*q[0]*q[1], 2*q[0]*q[0] + 2*q[3]*q[3] - 1);
192.         
193.                     // calculate yaw/pitch/roll angles
194.                     ypr[0] = atan2(2*q[1]*q[2] - 2*q[0]*q[3], 2*q[0]*q[0] + 2*q[1]*q[1] - 1);
195.                     ypr[1] = atan(gravity[0] / sqrt(gravity[1]*gravity[1] + gravity[2]*gravity[2]));
196.                     ypr[2] = atan(gravity[1] / sqrt(gravity[0]*gravity[0] + gravity[2]*gravity[2]));
197.         
198.                     // output various components for debugging
199.                     //println("q:\t" + round(q[0]*100.0f)/100.0f + "\t" + round(q[1]*100.0f)/100.0f + "\t" + round(q[2]*100.0f)/100.0f + "\t" + round(q[3]*100.0f)/100.0f);
200.                     //println("euler:\t" + euler[0]*180.0f/PI + "\t" + euler[1]*180.0f/PI + "\t" + euler[2]*180.0f/PI);
201.                     //println("ypr:\t" + ypr[0]*180.0f/PI + "\t" + ypr[1]*180.0f/PI + "\t" + ypr[2]*180.0f/PI);
202.                     */
203.                 }
204.             }
205.         }
206.     }
207. }
208. 
     
209. void drawCylinder(float topRadius, float bottomRadius, float tall, int sides) {
210.     float angle = 0;
211.     float angleIncrement = TWO_PI / sides;
212.     beginShape(QUAD_STRIP);
213.     for (int i = 0; i < sides + 1; ++i) {
214.         vertex(topRadius*cos(angle), 0, topRadius*sin(angle));
215.         vertex(bottomRadius*cos(angle), tall, bottomRadius*sin(angle));
216.         angle += angleIncrement;
217.     }
218.     endShape();
219.     
220.     // If it is not a cone, draw the circular top cap
221.     if (topRadius != 0) {
222.         angle = 0;
223.         beginShape(TRIANGLE_FAN);
224.         
225.         // Center point
226.         vertex(0, 0, 0);
227.         for (int i = 0; i < sides + 1; i++) {
228.             vertex(topRadius * cos(angle), 0, topRadius * sin(angle));
229.             angle += angleIncrement;
230.         }
231.         endShape();
232.     }
233.   
234.     // If it is not a cone, draw the circular bottom cap
235.     if (bottomRadius != 0) {
236.         angle = 0;
237.         beginShape(TRIANGLE_FAN);
238.     
239.         // Center point
240.         vertex(0, tall, 0);
241.         for (int i = 0; i < sides + 1; i++) {
242.             vertex(bottomRadius * cos(angle), tall, bottomRadius * sin(angle));
243.             angle += angleIncrement;
244.         }
245.         endShape();
246.     }
247. }

 Exception in thread "Animation Thread" java.lang.RuntimeException: java.lang.RuntimeException: No framebuffer objects available

at jogamp.common.awt.AWTEDTExecutor.invoke(AWTEDTExecutor.java:58)

at jogamp.opengl.awt.AWTThreadingPlugin.invokeOnOpenGLThread(AWTThreadingPlugin.java:99)

at jogamp.opengl.ThreadingImpl.invokeOnOpenGLThread(ThreadingImpl.java:205)

at javax.media.opengl.Threading.invokeOnOpenGLThread(Threading.java:172)

at javax.media.opengl.Threading.invoke(Threading.java:191)

at javax.media.opengl.awt.GLCanvas.display(GLCanvas.java:461)

at processing.opengl.PGL.requestDraw(PGL.java:1195)

at processing.opengl.PGraphicsOpenGL.requestDraw(PGraphicsOpenGL.java:1550)

at processing.core.PApplet.run(PApplet.java:2140)

at java.lang.Thread.run(Thread.java:662)

Caused by: java.lang.RuntimeException: No framebuffer objects available

at processing.opengl.PGL$PGLListener.init(PGL.java:3255)

at jogamp.opengl.GLDrawableHelper.init(GLDrawableHelper.java:532)

at jogamp.opengl.GLDrawableHelper.init(GLDrawableHelper.java:552)

at javax.media.opengl.awt.GLCanvas$5.run(GLCanvas.java:1032)

at jogamp.opengl.GLDrawableHelper.invokeGLImpl(GLDrawableHelper.java:1019)

at jogamp.opengl.GLDrawableHelper.invokeGL(GLDrawableHelper.java:896)

at javax.media.opengl.awt.GLCanvas$7.run(GLCanvas.java:1060)

at java.awt.event.InvocationEvent.dispatch(InvocationEvent.java:199)

at java.awt.EventQueue.dispatchEventImpl(EventQueue.java:666)

at java.awt.EventQueue.access$400(EventQueue.java:81)

at java.awt.EventQueue$2.run(EventQueue.java:627)

at java.awt.EventQueue$2.run(EventQueue.java:625)

at java.security.AccessController.doPrivileged(Native Method)

at java.security.AccessControlContext$1.doIntersectionPrivilege(AccessControlContext.java:87)

at java.awt.EventQueue.dispatchEvent(EventQueue.java:636)

at java.awt.EventDispatchThread.pumpOneEventForFilters(EventDispatchThread.java:269)

at java.awt.EventDispatchThread.pumpEventsForFilter(EventDispatchThread.java:184)

at java.awt.EventDispatchThread.pumpEventsForHierarchy(EventDispatchThread.java:174)

at java.awt.EventDispatchThread.pumpEvents(EventDispatchThread.java:169)

at java.awt.EventDispatchThread.pumpEvents(EventDispatchThread.java:161)

at java.awt.EventDispatchThread.run(EventDispatchThread.java:122)