MouseX and MouseY Relative to Transformation Matirx

General Discussion Other

Jacob Tay..

MouseX and MouseY Relative to Transformation Matirx

in General Discussion • Other • 1 month ago

In this application I'm creating (a simple Paint like thing) I am having trouble with detecting whether an object (a square, ellipse, photo - all insertable objects are simply classes that derive from a base class, or a subclass of the base class). baseObject defines an abstract method called mouseCollide, returning a boolean. It returns true when the mouse is in the shape when called, false if not. When testing the logic, I factored out translations (namely rotate) but I need to be able to detect collisions when the object is rotated.

The question is: how can I translate absolute coordinates (relative to the window) to coordinates relative to a transformation matrix? Namely, the Mouse X and Y values?

Replies(5)

quarks

Re: MouseX and MouseY Relative to Transformation Matirx

1 month ago

Difficult to advise you about your specific code but I have created the example below.

It creates five rectangles at random locations, size and rotations. Every time the mouse moves it tests to see if it is over a shape and remembers the shape in the selected variable (selected == null if the mouse is not over a shape. When a shape is displayed it will add a red box round the rectangle. Notice that this works not matter what the position, size or rotation of the rectangle.

HTH

import java.awt.geom.*;
Shape selected = null;
int nbr = 5;
Shape[] shapes = new Shape[nbr];
public void setup() {
size(400, 400);
cursor(CROSS);
for (int i = 0; i < shapes.length; i++) {
float x = 50 + random(width - 100);
float y = 50 + random(height - 100);
float w = random(20, 50);
float h = random(20, 50);
float a = random(TWO_PI);
shapes[i] = new Rectangle(this, x, y, w, h, a);
}
}
public void mouseMoved() {
selected = null;
for (int i = 0; i < shapes.length; i++) {
if (shapes[i].isOver(mouseX, mouseY)) {
selected = shapes[i];
break; // exit for loop
}
}
}
public void draw() {
background(255);
for (int i = 0; i < shapes.length; i++)
shapes[i].display(selected);
}
public static abstract class Shape {
protected PApplet app;
// These variables are used to calculate whether a
// point is over the shape. They are created once
// and reused for efficiency reasons.
protected AffineTransform aff = new AffineTransform();
protected double[] temp = new double[2];
protected float ox, oy;
// ------------------------------------------------
protected float x, y; // position
protected float rot; // angle rotated in radians
protected int strokeColor;
protected int fillColor;
protected float strokeWeight;
public Shape(PApplet app, float x, float y, float rot) {
this.app = app;
this.x = x;
this.y = y;
this.rot = rot;
strokeColor = 0xFF6464C8;
fillColor = 0xFFF0F000;
strokeWeight = 2.0f;
}
public abstract boolean isOver(float px, float py);
public abstract void display(Shape selected);
}
public static class Rectangle extends Shape {
private float w, h;
public Rectangle(PApplet app, float x, float y, float w, float h, float rot) {
super(app, x, y, rot);
this.w = w;
this.h = h;
}
public boolean isOver(float px, float py) {
// Use setToTranslation so that it replaces previous
// transformation
aff.setToTranslation(x, y);
aff.rotate(rot);
// Store coordinates of interest in array for transforming
temp[0] = px;
temp[1] = py;
try {
// Reverse the applied transformation to the coordinates
aff.inverseTransform(temp, 0, temp, 0, 1);
ox = (float) temp[0];
oy = (float) temp[1];
}
catch (NoninvertibleTransformException e) {
// Unable to invert point so not over shape
return false;
}
// Is [ox,oy] over the un-transformed shape
if (ox > -w/2 && ox < w/2 && oy > -h/2 && oy < h/2)
return true;
else
return false;
}
public void display(Shape selected) {
app.pushStyle();
app.pushMatrix();
app.rectMode(PApplet.CENTER);
app.fill(fillColor);
app.stroke(strokeColor);
app.strokeWeight(strokeWeight);
app.translate(x, y);
app.rotate(rot);
// Draw the shape
app.rect(0, 0, w, h);
// See if this is the selected shape
// if it is draw a red box round it
if (this == selected) {
app.stroke(255, 0, 0);
app.strokeWeight(3);
app.noFill();
app.rect(0, 0, w, h);
}
app.popMatrix();
app.popStyle();
}
}

v.k.

Re: MouseX and MouseY Relative to Transformation Matirx

1 month ago

Quarks, I could not run your code in PDE 2.0.1.

got a:

"unexpected token:."

@ line 59

quarks

Re: MouseX and MouseY Relative to Transformation Matirx

1 month ago

I was surprised at this because the code ran faultlessly in Eclipse and there is NO syntax error. It must be a bug in Processing's pre-processor that converts the sketch code to a Java class. I have modified the code so that the Shape and Rectangle classes are in their own .java tabs so are true top-level classes and the code works just fine.

Here is the corrected code - note that the sketch now has 3 tabs the Shape and Rectangle tabs being called Shape.java and Rectangle.java

Main sketch code

Shape selected = null;
int nbr = 5;
Shape[] shapes = new Shape[nbr];
public void setup() {
size(400, 400);
cursor(CROSS);
for (int i = 0; i < shapes.length; i++) {
float x = 50 + random(width - 100);
float y = 50 + random(height - 100);
float w = random(20, 50);
float h = random(20, 50);
float a = random(TWO_PI);
shapes[i] = new Rectangle(this, x, y, w, h, a);
}
}
public void mouseMoved() {
selected = null;
for (int i = 0; i < shapes.length; i++) {
if (shapes[i].isOver(mouseX, mouseY)) {
selected = shapes[i];
break; // exit for loop
}
}
}
public void draw() {
background(255);
for (int i = 0; i < shapes.length; i++)
shapes[i].display(selected);
}

Shape.java tab

import processing.core.*;
import java.awt.geom.*;
public abstract class Shape {
protected PApplet app;
// These variables are used to calculate whether a
// point is over the shape. They are created once
// and reused for efficiency reasons.
protected AffineTransform aff = new AffineTransform();
protected double[] temp = new double[2];
protected float ox, oy;
// ------------------------------------------------
protected float x, y; // position
protected float rot; // angle rotated in radians
protected int strokeColor;
protected int fillColor;
protected float strokeWeight;
public Shape(PApplet app, float x, float y, float rot) {
this.app = app;
this.x = x;
this.y = y;
this.rot = rot;
this.strokeColor = app.color(100, 100, 200);
this.fillColor = app.color(240, 240, 0);
strokeWeight = 2.0f;
}
public abstract boolean isOver(float px, float py);
public abstract void display(Shape selected);
}

Rectangle.java tab

import processing.core.*;
import java.awt.geom.*;
public class Rectangle extends Shape {
private float w, h;
public Rectangle(PApplet app, float x, float y, float w, float h, float rot) {
super(app, x, y, rot);
this.w = w;
this.h = h;
}
public boolean isOver(float px, float py) {
// Use setToTranslation so that it replaces previous
// transformation
aff.setToTranslation(x, y);
aff.rotate(rot);
// Store coordinates of interest in array for transforming
temp[0] = px;
temp[1] = py;
try {
// Reverse the applied transformation to the coordinates
aff.inverseTransform(temp, 0, temp, 0, 1);
ox = (float) temp[0];
oy = (float) temp[1];
}
catch (NoninvertibleTransformException e) {
// Unable to invert point so not over shape
return false;
}
// Is [ox,oy] over the un-transformed shape
if (ox > -w/2 && ox < w/2 && oy > -h/2 && oy < h/2)
return true;
else
return false;
}
public void display(Shape selected) {
app.pushStyle();
app.pushMatrix();
app.rectMode(PApplet.CENTER);
app.fill(fillColor);
app.stroke(strokeColor);
app.strokeWeight(strokeWeight);
app.translate(x, y);
app.rotate(rot);
// Draw the shape
app.rect(0, 0, w, h);
// See if this is the selected shape
// if it is draw a red box round it
if (this == selected) {
app.stroke(255, 0, 0);
app.strokeWeight(3);
;
app.noFill();
app.rect(0, 0, w, h);
}
app.popMatrix();
app.popStyle();
}
}

quarks

Re: MouseX and MouseY Relative to Transformation Matirx

1 month ago

GoToLoop pointed out that the problem with the pre- so I have corrected the code in my first reply and have tested it with 2.0.3 and it now works.

So take your pick

Jacob Tay..

Re: MouseX and MouseY Relative to Transformation Matrix

1 month ago

Bingo! I would never have guessed that, I come from C++ and am not used to the convenience of having numerous libraries readily at my disposal. Well, that's one major roadblock removed. Thanks for the help, and sorry for not replying sooner.