Moving buttons for a game

Programming Questions

katherz

in Programming Questions • 10 months ago

Hi, I am a new programming student and for my school final, I am working on a mini game, where you have to shoot werewolves in a set amount of time. How can I make it so that the werewolf image is a button that you can click on it and after you click on it twice, it disappears? Really need the help, I have the girl shooting and the werewolf walking. Download in comment below >_<

//DECLARING OBJECTS
Werewolf werewolf;

//BACKGROUND

float r = 0.8;
PImage bg;

//SHOOT LEFT

PImage shootleft;

//SHOOT RIGHT

PImage shootright;

//STAND

float v = 0.5;
PImage standleft;
PImage standright;

//SETUP

void setup() {

size (650, 700);
bg = loadImage ("bg_0.png"); //load background
standleft = loadImage ("stand_left.png"); //load standing left image
standright = loadImage ("stand_right.png"); //load standing right image
shootleft= loadImage ("shoot_left.png"); //load shooting left image
shootright= loadImage ("shoot_right.png"); //load shooting right image
werewolf = new Werewolf(); //load werewolf class
}

//DRAW

void draw() {
frameRate(10);
scale(v); //scale bg image
image(bg, 0, 0); //display bg image
scale (r); //scale Ellen image

if (mousePressed && mouseX> width/2) { //
    image(shootright, 500, 850);
}
else if (mousePressed) {
    image(shootleft, 500, 850);
}
else if (mouseX > width/2) {
    image(standright, 500, 850);
}
else {
    image(standleft, 500, 850);
}

werewolf.display(); //call display method
werewolf.movement();
}
class Werewolf {
float life; //life counter
int walk; //walk 8 images
int imageIndex; // start at image 0
int die; // death 7 images
int imageIndextwo; //start at image 0
float movement; //movement counter
float sizewolf; //scale wolf down
int xtwo; // x variable for position
PImage [] wolf; //wolf image walking to the left
PImage [] death; //death image walking to the left
boolean hit;
float tempX;
float tempY;
float tempW;
float tempH;

Werewolf() {
    life = 2;
    walk = 8;
    die = 7;
    imageIndex = 0;
    imageIndextwo = 0;
    movement = 3;
    sizewolf = 0.9;
    tempX = 0;
    tempY = 0;
    tempW = 0;
    tempH = 0;
    xtwo = 0;
    wolf = new PImage [walk]; //left walk
    death = new PImage [die]; // left death
    hit = false;

    for (int w = 0; w < wolf.length; w ++) {
      wolf[w] = loadImage("wolf_walk_" + w + ".png");
    }

    for (int q = 0; q < death.length; q ++) {
      death[q] = loadImage("wolf_death_" + q + ".png");
    }
}
void display() {
    image(wolf[imageIndex], xtwo+1386, 650);
    imageIndex = (imageIndex + 1) % wolf.length;
}

void movement() {
    xtwo-=4;
}

void lifecounter(int mx, int my) {
    if (mx > tempX && mx < tempX + tempW && my > tempY && my < tempY + tempH) {
      hit = !hit;
    }
    if (hit) {
      life -= 1;
    }
}

void deathdisplay() {
    image(death[imageIndex], xtwo+1386, 650);
    imageIndextwo = (imageIndextwo + 1) % death.length;
}
}

Replies(6)

GoToLoop

Re: Moving buttons for a game

10 months ago

It'd be nice if we had the images to run it!

katherz

Re: Moving buttons for a game

10 months ago

sorry sorry first time using forums >_< Here are the images along with the code

https://www.dropbox.com/s/hmiqvcj2q9lwux1/Shooting_game.zip

GoToLoop

Re: Moving buttons for a game

10 months ago

To do a task every time a mouse is clicked, you need to use callback function mousePressed() , rather than relying on global variable mousePressed .

But to check if a mouse was clicked within a werewolf image's area, you have to know its dimensions (width, height).
And since you also use scale() , it is even more confusing to find that.
B/c I have no idea how to do an algorithm which would translate mouse coordinates to scaled up image ones!

And I'm not good enough on Processing either!

The ideal situation would be to have the images loaded having their right scaled up sizes already!

But while I was perusing your code, I've made many modifications.
Check it out: [Newer version 2.2!] [Version 2.3; starting to kill]

ShootingGame

/*
 * Shooting Game (v2.3)
 * by Katherz (2012/Dec)
 * http://forum.processing.org/topic/moving-buttons-for-a-game
 */

//DECLARING OBJECTS
final static int wolvesNum = 10;
final static List<Werewolf> werewolves = new ArrayList(); //load werewolves class

final static int wolfSpd = 20;
final static int wolfHP  = 2;

final static int walkNum = 8; //walk 8 images
final static int dieNum  = 7; //death 7 images

final static PImage[] wolf  = new PImage[walkNum]; //wolf image walking to the left
final static PImage[] death = new PImage[dieNum];  //death image walking to the left

//BAZOOKA
final static int fireDelay = 1;  //how many frames Ellen keeps shooting after a click
int fireTimer;
boolean isFiring;

//SCALE
final static float v = .5f;
final static float r = .8f * v;

//BACKGROUND
PGraphics bg;

//SHOOT
PImage shootLeft;
PImage shootRight;

//STAND
PImage standLeft;
PImage standRight;

//MISC
final static int fps = 10;

//SETUP
void setup() {

    size (650, 700);
    frameRate(fps);

    createBGImage();
    loadEllenImages();
    loadWerewolfImages();
    createWerewolves();
}

//BACKGROUND IMAGE
void createBGImage() {

    bg = createGraphics(width, height, P2D);

    bg.beginDraw();

    bg.scale(v); //scale for BG image
    bg.image(loadImage("bg_0.png"), 0, 0); //load & create BG image

    bg.endDraw();
}

//ELLEN'S IMAGES
void loadEllenImages() {

    standLeft  = loadImage("stand_left.png");  //load standing left image
    standRight = loadImage("stand_right.png"); //load standing right image
    shootLeft  = loadImage("shoot_left.png");  //load shooting left image
    shootRight = loadImage("shoot_right.png"); //load shooting right image
}

//WEREWOLVES' IMAGES
void loadWerewolfImages() {

    for (int w=0; w<walkNum; w++)
        wolf[w]  = loadImage("wolf_walk_"  + w + ".png");

    for (int q=0; q<dieNum;  q++)
        death[q] = loadImage("wolf_death_" + q + ".png");
}
//CREATE WEREWOLVES
void createWerewolves() {

    for (int wolves=0; wolves<wolvesNum; wolves++)
        werewolves.add( new Werewolf(wolves<<9, 
        (int) random(wolfSpd>>1, wolfSpd + 1), 
        (int) random(wolfHP>>1, wolfHP + 1)) );
}

//DRAW
void draw() {

    image(bg, 0, 0); //display BG image

    displayEllen();  //show Ellen//

    Iterator<Werewolf> i = werewolves.iterator();

    while ( i.hasNext () ) {
        Werewolf wolves = i.next();
        if ( wolves.all() )   //call all Werewolf's methods
            i.remove();       //remove it if it has died!
    }

    if (fireTimer == frameCount)   isFiring = false;
}

//DISPLAY ELLEN
void displayEllen() {

    scale(r); //scale Ellen + werewolves images
    boolean aim = mouseX > width>>1;

    if (isFiring)
        if (aim)  image(shootRight, 500, 850);
        else      image(shootLeft, 500, 850);

    else
        if (aim)  image(standRight, 500, 850);
        else      image(standLeft, 500, 850);
}

//MOUSE CLICK
void mousePressed() {

    isFiring  = true;  //activate Ellen's firing animation
    fireTimer = frameCount + fireDelay;  //set timer to future -> present + delay
}

Werewolf

final class Werewolf {

    int imgIdx;        //current healthy wolf animation frame
    int imgIdxHurt;    //current wounded wolf animation frame

    int wolfPos;       //current wolf X position
    int wolfMov;       //wolf movement speed
    int wolfLife;      //current wolf HP

    Werewolf(int posX, int spd, int hp) {

        wolfPos  = posX + (width<<1);
        wolfMov  = spd;
        wolfLife = hp;
    }

    boolean display() {   //return true if it has died

        if (wolfLife > 0) {
            image( wolf[imgIdx], wolfPos, 650 );
            imgIdx = (imgIdx + 1) % walkNum;
        }

        else {
            image( death[imgIdxHurt], wolfPos, 650 );
            if ( ++imgIdxHurt == dieNum )   return true;
        }

        return false;
    }

    void update() {

        if ( wolfPos > -400 )   wolfPos -= wolfMov;
        else                    wolfPos = (width<<1) + 200;
    }

    void checkHit() {

        if ( mouseX<<1 > wolfPos && mouseX<<1 < wolfPos+100 ) 
            //&& mouseY<<1 > 650 && mouseY<<1 < 650+900 )
            --wolfLife;

        println( (mouseX<<1) + " \t " + wolfPos );
    }

    boolean all() {

        if (isFiring)   checkHit();
        update();
        return display();
    }
}