moving pixels to the right

Programming Questions

sebastiako

in Programming Questions • 2 years ago

i ve made a very simple draw tool , it just paint pixels with the mouse.
I need that the background can move to the right as in this video:

http://www.youtube.com/watch?v=9JyfUWuhSKI

You can see that the background is always going down. How can I achieve this effect manipulating pixels arrays?

thanks

S.

Replies(2)

PhiLho

Re: moving pixels to the right

2 years ago

The movie you shows seems to be done in 3D.

Anyway, in 2D, you can do something like:

final int INTERVAL = 10;
void setup()
{
size(400, 400);
smooth();
background(255);
}
void draw()
{
// Scroll one line of pixels per frame
loadPixels();
arrayCopy(pixels, 0, pixels, width, (height - 1) * width);
updatePixels();
// Add a line from time to time
if (frameCount % INTERVAL == 0)
{
stroke(color(random(0, 50), random(50, 200), random(100, 255)));
strokeWeight(random(2, 10));
line(0, random(height - INTERVAL), width, random(height - INTERVAL));
}
}

PhiLho

Re: moving pixels to the right

2 years ago

Ah, somehow, I saw the drawings going down, so I coded like this, but you asked for it to go to the right. Need a little more work!

New code is:

final int INTERVAL = 10;
void setup()
{
size(400, 400);
smooth();
background(255);
}
void draw()
{
// Scroll one column of pixels per frame
loadPixels();
for (int r = 0; r < height; r++)
{
arrayCopy(pixels, width * r, pixels, width * r + 1, width - 1);
}
updatePixels();
// Add a line from time to time
if (frameCount % INTERVAL == 0)
{
stroke(color(random(0, 50), random(50, 200), random(100, 255)));
strokeWeight(random(2, 10));
line(random(INTERVAL, width), 0, random(INTERVAL, width), height);
}
}

Top Reply