Move along a PVector []

Programming Questions

dimiro

in Programming Questions • 6 months ago

hi,
a small question .
how do i make a ball move along the lines that connect the dots?

public class Ball {
private PVector location=new PVector();
private PVector [] points;
int step;
int increment;
public Ball(PVector[] points) {
this.points = points;
location=points[0].get();
step=0;
increment=1;
}
public void setLocation(PVector loc) {
location=loc;
}
public PVector getLocation() {
return this.location;
}
public void move () {
location.x = lerp(location.x, this.points[step].x, .11f);
location.y = lerp(location.y, this.points[step].y, .11f);
if (step <= 0) {
increment=abs(increment);
}
else if (step >= this.points.length-1) {
increment = -abs(increment);
}
location.set(points[step].x, points[step].y, 0);
pushStyle();
fill(0);
noStroke();
ellipse(location.x, location.y, 10, 10);
popStyle();
step+=increment;
}
}
private PVector [] points;
Ball ball;
public void setup() {
size(800, 700);
textSize(12);
points=new PVector[10];
randomSeed(233);
for (int i=0; i<points.length; i++)
points[i]=new PVector((int)random(0, width), (int)random(0, height));
ball=new Ball( points);
}
public void draw() {
background(255);
smooth();
frameRate(3);
// pushStyle();
noStroke();
fill(255, 0, 0);
for (int i=0; i<points.length; i++) {
ellipse(points[i].x, points[i].y, 20, 20);
}
// popStyle();
stroke(1);
for (int i=1; i<points.length; i++) {
line(points[i-1].x, points[i-1].y, points[i].x, points[i].y);
}
ball.move();
}

if i do

public void move () {
location.x = lerp(location.x, this.points[1].x, .11f);
location.y = lerp(location.y, this.points[1].y, .11f);
pushStyle();
fill(0);
noStroke();
ellipse(location.x, location.y, 10, 10);
popStyle();
}
}

it moves along the line that connects points[0] and points[1]

but how do i do it for the all the points in the array?

thanks

Replies(6)

asimes

Re: Move along a PVector []

6 months ago

I made a post on traversing paths a little bit ago, maybe it will be useful for you: http://forum.processing.org/topic/intermediate-level-workshop

Specifically the second code:

PVector[] p = new PVector[10];
float t;
int curr;
void setup() {
size(600, 600);
noFill();
for (int i = 0; i < p.length; i++) p[i] = new PVector();
reset();
}
void draw() {
background(255);
for (int i = 0; i < p.length-1; i++) line(p[i].x, p[i].y, p[i+1].x, p[i+1].y);
float tx = p[curr].x+t*(p[curr+1].x-p[curr].x);
float ty = p[curr].y+t*(p[curr+1].y-p[curr].y);
ellipse(tx, ty, 20, 20);
if (t < 1.0) {
t += 0.025;
if (t > 1.0) {
t = 0.0;
if (curr < p.length-2) curr++;
else t = 1.0;
}
}
}
void mousePressed() {
reset();
}
void reset() {
for (int i = 0; i < p.length; i++) {
p[i].x = random(width);
p[i].y = random(height);
}
t = 0.0;
curr = 0;
}

amnon.owed

Re: Move along a PVector []

6 months ago

Also see this thread: https://forum.processing.org/topic/moving-circle-along-a-path

dimiro

thanks for replying ...
i see...
both asimes & ammon code works, but i d like to figure out how to do it with lerp,

i mean, is there a way to add this functionality in my move() function ? how do i need to update location vector with lerp so as to constantly travel from one point to another and backwards with constant speed...

asimes

Re: Move along a PVector []

6 months ago

There is no difference between lerp(): http://processing.org/reference/lerp_.html

and this:

float tx = p[curr].x+t*(p[curr+1].x-p[curr].x);
float ty = p[curr].y+t*(p[curr+1].y-p[curr].y);

If you want to do it with lerp(), you would pass points[curr] to the first argument, points[curr+1] to the second argument, and have the third argument go from 0 to 1 where curr is the index of where you are in the array. If you want to go backwards you make the third argument go from 1 to 0 instead.

asimes

Re: Move along a PVector []

6 months ago

I moved some of your code around and put in what I explained above, I figured it may be hard to follow without seeing it. You should really either separate the location from the path (different classes) or name the class something other than Ball. That was fairly confusing at first.

private PVector[] points;
Ball ball;
public void setup() {
size(800, 700);
// These only need to be called once, not every frame in draw()
smooth();
//frameRate(3);
points = new PVector[10];
randomSeed(233);
for (int i = 0; i < points.length; i++) points[i] = new PVector(random(width), random(height));
ball = new Ball(points);
}
public void draw() {
background(255);
noStroke();
fill(255, 0, 0);
for (int i = 0; i < points.length; i++) ellipse(points[i].x, points[i].y, 20, 20);
stroke(1);
for (int i=1; i<points.length; i++) line(points[i-1].x, points[i-1].y, points[i].x, points[i].y);
ball.move();
}
public class Ball {
private PVector location = new PVector();
private PVector[] points;
int curr;
float t;
public Ball(PVector[] points) {
this.points = points;
location = points[0].get();
curr = 0;
t = 0;
}
public void move () {
location.x = lerp(points[curr].x, points[curr+1].x, t);
location.y = lerp(points[curr].y, points[curr+1].y, t);
fill(0);
noStroke();
ellipse(location.x, location.y, 10, 10);
if (t < 1.0) {
t += 0.025;
if (t > 1.0) {
t = 0.0;
if (curr < points.length-2) curr++;
else t = 1.0;
}
}
}
}

dimiro

Re: Move along a PVector []

6 months ago

ok got it

thanks!

Top Reply