mouseX, translate and mousePressed()

Programming Questions

unopuntoz..

mouseX, translate and mousePressed()

in Programming Questions • 9 months ago

Hi,

I've been looking for this in other posts. There are similar issues reported, but the answers I've found do not completely apply to my case (surprisingly, because I think it's kind of basic stuff).

In short, I don't know how to have variables mouseX and mouseY changed according to a transform function within mousePresses (say, translate()). Here's what I would like to achieve:

void mousePressed()
{
pushMatrix();
translate(width/2,height/2); // want to have coordinates respect to the center of the sketch
println(mouseX + "," + mouseY); // this should return 0,0 when I click on the center of the sketch
popMatrix();
}

What am I missing?

thank you in advance

Replies(3)

quarks

Re: mouseX, translate and mousePressed()

9 months ago

You can't control the values in mouseX or mouseY that is done by processing. If you want the mouse coordinates to be relative to the centre of the screen then here is a possible solution

int mx, my;
void setup(){
size(300,300);
fill(255);
stroke(0,255,0);
}
void draw(){
background(0);
cursor(CROSS);
line(0,height/2,width,height/2);
line(width/2,0,width/2,height);
text("mouse at ["+mx+", "+my+"]", 20,40);
}
void mouseMoved(){
mx = mouseX - width/2;
my = mouseY - height/2;
}

The values in mx, my are being updated everytime the mouse moves. You can use these instead of mouseX and mouseY.

This code has been tested in 2.0b7

unopuntoz..

Re: mouseX, translate and mousePressed()

9 months ago

Thank you for the explanation and the possible solution,

best regards

walter

GoToLoop

Re: mouseX, translate and mousePressed()

9 months ago

Here's a version using -> translate(width>>1, height>>1);
But it's more complicated and cryptic though!

int mx, my;

void setup() {

    size(300, 300);
    frameRate(50);
    fill(255);
    stroke(#00FF00);
    cursor(CROSS);
}

void draw() {

    background(0);

    translate(width>>1, height>>1);

    line(-width>>1, 0, width>>1, 0);
    line(0, -height>>1, 0, height>>1);
    text("mouse @  ["+mx+", "+my+"]", 20 - width/2, 40 - height/2);
}

void mouseMoved() {

    mx = mouseX - width/2;
    my = mouseY - height/2;
}

Top Reply