Moving on an angle

Programming Questions

cammie827

in Programming Questions • 10 months ago

I'm trying to make a character controlled by arrow keys, and I want it to move in any direction. when I hit left and right, i would like it to turn, and up and down should be forwards and backwards. I have something that kinda works, but it only rotates around the screen corner, and is technically only sliding on the x axis. Can anybody help?

int x;
int y;
float ang;
void setup() {
size(500, 500);
smooth();
}
void draw() {
background(0);
pushMatrix();
rotate(ang);
translate(x, y);
rect(0, -5, 40, 10);
popMatrix();
if (keyPressed) {
switch(keyCode) {
case UP:
x+=5;
break;
case DOWN:
x-=5;
break;
case LEFT:
ang -= 0.01;
break;
case RIGHT:
ang += 0.01;
break;
}
}
}

Replies(5)

asimes

Re: Moving on an angle

10 months ago

This may be doable with just translate() and rotate() but I am more accustomed to controlling the direction of travel with cos() and sin(). This is a good tutorial if you are not familiar, check the part on the unit circle: http://processing.org/learning/trig/

float ang, speed, x, y;
void setup() {
size(500, 500);
smooth();
ang = 0;
speed = 3;
x = width/2;
y = height/2;
}
void draw() {
background(0);
pushMatrix();
translate(x, y);
rotate(ang);
rect(-20, -7.5, 40, 15); // Center the rect
translate(20, 0); // Translate to default Polar Coordinate 0 radians
ellipse(0, 0, 5, 5); // Display direction
popMatrix();
if (keyPressed) {
switch(keyCode) {
case UP:
x += cos(ang)*speed;
y += sin(ang)*speed;
break;
case DOWN:
x -= cos(ang)*speed;
y -= sin(ang)*speed;
break;
case LEFT:
ang -= 0.05;
break;
case RIGHT:
ang += 0.05;
break;
}
}
}

amnon.owed

Re: Moving on an angle

10 months ago

Also check out: https://forum.processing.org/topic/rotating-object-around-a-point

cammie827

Re: Moving on an angle

10 months ago

Thanks for the help guys! One more question: I'm now attempting to make the shape loop back to the other side of the screen when it leaves the window. This is what I have so far, but it doesn't work right. If the angle is anything over 0, it doesn't work.

if (x-20 >= width) {
x = -1*(ang*40)-19;
}
if (x+20 <= 0) {
x = (ang*40)+19+width;
}

asimes

Re: Moving on an angle

10 months ago

if (x > width+20) x = -20;
if (x < -20) x = width+20;

cammie827

Re: Moving on an angle

10 months ago

Thanks! I don't even know what I was trying to do there :P

Top Reply