This is a forum so it's meant for asking questions and getting answers.

It's easier to help if you show your code.

My guess is that you try to load from the data directory before the size() call in setup(). However only after that call does the sketch 'know' where the data directory is. If this is the case, the solution is to do loadStrings() inside setup().

However as said, it's hard to solve code problems without the actual code.

Oh moving the init in the setup() function solved it. Thank you much!

Forgive me again, here's my code now:

1. String lines[];
2. PFont f = createFont("Tahoma",40);
3. PVector puncte[];
4. void setup()
5. {
6.   lines =  loadStrings("date.txt");
7.   size (700,700);
8.   background(0);
9.   noLoop();
10. }
11. void draw()
12. {
13.   int i, x;
14.   textFont(f);
15.   puncte = new PVector[100];
16.   textAlign(CENTER,CENTER);
17.   String var[] = split(lines[0],' ');
18.   x = int(var[0]);
19.   for (i=1;i<=x;i++)
20.   {
21.     puncte[i].x = random(700);
22.     puncte[i].y = random(700);
23.     text(i,puncte[i].x,puncte[i].y);
24.   }
25. }

This gives me NullPointerException on line 21. I must say that I'm also new to Java-style programming. What is wrong here?

You've declared the array, but it doesn't contain anything yet. Think about it, what is the current value of puncte[i].x. Answer: there isn't any, because nothing has been set yet. It's just an empty array ready to store PVectors, but there aren't any PVectors in it yet. Which means you cannot yet set specific parts (x, y, z) of the PVector.

So the solution is to replace line 21 and 22 by the following line:

1.     puncte[i] = new PVector( random(700), random(700) );

I must say that I'm also new to Java-style programming.

I wonder what's your previous background then? 

I've re-written your code to be more in line w/ Processing/Java style:

String[] lines;
int[] vars;
PVector[] puncte;

void setup() {
  size(700, 700);
  noLoop();
  background(0);

  textAlign(CENTER, CENTER);
  textFont( createFont("Tahoma", 40) );

  lines = loadStrings("date.txt");
  vars = int( splitTokens(lines[0]) );
  println(vars);

  final int count = vars[0];
  puncte = new PVector[count];
  println("\n" + count);

  for (int i=0; i!=count; ++i) {
    puncte[i] = new PVector( random(width), random(height) );
    text(i, puncte[i].x, puncte[i].y);
  }
}