So if understood what you mean, the sketch is playing the sound all the time, while you have the mouse over the right half of the window. But you want it to play only once, when it enters the right half?

Then just store in a varable, if the mouse is over that area or not. Then the next frame, you can check, if the mouse was over that area in the previous frame, and only play the sound if not.

And you should not use delay, it seems to be an easy way to handle timings, but can cause a lot of problems, because no more can is executed until the delay is over. Better use millis()

Here is an example, i only tested with RWMidi, but that should not be relevant for your problem:

1. import themidibus.*;
   //import rwmidi.*;
   
   MidiBus myBus;
   //MidiOutput myBus;
   
   int aChannel, bChannel ;
   int aPitch, bPitch;
   int aVelocity, bVelocity;
   
   boolean over = false;
   boolean playing = false;
   int start;
   
   void setup() {
     size(200, 200);
     background(0);
   
     myBus = new MidiBus(this, "", "Java Sound Synthesizer");
     //myBus = RWMidi.getOutputDevices()[1].createOutput();
   }
   
   void draw() {
   
     // check if mouse entered left side of the window
     if (!over && mouseX<width/2) {
       aChannel = 1;
       aPitch = 60;
       aVelocity = 127;
       myBus.sendNoteOn(aChannel, aPitch, aVelocity);
   
       over = true;  // remember, that mouse was over the area
       playing = true;  // remember that sound was started
       start = millis();  // remember when sound was started
     }
     // check if mouse has left the left side of the window
     else if (mouseX > width/2) {
       over = false;
     }
   
     // check if sound has played for 1 second
     if (playing && (millis()-start) >= 1000) {
       myBus.sendNoteOff(aChannel, aPitch, aVelocity);
       playing = false;
     }
   }