Mapping xpos to mouseX inside a class?

Programming Questions

patrickfc..

Mapping xpos to mouseX inside a class?

in Programming Questions • 1 year ago

I'm trying to create a series of rectangles that move from one xpos to another xpos as mouseX goes from 0 to width.

Each rectangle has a unique starting xpos and a unique final xpos so my initial attempt involved creating a separate float for each rectangle that mapped to mouseX: map(mouseX,0,width,initial,final). That works just fine, but as I get more and more complex and add more rectangles, it gets too complicated.

So for the next attempt I created a rectangle class (the rectangles are all the same size, they only move xpos) and then drew those to the screen. But I can't figure out how/where to incorporate the mapping of mouseX that I used in the initial attempt.

How can I feed data into a mapped function that can be reflected when I draw the class inside the display function?

THANKS SO MUCH!

Replies(6)

calsign

Re: Mapping xpos to mouseX inside a class?

1 year ago

You should perform the mapping inside the display function, so that the location varies depending on the mouseX; if the mouse position is updated every frame, you have to update the relative location every frame.

If you need more descriptive information, it would help to post your code...

patrickfc..

Re: Re: Mapping xpos to mouseX inside a class?

1 year ago

Here is my code so far. I added some of the stuff from below (thanks tfguy44), but still can't quite figure it out. Thanks!

class block

{

//EVERY BLOCK has these pieces of data

float xstart, xend;

float xpos, ypos;

//Declaring

//Constructor

block (float xstart,float xend, float tempY)

{

rectMode(CENTER);

ypos = tempY;

}

//Functionality

//Display

void display(){

fill(0);

rect(map(mouseX,0,width,xstart,xend),ypos,30,5);

}

//DECLARING

block uno;

void setup()

{

size(500,500);

smooth();

noStroke();

uno = new block(100,400,250);

}

void draw(){

background(255);

uno.display();

}

calsign

Re: Re: Mapping xpos to mouseX inside a class?

1 year ago

The problem... has nothing to do with your mapping, but the fact that xstart and xend are never initialized. If you print them out using println(), you can see that they are both 0. This is because you never actually initialize them in your constructor... you pass variables that you don't do anything with.

It isn't enough to pass the variables of the same name... you have to assign them accordingly. Because of scope issues, you have to prefix the assigned variable with the current class, or this, which adds a degree of complication... in short, add the following two lines to your constructor:

this.xstart = xstart;
this.xend = xend;

tfguy44

Re: Mapping xpos to mouseX inside a class?

1 year ago

Like this:

class Rect{
int y;
int xstart,xend;
color c;
Rect(){
y = int(random(height));
xstart = int(random(height));
xend = int(random(width));
c = color( random(255), random(255), random(255) );
}
void render(){
stroke(0);
fill(c);
rect( map(mouseX,0,width,xstart,xend), y, 5,5);
}
}
Rect[] Rects;
void setup(){
size(400,400);
Rects = new Rect[40];
for( int i=0;i<Rects.length;i++){
Rects[i] = new Rect();
}
}
void draw(){
background(0);
for( int i=0;i<Rects.length;i++){
Rects[i].render();
}
}

tfguy44

Re: Mapping xpos to mouseX inside a class?

1 year ago

Your constructor is the problem. Notice that it takes in an xstart and xend as PARAMETERS, but does nothing to save them to CLASS VARIABLES. This is more apparent if you rename the parameters so the start with "temp", like so:

//Constructor
block (float tempxstart,float tempxend, float tempY)
{
rectMode(CENTER);
xstart = tempxstart;
xend = tempxend;
ypos = tempY;
}

patrickfc..

Re: Re: Mapping xpos to mouseX inside a class?

1 year ago

Thanks a ton!

Top Reply