moving shapes created by arrays

Programming Questions

blade7022

moving shapes created by arrays

in Programming Questions • 7 months ago

I need help figuring out how to move a shape created by an array. I am really new to this, and it is for a class. To be honest, the teacher does not explain anything very well, plus it's an online class. I have to create 3 "constelations" and have them move across the sky. I have a good idea on how to create the arrays them selves, but can't figure out houw to make them move well. I need them to go from a to b on a path and revert to a after they reach point b.

Replies(5)

tfguy44

Re: moving shapes created by arrays

7 months ago

Please post your current code. It is very hard to help you without seeing what you are trying to accomplish.

blade7022

Re: moving shapes created by arrays

7 months ago

This is mostly from a given example. I have reworked the shapes. But I dont like the movement. Is ther a way to have the ponints reset without them jetting back across the screen. How do you set them to a non linear path?

int[] x = {0,40,60,80,120,80,60,40};
int[] y = {60,40,0,40,60,80,120,80};
int[] x1 = {20,40,40,50,60,60,80,80,60,80,80,60,60,50,40,40,20,20,40,20};
int[] y1 = {20,40,60,50,60,40,20,60,80,100,140,120,100,110,100,120,140,100,80,60};

void setup(){
size(600,600);
}
void draw(){
background (0);
   colorMode (RGB);
fill(0,255,0);
beginShape();
for (int i = 0; i < x.length; i++) {
    if ((x[0] >= 1000) && ( x[i] <= 1600) ) {
    }
    vertex(x[i], y[i]);
    x[i] = x[i] +3;
    if (x[i] >= 1600) {

      x[i]=-250;
    }
}
endShape();

fill(0,0,255);
beginShape();
for (int i = 0; i < x1.length; i++) {
    if ((x1[0] >= 1000) && ( x1[i] <= 1600) ) {
    }
    vertex(x1[i], y1[i]);
    x1[i] = x1[i] +3;
    if (x1[i] >= 1600) {

x1[i]=-150;
}
}
endShape();
}

tfguy44

Re: moving shapes created by arrays

7 months ago

Here, like this:

int[] x = {0,40,60,80,120,80,60,40};
int[] y = {60,40,0,40,60,80,120,80};
int[] x1 = {20,40,40,50,60,60,80,80,60,80,80,60,60,50,40,40,20,20,40,20};
int[] y1 = {20,40,60,50,60,40,20,60,80,100,140,120,100,110,100,120,140,100,80,60};
int xoff = 0;
int xupdate = 3;
void setup(){
size(600,600);
}
void draw(){
background (0);
xoff+=xupdate; // Adjust how much it moves over.
if( xoff > width-120 || xoff < 0 ){ xupdate*=-1; } // Changes directions at the edges.
pushMatrix(); // Remember this position.
translate(xoff,0); // Move it over this much.
fill(0,255,0);
beginShape();
for (int i = 0; i < x.length; i++) { // Draw it.
vertex(x[i], y[i]);
}
endShape();
popMatrix(); // Restore the remembered position.
pushMatrix();
translate(xoff,0);
fill(0,0,255);
beginShape();
for (int i = 0; i < x1.length; i++) {
vertex(x1[i], y1[i]);
}
endShape();
popMatrix();
}

tfguy44

Re: moving shapes created by arrays

7 months ago

This also allows you to set them to move however you want. You just need to work out the X and Y offsets to have them follow any path you want.
Here's an example of them going in a circle. The X and Y offsets are calculated based on the elapsed time in milliseconds the sketch has been running, using trig to work out where on a circle they should be.

int[] x = {0,40,60,80,120,80,60,40};
int[] y = {60,40,0,40,60,80,120,80};
int[] x1 = {20,40,40,50,60,60,80,80,60,80,80,60,60,50,40,40,20,20,40,20};
int[] y1 = {20,40,60,50,60,40,20,60,80,100,140,120,100,110,100,120,140,100,80,60};
float xoff, yoff;
void setup(){
size(600,600);
}
void draw(){
background (0);
translate(width/2-60,height/2-60);
xoff = 200 * cos( map(millis()%5000,0,5000,0,TWO_PI) );
yoff = 200 * sin( map(millis()%5000,0,5000,0,TWO_PI) );
pushMatrix();
translate(xoff,yoff);
fill(0,255,0);
beginShape();
for (int i = 0; i < x.length; i++) {
vertex(x[i], y[i]);
}
endShape();
popMatrix();
pushMatrix();
translate(xoff,yoff);
fill(0,0,255);
beginShape();
for (int i = 0; i < x1.length; i++) {
vertex(x1[i], y1[i]);
}
endShape();
popMatrix();
}

blade7022

Re: moving shapes created by arrays

7 months ago

Thanks for the help!

Would you be able to show me how to add a primitive with keypressed()? I'm not having any luck

Top Reply