have a class Letter
and an array of this class, init in setup().

then do all in draw().


class Letter {
      char letter=' ';
      int x,y,xAdd,yAdd;

      void move(){
           
      }
     
      void display() {
           
      }

}

like this...   

1. //
2. String sourceText = "ELEPHANT";
3. Letter [] arrLetterBoxes = new Letter [sourceText.length()];
4. int startingMillis;
5. final int durationTillMovement = 1400; // starts after 1400 millis
6. //
7. void setup () {
8.   size(800, 600);
9.   // Init
10.   for (int i = 0; i < sourceText.length(); i++) {
11.     arrLetterBoxes[i] = new Letter(sourceText.charAt(i), i * 60 + 30, 120, giveValueToAdd(), 0.0 );
12.   } // for
13.   startingMillis=millis();
14. } // func
15. //
16. void draw () {
17.   background (125);
18.   // move and paint the letters
19.   for (int i = 0; i < arrLetterBoxes.length; i++) {
20.     if (millis() > startingMillis + durationTillMovement) {
21.       arrLetterBoxes[i].move();
22.     }
23.     arrLetterBoxes[i].display();
24.   }
25. } // func
26. //
27. float giveValueToAdd() {
28.   // this delivers a float between
29.   // -2.1 and +2.1 but without
30.   // values between -0.3 to +0.3 to
31.   // avoid unmoving letters.
32.   float buffer=0;
33.   // get positive random number
34.   buffer = random (.3, 2.1);
35.   // with 50% make it negativ
36.   if (random(100) > 50 ) {
37.     buffer *= -1;
38.   }
39.   // return it
40.   return buffer;
41. } // func
42. //
43. // =========================================================
44. //
45. class Letter {
46.   char letter=' ';  // letter
47.   float x, y;       // position
48.   float xAdd, yAdd; // for movement
49.   int w=30;         // width
50.   int h=60;         // height
51.   //
52.   // constructor
53.   Letter (char tempLetter, float tempX, float tempY, float tempXAdd, float tempYAdd) {
54.     letter =tempLetter;
55.     x      =tempX;
56.     y      =tempY;
57.     xAdd   =tempXAdd;
58.     yAdd   =tempYAdd;
59.   }  // constructor
60.   //
61.   void move() {
62.     x+=xAdd;
63.     y+=yAdd;
64.     xAdd=keepInBoundary(x, 1, width-w, xAdd);
65.     yAdd=keepInBoundary(y, 1, height-h, yAdd);
66.   } // method
67.   //
68.   private float keepInBoundary(float testPoint, float lowerBoundary, float upperBoundary, float valueToAdd) {
69.     // Situation: testPoint is a position (e.g. ball) and valueToAdd gets added to it, so testPoint moves.
70.     // Now testPoint must stay within lowerBoundary and upperBoundary (e.g. screen).
71.     // ValueToAdd gets changed accordingly and is returned as return value.
72.     if (testPoint<=lowerBoundary) {
73.       valueToAdd=abs(valueToAdd);
74.     }
75.     else if (testPoint>=upperBoundary) {
76.       valueToAdd=-1*abs(valueToAdd);
77.     }
78.     return valueToAdd;
79.   } // method
80.   //
81.   void display() {
82.     stroke(2, 255, 2);
83.     fill(25, 25, 22);
84.     rect(x, y, 30, 70);
85.     fill(255, 2, 2);
86.     text(letter, x+12, y+30);
87.   } // method
88. } // class
89. // ==========================================================

that is also a nice version, the letters collide now among each other so the word stays "elephant"
although the letters are moving.
The movement starts only after 2 seconds.

1. //
2. String sourceText = "ELEPHANT";
3. Letter [] arrLetterBoxes = new Letter [sourceText.length()];
4. int startingMillis;
5. final int durationTillMovement = 1400; // starts after 1400 millis
6. //
7. void setup () {
8.   size(800, 600);
9.   // Init
10.   for (int i = 0; i < sourceText.length(); i++) {
11.     arrLetterBoxes[i] = new Letter(sourceText.charAt(i), i,
12.     i * 60 + 30, 120,
13.     giveValueToAdd(), 0.0 );
14.   } // for
15.   startingMillis=millis();
16. } // func
17. //
18. void draw () {
19.   background (125);
20.   // move and paint the letters
21.   for (int i = 0; i < arrLetterBoxes.length; i++) {
22.     if (millis() > startingMillis + durationTillMovement) {
23.       arrLetterBoxes[i].move();
24.       arrLetterBoxes[i].collide();
25.     } // if
26.     arrLetterBoxes[i].display();
27.   } // for
28. } // func
29. //
30. float giveValueToAdd() {
31.   // this delivers a float between
32.   // -2.1 and +2.1 but without
33.   // values between -0.3 to +0.3 to
34.   // avoid unmoving letters.
35.   float buffer=0;
36.   // get positive random number
37.   buffer = random (0.3, 2.1);
38.   // with 50% make it negativ
39.   if (random(100) > 50 ) {
40.     buffer *= -1;
41.   }
42.   // return it
43.   return buffer;
44. } // func
45. //
46. // =========================================================
47. //
48. class Letter {
49.   char letter=' ';  // letter
50.   int index;        // index
51.   float x, y;       // position
52.   float xAdd, yAdd; // for movement
53.   int w=30;         // width
54.   int h=60;         // height
55.   //
56.   // constructor
57.   Letter (char tempLetter, int tempIndex, float tempX, float tempY, float tempXAdd, float tempYAdd) {
58.     letter =tempLetter;
59.     index  =tempIndex;
60.     x      =tempX;
61.     y      =tempY;
62.     xAdd   =tempXAdd;
63.     yAdd   =tempYAdd;
64.   }  // constructor
65.   //
66.   void move() {
67.     x+=xAdd;
68.     y+=yAdd;
69.     xAdd=keepInBoundary(x, 1, width-w, xAdd);
70.     yAdd=keepInBoundary(y, 1, height-h, yAdd);
71.   } // method
72.   //
73.   private float keepInBoundary(float testPoint, float lowerBoundary, float upperBoundary, float valueToAdd) {
74.     // Situation: testPoint is a position (e.g. ball) and valueToAdd gets added to it, so testPoint moves.
75.     // Now testPoint must stay within lowerBoundary and upperBoundary (e.g. screen).
76.     // ValueToAdd gets changed accordingly and is returned as return value.
77.     if (testPoint<=lowerBoundary) {
78.       valueToAdd=abs(valueToAdd);
79.     }
80.     else if (testPoint>=upperBoundary) {
81.       valueToAdd=-1*abs(valueToAdd);
82.     }
83.     return valueToAdd;
84.   } // method
85.   //
86.   void collide() {
87.     // checks collision with neighbours and only for x.
88.     // 1st: to the left:
89.     if (index>0) {
90.       if (arrLetterBoxes[index-1].x+arrLetterBoxes[index-1].w >= x) {
91.         xAdd= abs(xAdd); // make it pos
92.       } // if
93.     } // if
94.     // 2nd: to the right:
95.     if (index<arrLetterBoxes.length-1) {
96.       if (x+w >= arrLetterBoxes[index+1].x) {
97.         xAdd= -1 * abs(xAdd); // make it negative
98.       } // if
99.     } // if
100.   } // method
101.   //
102.   void display() {
103.     stroke(2, 255, 2);
104.     fill(25, 25, 22);
105.     rect(x, y, 30, 70);
106.     fill(255, 2, 2);
107.     text(letter, x+12, y+30);
108.   } // method
109. } // class
110. // ==========================================================